I've seen a few particle systems like this, could you provide the link to the one you're talking about so we can try and help.  It should be pretty simple.

Maybe something like this... will display the pixelwords by default, move them around on mouse press.  clear the words on "delete" and will add letters as you type.  I'm not all that familiar with this color mode, which does some strange stuff if changed much.  It's based on this sketch.

1. color[][] clre;
2. PVector[][] posizioni;
3. PVector origin;
4. ArrayList particles = new ArrayList();
5. int numParticles = 10000;
6. int z = 0;
7. String pixelwords = "Ho Ho Ho"+'\n'+"Merry Christmas";
8. void setup()
9. {
10.   size(400, 400);
11.   colorMode(HSB, 360, 100, 100, 100);
12.   PFont font = loadFont("SansSerif-32.vlw");
13.   textFont(font, 32);
14.   clre = new color[width][height/2];
15.   posizioni = new PVector[width][height/2];
16. }
17. void draw()
18. {
19.   background(1, 0, 100);
20.   textAlign(CENTER);
21.   fill(1, 100, 100, 1);
22.   text(pixelwords, width/2, 50);
23.   for(int i=0; i<width; i++) {
24.     for(int j = 0; j<height/2; j++) {
25.       clre[i][j] = get(i,j);
26.       if(clre[i][j] != -1) {
27.         if(z < numParticles) {
28.           posizioni[i][j] = new PVector(i,j,0); 
29.           origin = new PVector(posizioni[i][j].x, 130+posizioni[i][j].y, 0);
30.           PVector a = new PVector();
31.           PVector v = new PVector();       
32.           PVector l = new PVector(random(width), random(height), 0);
33.           particles.add(new Particle(a,v,l, origin, random(0.05f, 2.0f)));
34.           z++;
35.         }
36.       }
37.     }
38.   }
39.   for (int h = 0; h<particles.size()-1; h++) {
40.     Particle prt = (Particle) particles.get(h);
41.     prt.run();
42.     PVector actualVel = prt.getVelocity();
43.     PVector attrito = PVector.mult(actualVel,-0.05);
44.     prt.add_force(attrito);
45.     if(mousePressed) { 
46.       PVector mouseLoc = new PVector(mouseX, mouseY, 0);
47.       PVector diff = PVector.sub(mouseLoc,prt.getLocation());
48.       diff.normalize();
49.       float factor = 1.0f; 
50.       diff.mult(factor);
51.       prt.setAcceleration(diff);
52.     }
53.      else  {
54.      
55.         PVector origLoc = prt.getOrigin();
56.         PVector diff = PVector.sub(origLoc,prt.getLocation());
57.         diff.normalize();
58.         float factor = 0.5f; 
59.         diff.mult(factor);
60.         prt.setAcceleration(diff);
61.      
62.     }
63.   }
64.   //mm.addFrame();
65. }
66. void keyPressed() {
67.   if (key == DELETE || keyCode == 8) {
68.     pixelwords = "";
69.   } else {
70.     pixelwords = pixelwords + key;
71.   }
72.   particles.clear();
73.   z = 0;
74. }
75. class Particle {
76.   PVector or;
77.   PVector loc;
78.   PVector vel;
79.   PVector acc;
80.   float ms;
81.   float distance;
82.   Particle(PVector a, PVector v, PVector l, PVector o, float ms_) {
83.     acc = a;
84.     vel = v;
85.     loc = l;
86.     ms = ms_;
87.     or = o;
88.   }
89.   void run() {
90.     update();
91.     render();
92.   }
93.   void update() {
94.     vel.add(acc);
95.     loc.add(vel);
96.     acc = new PVector();
97.   }
98.  
99.   void render() {
100.     stroke(1, 100, random(50,100));  //Black Pixes  stroke(1, 100, 0);
     
101.     point(loc.x,loc.y);
102.   }
103.  
104.  void add_force(PVector force) {
105.     force.div(ms);
106.     vel.add(force);
107.   } 
108.  
109.  float getMass() {
110.     return ms;
111.   } 
112.  
113.   PVector getLocation() {
114.     return loc;
115.   }
116.   PVector getOrigin() {
117.     return or;
118.   }
119.   PVector getVelocity() {
120.     return vel;
121.   }
122.   void setLocation(PVector l){
123.     loc = l;   
124.   }
125.   void setAcceleration(PVector a){
126.     acc = a;
127.   }
128. }

Hey this is great thanks very much for your time and input. The original creator got back to me with another version, both are great and really close to what i was looking for. I had one other question regarding the system. Currently on the new key pressed it refreshes the particle system. Is it possible for the text to reform out of the remnants of the old text, this is pretty hard to explain in words sorry. In the original program when the key is not being pressed the particles start to float away. I would like to implement it so that the particles reform the new word. The current version is perfectly fine for the presentation i'm just interested to see how it works. Thanks again for your help and could you please send me an email to the above address with your full name for referencing/credit.

This is what i have so far 

1. class Particle {
     PVector or;
     PVector loc;
     PVector vel;
     PVector acc;
     float ms;
     float distance;
   
     Particle(PVector a, PVector v, PVector l, PVector o, float ms_) {
       acc = a;
       vel = v;
       loc = l;
       ms = ms_;
       or = o;
     }
   
     void run() {
       update();
       render();
     }
   
     void update() {
       vel.add(acc);
       loc.add(vel);
       acc = new PVector();
     }
    
     void render() {
       stroke(0);
       point(loc.x,loc.y);
     }
    
    void add_force(PVector force) {
       force.div(ms);
       vel.add(force);
     } 
    
    float getMass() {
       return ms;
     } 
    
     PVector getLocation() {
       return loc;
     }
     PVector getOrigin() {
       return or;
     }
     PVector getVelocity() {
       return vel;
     }
     void setLocation(PVector l){
       loc = l;   
     }
   
     void setAcceleration(PVector a){
       acc = a;
     }
   }
   
   ArrayList particles = new ArrayList();
   PFont ff;
   PImage ww;
   String[] sentence = new String[3];
   Particle prt;
   PVector origin;
   
   void setup()
   {
     size(800, 600,P3D);
     ff = loadFont("trade.vlw");
    
     sentence[0] = "Interactive";
     sentence[1] = "Dynamic";
     sentence[2] = "Typography";
    
   
   }
   
   void draw()
   {
     background(255);
     //println(particles.size());
     moveYa();
   }
   
   PImage crImage(String s)
   {
     PGraphics pg = createGraphics(800,160,JAVA2D);
     pg.beginDraw();
     pg.background(255);
     pg.fill(250);
     pg.textAlign(CENTER);
     pg.textFont(ff, 32);
     pg.text(s, 0, 0, 800, 160);
     pg.endDraw();
     PImage w = createImage(800,160,RGB);
     copy(pg, 0, 0, 800, 160, 0, 0, 800, 160);
     return w;
   }
   
   void scan()
   {
     particles.clear();
     for(int x = 0; x < ww.width; x++) {
       for(int y = 0; y < ww.height; y++) {
         if(get(x,y) != -65794){
         origin = new PVector(x, y+200, 0);
         PVector a = new PVector();
         PVector v = new PVector();       
         PVector l = new PVector(random(width), random(height) , 0);
           particles.add(new Particle(a,v,l, origin, random(0.05f, 2.0f)));
         }
       }
      }
   }
   
   void moveYa(){
     if(particles.size() <= 0)
       return;
      for (int h = 0; h<particles.size()-1; h++){
       
       prt = (Particle) particles.get(h);
       prt.run();
       PVector actualVel = prt.getVelocity();
       PVector attrito = PVector.mult(actualVel,-0.05);
       prt.add_force(attrito);
      
       PVector origLoc = prt.getOrigin();
       PVector diff = PVector.sub(origLoc,prt.getLocation());
       diff.normalize();
       float factor = 0.5f; 
       diff.mult(factor);
       prt.setAcceleration(diff);
    
   
       if(mousePressed) { 
         PVector mouseLoc = new PVector(mouseX, mouseY, 0);
         PVector diff2 = PVector.sub(mouseLoc,prt.getLocation());
         diff2.normalize();
         float factor2 = 1.0f; 
         diff2.mult(factor2);
         prt.setAcceleration(diff2);
       }
      
     }
    
   }
   
   void keyPressed()
   {
        if (key == 'a' || key == 'A')
       {
         ww = crImage(sentence[0]);
         scan();
       }
        if (key == 'b' || key == 'B')
       {
          ww = crImage(sentence[1]);
          scan();
       }   
        if (key == 'c' || key == 'C')
       {
          ww = crImage(sentence[2]);
          scan();
       }   
   }
   

Something like this perhaps..

1. void scan()
2. {
3.   //particles.clear();
4.   boolean firstrun = true;
5.   if (particles.size() > 1) {
6.     firstrun = false;
7.   }
8.   int count = 0;
9.   for(int x = 0; x < ww.width; x++) {
10.     for(int y = 0; y < ww.height; y++) {
11.       if(get(x,y) != -65794) {
12.         origin = new PVector(x, y+200, 0);
13.         PVector a = new PVector();
14.         PVector v = new PVector();      
15.         if (firstrun) {
16.           PVector l = new PVector(random(width), random(height), 0);
17.           particles.add(new Particle(a,v,l, origin, random(0.05f, 2.0f)));
18.         }
19.         else {
20.           if (count < particles.size()) {
21.             Particle prt = (Particle) particles.get(count);
22.             prt.or = origin;
23.           }
24.           else {
25.             PVector l = new PVector(width/2, height/2-100, 0);
    
26.             particles.add(new Particle(a,v,l, origin, random(0.05f, 2.0f)));
27.           }
28.         }
29.         count++;
30.       }
31.     }
32.   }
33.   while (particles.size() > count) {
34.     particles.remove(particles.size() - 1);
35.   }
36. }

Note: I updated the scan() code above to provide better placement of incoming pixels for additional characters when the word is changed.  So they're only randomly placed when the first word is created, after that it creates new pixels for additional characters close to the top center of the word.

Wow this is spot on, i cannot thank you enough. I am still unsure as to where the colour data is stored but i will play around with it a little, thanks again this has been really great of you.

Hi,
I uploaded a new version of WAP.
Press keys a,b,c,d,e to morph between the sentences.
http://www.openprocessing.org/visuals/?visualID=16766

GC

Very cool :-)