Help with sorting an array

Programming Questions

kevintdame

in Programming Questions • 1 year ago

Hi. I've been having some trouble with this and hoping for some help. Here's my situation:

I have a .txt file with data organized in lots of columns (30+) and lots of rows (150+). I am using the following commands to parse the data:

lines = loadStrings("datafile.txt");

then later:

for (int i=2; i<lines.length; i++) { // I start with 2 rather than 0 because there are 2 rows of header info in the file

String[] pieces = split(lines[i], '\t'); // parsing each piece of data across the row
float X = float(pieces[5]); // defining a variable called X for column #5
float Y = float(pieces[8]); // defining a variable called Y for column #8

This works fine but I get (and display) the data in the order that it happens to be in the file. I want to sort the data in column 5 in descending order. And then later sort the data in column 8 in descending order.

How do I do this? I've looked up past posts on the sort() function but can't seem to get it to work.

I decided to not post my code because the code is very long and complicated and I am trying to simplify the challenge above.

Thanks very much for any help!

Kevin

Replies(1)

benja

Re: Help with sorting an array

1 year ago

Hey,

i suppose you want to sort the data, but still want to keep the row-data together. I would create a class for the data of one row, and store the data inside. Then if you want to use sort() with an array of that class you need to implement the Comparable-Interface. This is an example:

String[] lines;
Dataset[] theData;

void setup() {
size(300, 300);

//load data
lines = loadStrings("data.txt");
// create array with one dataset-object for every row
theData = new Dataset[lines.length];
for (int i =0; i<lines.length; i++) {
    theData[i] = new Dataset(lines[i]);
    println(i+": "+theData[i].x + "   " + theData[i].y);
}
println("------------------------");

Arrays.sort(theData);
for (int i =0; i<lines.length; i++) {
    println(i+": "+theData[i].x + "   " + theData[i].y);
}

noLoop();
}

void draw() {
}

// comparable nutrition class
class Dataset implements Comparable {
float x, y;

Dataset(String data) {
    // parse the data
    String[] pieces = split(data, '\t');
    x = float(pieces[0]);
    y = float(pieces[1]);
}

// compare-function, is called by Arrays.sort()
public int compareTo(Object o) {
    // check if class is of same type
    if (!(o instanceof Dataset))
      throw new ClassCastException();

    // compare x-values
    float oX = ((Dataset) o).x;
    if (oX < x)
      return 1;
    if (oX > x)
      return -1;

    // if x-values are equal, compare y
    float oY = ((Dataset) o).y;
    if (oY < y)
      return 1;
    if (oY > y)
      return -1;

    // if x and y are equal, return 0
    return 0;
}
}