help with star array needed

Programming Questions

oscar_co

in Programming Questions • 9 months ago

I am currently attempting to create an array of stars across the screen, in no particular order. I thought I was getting close with my script but I've just realised all I have done is replicate the script, which isn't going to work!

I guess I just want to create multiple objects, but I don't know where to start on that, as I've only been doing this for a week or so!

Any pointers would be awesome - many thanks in advance.

THE SCRIPT:

// VARIABLES

int step;

float angle, rad1, rad2;

int division=4;

int xsize=600;

int ysize=600;

float xdivider=float(xsize)/float(division);

float ydivider=float(ysize)/float(division);

float xcoord=xdivider;

float ycoord=ydivider;

Star star01;

Star star02;

// SETUP

void setup() {

size(xsize, ysize);

star01=new Star();

star02=new Star();

step = 10;

rad1 = 25.0;

rad2 = 50.0;

smooth();

xdivider = width / division;

ydivider = height / division;

}

//ANIMATION LOOP

void draw() {

background(55);

star01.display();

star02.display();

translate(xcoord, ycoord);

beginShape();

for (int i = 0; i < step; i++) {

float whichRad = (i%2 == 0)?rad1:rad2;

angle += TWO_PI/step;

float x = cos(angle)*whichRad;

float y = sin(angle)*whichRad;

stroke (0);

strokeWeight (2);

vertex(x, y);}

endShape(CLOSE);

angle += TWO_PI/360;

for (int x=0; x<division; x++) {

for (int y=0; y<division; y++) {

float xcoord = xdivider * (x+0.5);

float ycoord = ydivider * (y+0.5);

}

class Star{

//VARIABLES

float centreX;

float centreY;

void display()

{

beginShape();

for (int i = 0; i < step; i++) {

float whichRad = (i%2 == 0)?rad1:rad2;

angle += TWO_PI/step;

float x = cos(angle)*whichRad;

float y = sin(angle)*whichRad;

stroke (0);

strokeWeight (2);

vertex(x, y);

}

endShape(CLOSE);

angle += TWO_PI/360;

}

Replies(3)

asimes

Re: help with star array needed

9 months ago

I copy / pasted the code I put up the first time and added starX[] and starY[]. Otherwise it works about the same:

int numStars = 10;
float[] starX = new float[numStars];
float[] starY = new float[numStars];
int step;
float angle, rad1, rad2;
void setup() {
size(600, 600);
step = 10;
rad1 = 25.0;
rad2 = 50.0;
for (int i = 0; i < numStars; i++) {
starX[i] = random(width);
starY[i] = random(height);
}
}
void draw() {
background(255);
for (int i = 0; i < numStars; i++) {
beginShape();
for (int j = 0; j < step; j++) {
float whichRad = (j%2 == 0)?rad1:rad2;
angle += TWO_PI/step;
float x = starX[i]+cos(angle)*whichRad;
float y = starY[i]+sin(angle)*whichRad;
vertex(x, y);
}
endShape(CLOSE);
}
angle += TWO_PI/360;
}

GoToLoop

Re: help with star array needed

9 months ago

Here's my attempt. Not as fancy as asimes', but it's one more example on how to do it!

P.S.: Edited (v1.75) -> Using resetMatrix() and it's 4 stars now!

(1.91) -> more field variables for class Star!

/** Spinning Stars (v1.91)
 *  by Oscar_Co (2013/Jan)
 *
 *  http://forum.processing.org/topic/help-with-star-array-needed
 *  http://studio.processingtogether.com/sp/pad/export/ro.9q3XGOq4VPZWo/latest
 */

// VARIABLES

final static byte starSize = 25, step = 10, sp = 90;
final static byte fps = 50, offSet = 100;
final static color bg = 0100; 
final static color starStroke = 0, starFill = 255;

final static byte starsNum = 4;
final static Star[] stars = new Star[starsNum];

// SETUP

void setup() {
  size(400, 400);
  frameRate(fps);
  ellipseMode(CENTER);
  smooth();
  fill(starFill);
  stroke(starStroke);
  strokeWeight(2);

  stars[0] = new Star(offSet, offSet, starSize, step, -sp);
  stars[1] = new Star(width-offSet, height-offSet, starSize, step, sp);
  stars[2] = new Star(width>>1, height>>1, starSize, step, sp>>1);
  stars[3] = new Star(width>>1, height>>1, starSize>>1, step<<1, -sp<<1);
}

// ANIMATION LOOP

void draw() {
  background(bg);

  for (Star s: stars)  s.display();
}

// OBJECT STAR

class Star {
  int coordX, coordY;
  int size1, size2;
  int step, slowness;
  float angle;

  Star(int cx, int cy, int size, int st, int slow) {
    coordX = cx;
    coordY = cy;
    size1 = size;
    size2 = size1<<1;
    step  = st;
    slowness = slow;
  }

  void display() {
    resetMatrix();
    translate(coordX, coordY);

    beginShape();
    for (int i = 0; i < step; angle += TWO_PI/step) {
      float whichRad = i++%2 == 0? size1:size2;
      float x = cos(angle)*whichRad;
      float y = sin(angle)*whichRad;

      vertex(x, y);
    }
    endShape(CLOSE);

    angle += TWO_PI/slowness;
  }
}

oscar_co

Re: Re: help with star array needed

9 months ago

Thank you both ever so much!

Top Reply

Statistics

3 Replies
409 Views
0 Followers

Actions

Permalink