Help with Object Oriented Programming

Programming Questions

zombience

Help with Object Oriented Programming

in Programming Questions • 1 year ago

Hello, I am just learning to write sketches using OOP and I'm not quite sure how to implement the patch.

I have read the Object tutorial here on processing.org, and I've also read the OOP chapter out of Ira Greenberg's processing book. I get the concepts of OOP, but the specific implementation is baffling me.

I took a procedural patch I had written and attempted to rewrite it in OOP format. I've wrangled it such that the compiler doesn't complain at all, but when I run the sketch it just outputs a blank screen.

What I don't quite get is how to pass variables to constructors, how to write other methods that modify specific variables of constructors, etc.

In this patch I am trying to write a curve that follows the mouse cursor, and the cursor would also have a circle around it. I'd like to be able to modify the control point variables and have them constantly updating with a random() function or some similar thing. Currently, all I get is a black screen.

What am I missing here?

import processing.opengl.*;
Tentacle t1;
void setup()
{
size(screen.width, screen.height, OPENGL);
//background(0);
t1 = new Tentacle(100, 100, 0, 0, mouseX, mouseY, 600, 600);
}
void draw(){
background(0);
stroke(255);
strokeWeight(10);
fill(150, 20, 180, 80);
smooth();
t1.crv();
t1.circle(50);
}
class Tentacle{
float cx1, cy1, x1, y1, x2, y2, cx2, cy2, modX, modY, c;
Tentacle(float cx1, float cy1, float x1, float y1, float x2, float y2, float cx2, float cy2){
this.cx1 = cx1; //control point
this.cy1 = cy1;
this.x1 = x1; //curve startpoint
this.y1 = y1;
this.x2 = x2; //curve endpoint
this.y2 = y2;
this.cx2 = cx2; //2nd control point
this.cy2 = cy2;
}
//curve properties
void crv(){
curve(this.cx1, this.cy1, this.x1, this.y1, this.x2, this.y2, this.cx2, this.cy2);
}
void circle(float c){
this.c = c;
this.x2 = x2;
this.y2 = y2;
ellipse(this.c, this.c, this.x2, this.y2);
}
}

Replies(14)

Chrisir

Re: Help with Object Oriented Programming

1 year ago

like this..............

Remember: when calling the constructor ( t1 = new Tentacle( etc. ) the constructor gets variables ( 550, -2340, 222, 520, etc. ). I marked them in the constructor with a leading underscore which is this sign: _ .
Thus the constructor starts like this:

Tentacle(float _cx1, float _cy1, float _x1, float _y1, float _x2, float _y2, float _cx2, float _cy2)....

Those are passed to the variables of the class (same witout the underscore _ ).
In your program they had the same name. Doesn't work.
BTW: "this" is not needed.
Troughout the class its variables such as cx are known and can be used.

import processing.opengl.*;
Tentacle t1;
void setup()
{
size(screen.width, screen.height, OPENGL);
//background(0);
t1 = new Tentacle(550, -2340,
222, 520,
500, 520,
-1530, -2630);
}
void draw() {
background(0);
stroke(255);
strokeWeight(10);
fill(150, 20, 180, 80);
smooth();
//t1.x1=pmouseX;
//t1.y1=pmouseY;
t1.x2=mouseX;
t1.y2=mouseY;
t1.crv();
t1.circle(50);
}
// ===============================================================================
class Tentacle {
float cx1, cy1, x1, y1, x2, y2, cx2, cy2, modX, modY, c;
Tentacle(float _cx1, float _cy1, float _x1, float _y1, float _x2, float _y2, float _cx2, float _cy2) {
cx1 = _cx1; //control point
cy1 = _cy1;
x1 = _x1; //curve startpoint
y1 = _y1;
x2 = _x2; //curve endpoint
y2 = _y2;
cx2 = _cx2; //2nd control point
cy2 = _cy2;
}
//curve method
void crv() {
stroke(255, 102, 0);
curve(cx1, cy1, x1, y1, x2, y2, cx2, cy2);
}
//circle method
void circle(float c) {
stroke(33);
ellipse(x2, y2, c, c);
}
}

Greetings, Chrisir

Chrisir

Re: Help with Object Oriented Programming

1 year ago

from there you can go now anywhere............................................................

// import processing.opengl.*;
Tentacle t1;
// border
final int leftIndentText = -10;
PVector helpPoint; // Point #1
PVector helpPoint2; // Point #2
PVector helpPointAdd; // vector for moving Point #1
PVector helpPoint2Add; // vector for moving Point #2
void setup() {
size( screen.width, screen.height );
t1 = new Tentacle(550, -2340,
222, 520,
500, 520,
-1530, -2630);
initPointsForLine() ;
} // func
void draw() {
// background(0);
stroke(255);
strokeWeight(10);
fill(150, 20, 180, 80);
smooth();
if (keyPressed) {
initPointsForLine();
}
if (mousePressed && (mouseButton == RIGHT)) {
background(random(255), random(255), random(255));
}
checkHelpPointsForLine();
t1.cx1=pmouseX*10;
t1.cy1=pmouseY*10;
t1.cx1+=random(-12, 12);
t1.cy1+=random(-12, 12);
t1.x1=helpPoint.x;
t1.y1=helpPoint.y;
t1.x2=helpPoint2.x;
t1.y2=helpPoint2.y;
t1.crv();
// t1.circle(50);
} // func
// ----------------------------------------------------------------------
void initPointsForLine() {
// invisible help points
helpPoint = new PVector(random(leftIndentText+203, leftIndentText+299), 440);
helpPoint2 = new PVector(random(leftIndentText+203, leftIndentText+299), 460);
int speed = 9;
helpPointAdd = new PVector(random(-speed, speed), random(-speed, speed));
helpPoint2Add = new PVector(random(-speed, speed), random(-speed, speed));
}
void checkHelpPointsForLine() {
//
helpPoint.add(helpPointAdd);
helpPoint2.add(helpPoint2Add);
// check helpPoint ----------------------------
if (helpPoint.x<leftIndentText)
{
helpPointAdd.x=abs(helpPointAdd.x);
}
if (helpPoint.x>width) {
helpPointAdd.x=-1*abs(helpPointAdd.x);
}
if (helpPoint.y<0)
{
helpPointAdd.y=abs(helpPointAdd.y);
}
if (helpPoint.y>=height) {
helpPointAdd.y=-1*abs(helpPointAdd.y);
}
// check helpPoint2 ----------------------------
if (helpPoint2.x<leftIndentText)
{
helpPoint2Add.x=abs(helpPoint2Add.x);
}
if (helpPoint2.x>width) {
helpPoint2Add.x=-1*abs(helpPoint2Add.x);
}
if (helpPoint2.y<0)
{
helpPoint2Add.y=abs(helpPoint2Add.y);
}
if (helpPoint2.y>screenHeight) {
helpPoint2Add.y=-1*abs(helpPoint2Add.y);
}
} // func
// ----------------------------------------------------------
// ===============================================================================
class Tentacle {
float cx1, cy1, x1, y1, x2, y2, cx2, cy2, modX, modY, c;
Tentacle(float _cx1, float _cy1, float _x1, float _y1, float _x2, float _y2, float _cx2, float _cy2) {
cx1 = _cx1; //control point
cy1 = _cy1;
x1 = _x1; //curve startpoint
y1 = _y1;
x2 = _x2; //curve endpoint
y2 = _y2;
cx2 = _cx2; //2nd control point
cy2 = _cy2;
} // constructor
//curve method
void crv() {
stroke(255, 102, 0);
curve(cx1, cy1, x1, y1, x2, y2, cx2, cy2);
} // func
//circle method
void circle(float c) {
stroke(33);
ellipse(x2, y2, c, c);
} // func
} // class

Chrisir

zombience

Re: Re: Help with Object Oriented Programming

1 year ago

Thank you so much for the help! I was confused about how exactly to declare variables and then to access them later.

Mostly because in the tutorials they were giving abstract conceptual examples, and not concrete point-based/math examples that I could copy and 'break' to see how it works.

I see now where I was confused, and your second example is a great help to show me how to put different pieces together to form one whole.

I greatly appreciate it!

allonestr..

Re: Help with Object Oriented Programming

1 year ago

For completeness, I would have defined the class as you did from line 25 to 37:

class SomeClass

{

float float1, float2;

int int1, int2;

SomeClass(float float1, float float2, int int1, int int2)

{

this.float1 = float1;

this.float2 = float2;

this.int1 = int1;

this.int2 = int2;

}

--functions--

}

as I can't see the point of giving something two different names, but wouldn't have used "this" elsewhere in the class.

zombience

Re: Help with Object Oriented Programming

1 year ago

So, is the idea behind

aVariable = _aVariable;

and

aVariable = this.aVariable;

entirely preference, or is there a syntactical difference between the two?

allonestr..

Re: Help with Object Oriented Programming

1 year ago

It's the other way around, and I don't think that there's a difference.

SomeClass(float someFloat)

{

this.someFloat = someFloat;

}

zombience

Re: Help with Object Oriented Programming

1 year ago

wait wait wait...

NOW i'm confused again!

Chrisir above explicitly mentioned that I was assigning them the wrong way, the way you're telling me now?

He had corrected my code to appear like this:

class Tentacle {
float cx1, cy1, x1, y1, x2, y2, cx2, cy2, modX, modY, c;
Tentacle(float _cx1, float _cy1, float _x1, float _y1, float _x2, float _y2, float _cx2, float _cy2) {
cx1 = _cx1; //control point
cy1 = _cy1;
x1 = _x1; //curve startpoint
y1 = _y1;
x2 = _x2; //curve endpoint
y2 = _y2;
cx2 = _cx2; //2nd control point
cy2 = _cy2;

}

so that the assignments were going

aVariable = _aVariable;

but above, you're telling me I should be doing:

_aVariable = aVariable;

this.aVariable = aVariable

is that right?

I would like to make sure I'm getting this right! Thank you for the help

Chrisir

Re: Help with Object Oriented Programming

1 year ago

When you look at
http://www.processing.org/learning/objects/

The constructor must be rewritten to incorporate these arguments:

Car(color tempC, float tempXpos, float tempYpos, float tempXspeed)
{
c = tempC;
xpos = tempXpos;
ypos = tempYpos;
xspeed = tempXspeed;
}



umh... different variable names there, no this...

I don't see any advantage or disadvantage in both solutions.

zombience

Re: Help with Object Oriented Programming

1 year ago

Hmm. Still confused. I do know that I switched out the variable assignments in my patch to reflect what Chrisir had written above, and it worked. Perhaps it was other parts of the patch that I changed as well, but it all works now. I'm going to stick with that because at least I know it works.

However, for future knowledge, I would like to know what is causing this confusion.

I guess with more experience I'll understand

Chrisir

Re: Help with Object Oriented Programming

1 year ago

I like it, a lttle bit of theoretical work going on...

Indeed I was wrong when I wrote your way in your constructor was wrong. It wasn't. That was what allonestring was aiming at - and he was right!

It was my fault. You can write

this.cx1 = cx1; //control point
this.cy1 = cy1;
this.x1 = x1; //curve startpoint

etc. - I didn't know that. You had that right.

It's

aVariable = _aVariable;

this.aVariable = aVariable;

Your error in the code wasn't here but probably in your calling up the constructor

t1 = new Tentacle(100, 100, 0, 0, mouseX, mouseY, 600, 600);

and in the method circle().

The general thinking is:
You got a var in your class and you want to set the value of it.
Hence you call the constructor with a parameter to give that as a value to your var.
After the constructor is left by the program, the parameter is gone. Therefore, in the constructor you
want to make the parameter persistent and therefore push the parameter in the var of your class.
(The parameter is what you give to the constructor or function in brackets: SomeClass(float someFloat).)

In class SomeClass with a var someFloat you can write:

SomeClass(float someFloat)
{
this.someFloat = someFloat;
}

remember: what is left from the sign "=" gets/receives the value (the variable of the class). What is right from the sign gives its value (the parameter).

Therefore the word "this" refers to the class and makes sure the var "someFloat" of the class gets the given parameter "someFloat" that you call with the constructor.

Good way to do it is similar and equally:

SomeClass(float tempSomeFloat)
{
someFloat = tempSomeFloat;
}

to emphasize that the parameter will vanish after the constructor has ended (temp = it's temporary).

others write

SomeClass(float _someFloat)
{
someFloat = _someFloat;
}

which I use but find kind of too short.

Anyway: When you don't have the word "this", make sure the parameter of the constructor has another name than the var in the class...

zombience

Re: Help with Object Oriented Programming

1 year ago

aha! I see, so whether the constructor's variable is on the left or the right of the assignment basically determines whether it is a persistent variable particular to that object that can be referenced again later, OR whether it's just a temporary value that is called once and forgotten in order to execute some function.

SO, this execution would indicate that the variables are assigned once upon executing the function and are then lost. This is assuming the function needs only to be called once to operate on variables that are handed to it every time, and should in fact 'forget' the values of these variables?

class SomeClass(float var1 float var2){

      SomeClass(float _var1, float _var2){
      var1 = _var1;
      var2 = _var2;
}

Whereas in THIS execution

class SomeClass(float var1 float var2){

      SomeClass(float _var1, float _var2){
      _var1 = var1;
      _var2 = var2;
}

variables would be persistent, and next time I called for SomeClass.whatev(); the local variables would be remembered and could be iterated/manipulated/called or whatever was needed?

Do I understand you correctly? Sorry to be pedantic, but I really want to understand this clearly.
Thank you again for taking the time to explain this! This particular point didn't come across in the tutorials I've read so far on OOP.

Chrisir

Re: Help with Object Oriented Programming

1 year ago

Hello,

Well, maybe it is because of the language barriere on my side but being very pedantic indeed, your description is not accurate.

Are you familiar with the concept of giving parametes (variables like your _var1 with underscore) to a function (a function within a class is called a method)? Those parameters are always only valid within the function (or in our case within the constructor). This is true whether the constructor's parameter is on the left or the right of the assignment - other than said in your 1st paragraph - because when there's no assignment at all, the parameters are still known within the function.
The expression "the constructor's variable" you use I find not clear - it is either the parameter for the constructor (aka _var1) or the variable of the class (var1).

The point is, _var1 is un-persistent because it is a parameter.
Its value doesn't belong to the class yet.
To make it part of the class you have to push it into the class variable - you use the assignment to do so, which has the receiving element on its left side (that's changing):

      SomeClass(float _var1, float _var2){
      var1 = _var1;
      var2 = _var2;
      }

Thus the initial values of the parameters _var1 etc. become persistent in the class as var1. We want that!

BTW
you wouldn't write this:

class SomeClass(float var1 float var2){
SomeClass(float _var1, float _var2){
var1 = _var1;
var2 = _var2;
}
}

but better

class SomeClass {
float var1;
float var2;
SomeClass(float _var1, float _var2){
var1 = _var1;
var2 = _var2;
}
}

Then you write:

SomeClass(float _var1, float _var2){
_var1 = var1;
_var2 = var2;
variables would be persistent, and next time I called for SomeClass.whatev(); the local variables would be remembered and could be iterated/manipulated/called or whatever was needed?

Nope, not at all! Wrong.

To have the parameter on the left side doesn't make any sense I am afraid. Right solution see above (_var1 must be right of the sign = ; test it).

You might want to look at this again:

// Even though there are multiple objects, we still only need one class. 
// No matter how many cookies we make, only one cookie cutter is needed.
class Car { 
  color c;
  float xpos;
  float ypos;
  float xspeed;

  // The Constructor is defined with arguments.
  Car(color tempC, float tempXpos, float tempYpos, float tempXspeed) { 
    c = tempC;
    xpos = tempXpos;
    ypos = tempYpos;
    xspeed = tempXspeed;
  }

This is from
http://www.processing.org/learning/objects

Sorry to bother you with this stuff but I think with some of your assumptions, your code might not work as expected.
Please ask again when you like.

Greetings, Chrisir

zombience

Re: Help with Object Oriented Programming

1 year ago

Thank you so much! It is not a bother at all, I definitely was looking to clarify my thinking, so, thank you for pointing out my misconception so clearly.

Ok, I will go happily into the future and create classes with this knowledge

Chrisir

Re: Help with Object Oriented Programming

1 year ago

you are welcome

Top Reply