problem solved.thanks

Programming Questions

hellofish

in Programming Questions • 2 years ago

Hi, firstly thank you all for helping me out . I changed my code and posted below.

But new problem came...T^T

My palyerFish eats smaller enemyfish and grows size each time it eats now, but to some kind of enemyfish, Playerfish doest eat, even it is smaller than my playerfish..Maybe something wrong with my collision? Also, I set my palyer fish same as Enemyfish with random sizes..but sometime it is too random that my player fish is soooo small and cant eat any other fishes..

2.I need my playerfish dead and spawn at the bottom of the screen..how can I do that?

3. When the enemyFish is eaten I need to show eating traces for a period of time before the enemyFish is removed.

Teacher gave some hint on this:
"This means that the playerFish should stop colliding with the enemyFish, you can do this by setting a boolean in the enemyFish to false, and once false the playerFish should NOT be checking it's collision with the enemyFish.

When the enemyFish is eaten, you can set an int to equal some number of frames which the traces will remain on screen. If your enemyFish boolean is false, you can call a dead method in your enemyFish class. The method should look like this:

void dead() {
if (traceTimer > 0) {
traceTimer--; //decrement the trace timer so that it will eventually == 0
y += 2; //traces will sink to the bottom
} else {
fishList.remove(this); //remove the current enemyFish with a traceTimer < 0
spawnNewEnemyFish(); //your enemyFish respawn method
}
}

He says my eat method should change to this:

void eat(Fish other) {
if (fWidth > other.fWidth) {

fishScale *= 1.1;
fWidth = bSize * fishScale;
//change this next line so that the other fish alive is false
//and do the traces before removing from the arrayList
fishList.remove(other);
}
else {
//change this next line so that the alive is false
//and do the traces, call dead method from main draw loop
player.dead();
}
}

But I am still confusing

Here are my codes:

int numFishes = 8;
ArrayList<EnemyFish> fishList = new ArrayList<EnemyFish>();
PlayerFish player;
boolean keyUp, keyDown, keyLeft, keyRight;

void setup() {
size(800, 800);
player = new PlayerFish();
noStroke();
for (int i = 0; i < numFishes; i++) {
fishList.add(new EnemyFish());
}
keyUp = keyDown = keyLeft = keyRight = false;
}

void keyPressed() {
if (key == 'w') keyUp = true;
if (key == 's') keyDown = true;
if (key == 'a') keyLeft = true;
if (key == 'd') keyRight = true;
}

void keyReleased() {
if (key == 'w') keyUp = false;
if (key == 's') keyDown = false;
if (key == 'a') keyLeft = false;
if (key == 'd') keyRight = false;
}

void draw() {
background(62, 188, 202);
fill(62, 188, 202, 60);

if (keyUp) player.update(0, -1);
if (keyDown) player.update(0, 1);
if (keyLeft) player.update(-1, 0);
if (keyRight) player.update(1, 0);

player.update();
player.walls();
player.drawMe();

for (int i = 0; i < fishList.size(); i++) {
EnemyFish fishi = fishList.get(i);

if (fishi.alive) {
if (player.collision(fishi) && player.headOn(fishi)) {
player.eat(fishi);
}

for (int j = i+1; j < fishList.size(); j++) {
EnemyFish fishj = fishList.get(j);
if ( fishi.collision( fishj )) { //GeneralFish collision method
fishi.bounce( fishj ); //bounce the fish
}
}//for j

fishi.update();
fishi.walls(fishList);
} else {
fishi.dead();
}
fishi.drawMe();

}//for i
}//for draw

class Fish {
float x, y, velX, velY, fishScale, fWidth;
int bSize;
color c;

Fish() {
x = random(width);
y = random(height);
velX = random(-2, 2);
velY = random(-2, 2);
bSize = 150;
fishScale = random(0.3, 0.9);
fWidth = bSize * fishScale;
}

//a method for collision
boolean collision(Fish other) {
return dist(x, y, other.x, other.y) < fWidth/2 + other.fWidth/2;
}

void update() {
x += velX;
y += velY;
}

void dead(){
} // To be defined

}//class

class PlayerFish extends Fish {

PlayerFish() {
super();
fishScale = random(0.3, 0.9);
}

void update() {
velX *= 0.92;
velY *= 0.92;
super.update();
}

void update(float xDir, float yDir) {
velX += xDir;
velY += yDir;
}

boolean headOn(Fish other) {
return velX > 0 && other.velX < 0 || velX < 0 && other.velX > 0;
}

void eat(Fish other) {
if (fWidth > other.fWidth) {
fishScale *= 1.15;
other.dead();
} else {
player.dead();
}
}

void dead(){
fill(0,0,0);
rect(0,0,800,800);
}

void walls() {
//right wall
if (x > width - bSize/4) {
x = width - bSize/4;
velX *= -1;
}
//left wall
if (x < bSize/4) {
x = bSize/4;
velX *= -1;
}
//bottom wall
if (y > height - bSize/4) {
y = height - bSize/4;
velY *= -1;
}
//top wall
if (y < bSize/4) {
y = bSize/4;
velY *= -1;
}
}

void drawMe() {
pushMatrix();
translate(x, y);
scale(fishScale);

if (velX > 0) {
scale(-1, 1);
}

noStroke();
strokeWeight(1);
fill(255, 115, 85);

quad(-15, -20, 45, 0, -15, 30, -15, 30);
stroke(2);
fill(255, 115, 85);
curve(-100, 26, -15, -20, 45, 0, 73, 61);
curve(73, -50, 45, 0, -15, 30, 15, -25);
curve(600, -100, -15, -20, -15, 30, 73, -50);
triangle(45, 0, 55, 10, 65, -10);

noStroke();
fill(62, 188, 202);
// triangle(-20,15,-36,25,-56,0);
//eye
strokeWeight(1);
stroke(2);
fill(255, 255, 255);
ellipse(-25, 0, 15, 15);
fill(0, 0, 0);
ellipse(-25, 0, 8, 8);

popMatrix();
}
}//end class

class EnemyFish extends Fish {
float wave, waveSpeed, amp;
boolean alive;
int traceTimer;
int enemyBound;
color c;

EnemyFish() {
super();
alive= true;
wave = random(TWO_PI);
waveSpeed = random(0.1, 0.5);
amp = random(1, 4);
enemyBound=50;
fWidth = bSize * fishScale;
fishScale = random(0.3, 0.9);
c = color( random(255), random(10), 150);
}

EnemyFish(float xpos, float ypos, float velXa, float velYa) {
super();
x=xpos;
y=ypos;
velX=velXa;
velX=velYa;
alive= true;
wave = random(TWO_PI);
waveSpeed = random(0.1, 0.5);
amp = random(1, 4);
enemyBound=50;
fWidth = bSize * fishScale;
c = color( random(255), random(10), 150);
}

void update() {
wave += waveSpeed;
y += amp*sin(wave);
super.update();
}

void bounce(Fish other) {
float angle = atan2(y - other.y, x - other.x);
velX = 2 * cos(angle);
velY = 2 * sin(angle);
other.velX = 2 * cos(angle - PI);
other.velY = 2 * sin(angle - PI);
}

void dead() {
if (traceTimer > 0) {
traceTimer--;
y +=2;
} else {
fishList.remove(this);
spawnNewEnemyFish(fishList);
}
}

void spawnNewEnemyFish(ArrayList fishList) {
if (random(0, 2) < 1) {
fishList.add(new EnemyFish(-25, random(100, height-100), random(1, 4), random(-2, 2)));
} else {
fishList.add(new EnemyFish(width+25, random(100, height-100), random(-1, -4), random(-2, 2)));
}
}

//change this method for enemyFish wall collision
void walls(ArrayList fishList) {
//right wall
if (x > width + enemyBound) {
fishList.remove(this);
spawnNewEnemyFish(fishList);
}

if ( x <- enemyBound) {
fishList.remove(this);
spawnNewEnemyFish(fishList);
}
//bottom wall
if (y > height - bSize/4) {
y = height - bSize/4;
velY *= -1;
}
//top wall
if (y < bSize/4) {
y = bSize/4;
velY *= -1;
}
}

void drawMe() {
pushMatrix();
translate(x, y);
scale(fishScale);
if (velX<0) {
scale(-1, 1);
}

//fish
fill(c);
arc(30, 0, 60, 30, -PI/2, PI/2);
quad(30, -15, 30, 15, -50, 5, -50, -19);
quad(-50, -10, -50, 5, -70, 10, -69, 8);
stroke(3);
noFill();
curve(300, 100, 35, -15, -70, 35, 100, 270);
fill(0, 0, 0);
ellipse(40, -5, 6, 6);//eye
fill(229, 190, 157);
triangle(-66, 35, -40, 50, -40, 60);//tail
triangle(-70, 33, -40, 70, -40, 90);//tail

triangle(30-10, 30-16, 30-40, 30-20, 30-35, 30-10);//down fin

curve(30-20, 50, 30-80, 30-40, -30, 30-48, 30+20, 30+20);
curve(30*0, 0, 30-53, 30-48, 30-40, 30-48, 30, 30+10);

popMatrix();
}
}

Replies(9)

PhiLho

Re: HELP with my FISH game! thank you!!!!

2 years ago

Some problems:
- you forgot to give an fWidth to the enemy fishes
- you forgot to call dead() when fishes are eaten.

I fixed some minor things as well, so I give here my version. A finer collision algorithm should be designed...
Ah, I also used the arrow keys, as wsad is just too impractical on my French keyboard...

int numFishes = 7;
ArrayList<EnemyFish> fishList = new ArrayList<EnemyFish>();
PlayerFish player;
boolean keyUp, keyDown, keyLeft, keyRight;
void setup() {
size(600, 600);
player = new PlayerFish();
noStroke();
for (int i = 0; i < numFishes; i++) {
fishList.add(new EnemyFish());
}
keyUp = keyDown = keyLeft = keyRight = false;
}
void keyPressed() {
if (key == CODED) {
switch (keyCode) {
case UP: keyUp = true; break;
case DOWN: keyDown = true; break;
case LEFT: keyLeft = true; break;
case RIGHT: keyRight = true; break;
}
}
}
void keyReleased() {
if (key == CODED) {
switch (keyCode) {
case UP: keyUp = false; break;
case DOWN: keyDown = false; break;
case LEFT: keyLeft = false; break;
case RIGHT: keyRight = false; break;
}
}
}
void draw() {
background(62, 188, 202);
fill(62, 188, 202, 60);
if (keyUp) player.update(0, -1);
if (keyDown) player.update(0, 1);
if (keyLeft) player.update(-1, 0);
if (keyRight) player.update(1, 0);
player.update();
player.walls();
player.drawPlayer();
for (int i = 0; i < fishList.size(); i++) {
EnemyFish fishi = fishList.get(i);
if (fishi.alive) {
if (player.collision(fishi) && player.headOn(fishi)) {
player.eat(fishi);
}
for (int j = i+1; j < fishList.size(); j++) {
EnemyFish fishj = fishList.get(j);
if ( fishi.collision( fishj )) { //GeneralFish collision method
fishi.bounce( fishj ); //bounce the fish
}
}//for j
fishi.update();
fishi.walls();
} else {
fishi.dead();
}
fishi.drawMe();
}//for i
}//for draw
abstract class Fish {
float x, y, velX, velY, fishScale, fWidth;
int bSize;
color c;
Fish() {
x = random(width);
y = random(height);
velX = random(-2, 2);
velY = random(-2, 2);
bSize = 150;
fishScale = random(0.3, 0.9);
fWidth = bSize * fishScale;
}
//a method for collision
boolean collision(Fish other) {
return dist(x, y, other.x, other.y) < fWidth/2 + other.fWidth/2;
}
void update() {
x += velX;
y += velY;
}
abstract void dead(); // To be defined
}//class
class PlayerFish extends Fish {
PlayerFish() {
super();
c = color(0, 0, 255);
}
void update() {
velX *= 0.92;
velY *= 0.92;
super.update();
}
void update(float xDir, float yDir) {
velX += xDir;
velY += yDir;
}
boolean headOn(Fish other) {
return velX > 0 && other.velX < 0 || velX < 0 && other.velX > 0;
}
void eat(Fish other) {
if (fWidth > other.fWidth) {
fWidth = bSize * 1.1;
other.dead();
} else {
player.dead();
}
}
void dead(){
y+=4;
}
void walls() {
//right wall
if (x > width - bSize/4) {
x = width - bSize/4;
velX *= -1;
}
//left wall
if (x < bSize/4) {
x = bSize/4;
velX *= -1;
}
//bottom wall
if (y > height - bSize/4) {
y = height - bSize/4;
velY *= -1;
}
//top wall
if (y < bSize/4) {
y = bSize/4;
velY *= -1;
}
}
void drawPlayer() {
pushMatrix();
translate(x, y);
if (velX > 0) {
scale(-1, 1);
}
noStroke();
strokeWeight(1);
fill(255, 115, 85);
quad(0, -20, 60, 0, 0, 30, 0, 30);
stroke(2);
fill(255, 115, 85);
curve(bSize-250, 26, 0, -20, 60, 0, 73, 61);
curve(73, -50, 60, 0, 0, 30, 15, -25);
curve(600, -100, 0, -20, 0, 30, 73, -50);
triangle(60, 0, 70, 10, 80, -10);
popMatrix();
}
}//end class
class EnemyFish extends Fish {
float wave, waveSpeed, amp;
boolean alive;
int traceTimer;
int enemyBound;
EnemyFish() {
super();
alive= true;
wave = random(TWO_PI);
waveSpeed = random(0.1, 0.4);
amp = random(1, 4);
enemyBound=50;
}
EnemyFish(float xpos, float ypos, float velXa, float velYa) {
super();
x=xpos;
y=ypos;
velX=velXa;
velX=velYa;
alive= true;
wave = random(TWO_PI);
waveSpeed = random(0.1, 0.5);
amp = random(1, 4);
fishScale=random(0.3, 0.9);
enemyBound=50;
}
void update() {
wave += waveSpeed;
y += amp*sin(wave);
super.update();
}
void bounce(Fish other) {
float angle = atan2(y - other.y, x - other.x);
velX = 2 * cos(angle);
velY = 2 * sin(angle);
other.velX = 2 * cos(angle - PI);
other.velY = 2 * sin(angle - PI);
}
void dead() {
if (traceTimer > 0) {
traceTimer--;
y +=2;
} else {
fishList.remove(this);
spawnNewEnemyFish(fishList);
}
}
void spawnNewEnemyFish(ArrayList fishList) {
if (random(0, 2) < 1) {
fishList.add(new EnemyFish(-25, random(100, height-100), random(1, 4), random(-2, 2)));
} else {
fishList.add(new EnemyFish(width+25, random(100, height-100), random(-1, -4), random(-2, 2)));
}
}
//change this method for enemyFish wall collision
void walls() {
//right wall
if (x > width - bSize/4) {
x = width - bSize/4;
velX *= -1;
}
//left wall
if (x < bSize/4) {
x = bSize/4;
velX *= -1;
}
//bottom wall
if (y > height - bSize/4) {
y = height - bSize/4;
velY *= -1;
}
//top wall
if (y < bSize/4) {
y = bSize/4;
velY *= -1;
}
}
void drawMe() {
pushMatrix();
translate(x, y);
if (velX<0) {
scale(-1, 1);
}
scale(fishScale);
//fish
fill(0,255,255);
arc(30, 0, 60, 30, -PI/2, PI/2);
quad(30, -15, 30, 15, -50, 5, -50, -19);
quad(-50, -10, -50, 5, -70, 10, -69, 8);
noFill();
stroke(2);
curve(300, 100, 35, -15, -70, 35, 100, 270);
curve(300, 100, 30, -10, -70, 35, 100, 270);
curve(300, 100, 30, -5, -70, 35, 100, 270);
curve(300, 100, 30, 0, -70, 35, 100, 270);
curve(300, 100, 30, 5, -70, 35, 100, 270);
curve(300, 100, 30, 10, -70, 35, 100, 270);
curve(300, 100, 30, 15, -70, 35, 100, 270);
fill(0, 0, 0);
ellipse(40, -5, 6, 6);//eye
fill(229, 190, 157);
triangle(-66, 35, -40, 50, -40, 60);//tail
triangle(-70, 33, -40, 70, -40, 90);//tail
triangle(30-10, 30-16, 30-40, 30-20, 30-35, 30-10);//down fin
curve(30-20, 50, 30-80, 30-40, -30, 30-48, 30+20, 30+20);
curve(30*0, 0, 30-53, 30-48, 30-40, 30-48, 30, 30+10);
popMatrix();
}
}

hellofish

Re: Re: HELP with my FISH game! thank you!!!!

2 years ago

Thank you for help...and here came up some new problems..

Can you please help?

I updated my post

Thank you

fiveagon

Re: HELP with my FISH game! thank you!!!!

2 years ago

Again with the post deleting ...

mbraendle

Re: HELP with my FISH game! thank you!!!!

2 years ago

Yes, deleting the earlier question that you posted yesterday and all the answers was RUDE to all the people that helped you.

I expect an explanation and an excuse!

hellofish

Re: Re: HELP with my FISH game! thank you!!!!

2 years ago

Sorry for deleted my order post.....

PhiLho

Re: HELP with my FISH game! thank you!!!!

2 years ago

Indeed, I see you made two identical threads with only the topic changing between them. I can't see the answers, alas, but if people answered you, it isn't nice for them to delete their answers as well, and it duplicates the efforts to help you. Please, try to stick to a thread, edit it if you need. You can bump the thread if needed, but don't multiply threads on the same topic. Thank you.

PhiLho

Re: HELP with fish tale game.

2 years ago

For the record: we got private messages apologizing for the deletion of the threads. I blame the unfamiliarity with forum etiquette, so we go on. And, no, current state of this forum doesn't allow to prevent such deletion. I can restore deleted threads, but I don't want to multiply identical threads either...

Also, the deletion of such threads was motivated by the fact, as often in this case, that it is a school work, and the person was afraid to get a bad grade for asking for help here.
I believe there are two kind of homework help asked here:
- the bad way, pasting the homework text and asking (more or less directly) to do the job for them. Of course, this is usually declined, in favor of asking to do some work first, and offering help on the difficult parts;
- the good way, as here, making most of the job, being blocked on some parts, asking for help on these parts.
It seems legitimate here, it is similar to ask for help for co-students or co-workers, it is part of real life coding activity.
Now, I recommend to ask the teacher first, perhaps giving similar explanations. If the teacher is firmly opposed to this practice... just don't do it, perhaps as to co-students. But I believe teachers shouldn't prohibit such behavior. But they can ask to see the threads...

I will go back to the problem later. Note: you should have kept the original code, to show the amount of original work you made when asking for help... Posting new code in an answer is OK here. If code is really long, one can use a site like pastebin.com or similar.

PhiLho

Re: HELP with fish tale game.

2 years ago

OK, I don't have time to address all questions, but I solved some issues. I still use my code where I injected your improvements. I recommend using a diff utility to see were I added improvements...
I remove the drawing code below just for brevity sake, you have to restore it.

int numFishes = 8;
ArrayList<EnemyFish> fishList = new ArrayList<EnemyFish>();
PlayerFish player;
boolean keyUp, keyDown, keyLeft, keyRight;
void setup() {
size(800, 800);
player = new PlayerFish();
noStroke();
for (int i = 0; i < numFishes; i++) {
fishList.add(new EnemyFish());
}
keyUp = keyDown = keyLeft = keyRight = false;
}
void keyPressed() {
if (key == CODED) {
switch (keyCode) {
case UP: keyUp = true; break;
case DOWN: keyDown = true; break;
case LEFT: keyLeft = true; break;
case RIGHT: keyRight = true; break;
}
}
}
void keyReleased() {
if (key == CODED) {
switch (keyCode) {
case UP: keyUp = false; break;
case DOWN: keyDown = false; break;
case LEFT: keyLeft = false; break;
case RIGHT: keyRight = false; break;
}
}
}
void draw() {
background(62, 188, 202);
fill(62, 188, 202, 60);
if (keyUp) player.update(0, -1);
if (keyDown) player.update(0, 1);
if (keyLeft) player.update(-1, 0);
if (keyRight) player.update(1, 0);
player.update();
player.walls();
player.draw();
for (int i = 0; i < fishList.size(); i++) {
EnemyFish fishi = fishList.get(i);
if (fishi.isAlive) {
if (player.collision(fishi) && player.headOn(fishi)) {
player.eat(fishi);
}
for (int j = i+1; j < fishList.size(); j++) {
EnemyFish fishj = fishList.get(j);
if (fishi.collision(fishj)) { //GeneralFish collision method
fishi.bounce(fishj); //bounce the fish
}
}//for j
fishi.update();
fishi.walls(fishList);
} else {
fishi.dead();
}
fishi.draw();
}//for i
}//for draw
abstract class Fish {
float x, y, velX, velY, fishScale, fWidth;
int bSize;
color c;
boolean isAlive;
Fish() {
x = random(width);
y = random(height);
velX = random(-2, 2);
velY = random(-2, 2);
bSize = 150;
fishScale = random(0.3, 0.9);
isAlive = true;
}
void updateSize() {
fWidth = bSize * fishScale;
}
//a method for collision
boolean collision(Fish other) {
return dist(x, y, other.x, other.y) < fWidth/2 + other.fWidth/2;
}
void update() {
x += velX;
y += velY;
}
void dead() { isAlive = false; }
abstract void draw(); // To be defined
}//class
class PlayerFish extends Fish {
PlayerFish() {
super();
fishScale = random(0.5, 0.9);
updateSize();
}
void update() {
velX *= 0.92;
velY *= 0.92;
super.update();
}
void update(float xDir, float yDir) {
velX += xDir;
velY += yDir;
}
boolean headOn(Fish other) {
return velX > 0 && other.velX < 0 || velX < 0 && other.velX > 0;
}
void eat(Fish other) {
if (fWidth > other.fWidth && other.isAlive) {
fishScale *= 1.15;
updateSize();
other.dead();
} else {
dead();
}
}
void dead(){
super.dead();
background(0);
}
void walls() {
//right wall
if (x > width - bSize/4) {
x = width - bSize/4;
velX *= -1;
}
//left wall
if (x < bSize/4) {
x = bSize/4;
velX *= -1;
}
//bottom wall
if (y > height - bSize/4) {
y = height - bSize/4;
velY *= -1;
}
//top wall
if (y < bSize/4) {
y = bSize/4;
velY *= -1;
}
}
void draw() {
pushMatrix();
translate(x, y);
scale(fishScale);
if (velX > 0) {
scale(-1, 1);
}
// [...]
}
}//end class
class EnemyFish extends Fish {
float wave, waveSpeed, amp;
int traceTimer;
int enemyBound;
color c;
EnemyFish() {
super();
wave = random(TWO_PI);
waveSpeed = random(0.1, 0.5);
amp = random(1, 4);
enemyBound = 50;
fishScale = random(0.3, 0.9);
updateSize();
c = color(random(255), random(10), 150);
traceTimer = 10;
}
EnemyFish(float xpos, float ypos, float velXa, float velYa) {
this();
x = xpos;
y = ypos;
velX = velXa;
velX = velYa;
}
void update() {
wave += waveSpeed;
y += amp*sin(wave);
super.update();
}
void bounce(Fish other) {
float angle = atan2(y - other.y, x - other.x);
velX = 2 * cos(angle);
velY = 2 * sin(angle);
other.velX = 2 * cos(angle - PI);
other.velY = 2 * sin(angle - PI);
}
void dead() {
super.dead();
if (traceTimer > 0) {
traceTimer--;
y += 2;
} else {
fishList.remove(this);
spawnNewEnemyFish(fishList);
}
}
void spawnNewEnemyFish(ArrayList fishList) {
if (random(0, 2) < 1) {
fishList.add(new EnemyFish(-25, random(100, height-100), random(1, 4), random(-2, 2)));
} else {
fishList.add(new EnemyFish(width+25, random(100, height-100), random(-1, -4), random(-2, 2)));
}
}
//change this method for enemyFish wall collision
void walls(ArrayList fishList) {
//right and left wall
if (x > width + enemyBound || x < -enemyBound) {
fishList.remove(this);
spawnNewEnemyFish(fishList);
}
//bottom wall
if (y > height - bSize/4) {
y = height - bSize/4;
velY *= -1;
}
//top wall
if (y < bSize/4) {
y = bSize/4;
velY *= -1;
}
}
void draw() {
pushMatrix();
translate(x, y);
scale(fishScale);
if (velX<0) {
scale(-1, 1);
}
// [...]
}
}

Among other things, you forgot to update the fish's size when the scale changed.

PhiLho

Re: HELP with fish tale game.

2 years ago

OK, I finalized the sketch, but somehow it wasn't so obvious... I changed a bit the behavior, some names, added a game over condition...

PFont font;
int numFishes = 8;
ArrayList<EnemyFish> fishList = new ArrayList<EnemyFish>();
PlayerFish player;
boolean keyUp, keyDown, keyLeft, keyRight;
boolean bGameOver;
void setup() {
size(800, 800);
font = createFont("Arial", 100);
player = new PlayerFish();
noStroke();
for (int i = 0; i < numFishes; i++) {
fishList.add(new EnemyFish());
}
keyUp = keyDown = keyLeft = keyRight = false;
}
void keyPressed() {
if (key == CODED) {
switch (keyCode) {
case UP: keyUp = true; break;
case DOWN: keyDown = true; break;
case LEFT: keyLeft = true; break;
case RIGHT: keyRight = true; break;
}
}
}
void keyReleased() {
if (key == CODED) {
switch (keyCode) {
case UP: keyUp = false; break;
case DOWN: keyDown = false; break;
case LEFT: keyLeft = false; break;
case RIGHT: keyRight = false; break;
}
}
}
void draw() {
background(62, 188, 202);
if (player.isAlive) {
if (keyUp) player.update(0, -1);
if (keyDown) player.update(0, 1);
if (keyLeft) player.update(-1, 0);
if (keyRight) player.update(1, 0);
player.update();
player.checkWalls();
player.draw();
} else {
player.update();
player.draw();
if (bGameOver) {
gameOver();
}
}
for (int i = 0; i < fishList.size(); i++) {
EnemyFish fishi = fishList.get(i);
if (fishi.isAlive) {
if (player.collision(fishi) && player.headOn(fishi)) {
player.eat(fishi);
}
for (int j = i+1; j < fishList.size(); j++) {
EnemyFish fishj = fishList.get(j);
if (fishi.collision(fishj)) { //GeneralFish collision method
fishi.bounce(fishj); //bounce the fish
}
}//for j
fishi.update();
fishi.checkWalls();
} else {
fishi.update();
}
fishi.draw();
}//for i
}//for draw
void gameOver() {
textFont(font);
if (player.isAlive) {
fill(#2255FF);
} else {
fill(#882255);
}
textAlign(CENTER, CENTER);
text("Game Over", width / 2, height / 2);
textFont(font, 36);
if (player.isAlive) {
text("You win!", width / 2, 2 * height / 3);
} else {
text("You loose...", width / 2, 2 * height / 3);
}
noLoop();
}
abstract class Fish {
float x, y, velX, velY, fishScale, fWidth;
int bSize;
color c;
boolean isAlive;
int traceTimer;
int traceSpeed = 2;
Fish() {
x = random(width);
y = random(height);
traceTimer = int(y / traceSpeed);
velX = random(-2, 2);
velY = random(-2, 2);
bSize = 150;
fishScale = random(0.3, 0.9);
isAlive = true;
}
void updateSize(float newScale) {
fishScale = newScale;
fWidth = bSize * fishScale;
}
//a method for collision
boolean collision(Fish other) {
return dist(x, y, other.x, other.y) < fWidth/2 + other.fWidth/2;
}
void update() {
if (isAlive) {
x += velX;
y += velY;
} else if (traceTimer > 0) {
traceTimer--;
y += traceSpeed;
}
}
void dies()
{
isAlive = false;
}
abstract void checkWalls(); // To be defined
abstract void draw(); // To be defined
}//class
class PlayerFish extends Fish {
PlayerFish() {
super();
updateSize(random(0.4, 0.9));
}
void update() {
velX *= 0.92;
velY *= 0.92;
super.update();
if (traceTimer == 0) {
bGameOver = true;
}
}
void update(float xDir, float yDir) {
velX += xDir;
velY += yDir;
}
boolean headOn(Fish other) {
return velX > 0 && other.velX < 0 || velX < 0 && other.velX > 0;
}
void eat(Fish other) {
if (fWidth > other.fWidth && other.isAlive) {
if (fishScale < 4) {
updateSize(fishScale * 1.15);
} else {
// Game over?
gameOver();
}
other.dies();
} else {
background(0);
dies();
}
}
void dies(){
super.dies();
}
void checkWalls() {
//right wall
if (x > width - bSize/4) {
x = width - bSize/4;
velX *= -1;
}
//left wall
if (x < bSize/4) {
x = bSize/4;
velX *= -1;
}
//bottom wall
if (y > height - bSize/4) {
y = height - bSize/4;
velY *= -1;
}
//top wall
if (y < bSize/4) {
y = bSize/4;
velY *= -1;
}
}
void draw() {
pushMatrix();
translate(x, y);
scale(fishScale);
if (velX > 0) {
scale(-1, 1);
}
noStroke();
strokeWeight(1);
fill(255, 115, 85);
quad(-15, -20, 45, 0, -15, 30, -15, 30);
stroke(2);
fill(255, 115, 85);
curve(-100, 26, -15, -20, 45, 0, 73, 61);
curve(73, -50, 45, 0, -15, 30, 15, -25);
curve(600, -100, -15, -20, -15, 30, 73, -50);
triangle(45, 0, 55, 10, 65, -10);
noStroke();
fill(62, 188, 202);
// triangle(-20,15,-36,25,-56,0);
//eye
strokeWeight(1);
stroke(2);
fill(255, 255, 255);
ellipse(-25, 0, 15, 15);
fill(0, 0, 0);
ellipse(-25, 0, 8, 8);
noStroke();
fill(153, 204, 50);
ellipse(3, 0, 10, 10);
ellipse(5, -2, 10, 10);
ellipse(10, 5, 8, 8);
ellipse(25, 1, 10, 10);
ellipse(0, 10, 10, 10);
ellipse(32, -5, 5, 5);
ellipse(10, - 8, 10, 10);
ellipse(15, 10, 10, 10);
ellipse(30, -2, 5, 5);
ellipse(5, -8, 4, 4);
ellipse(25, -5, 5, 5);
popMatrix();
}
}//end class
class EnemyFish extends Fish {
float wave, waveSpeed, amp;
int enemyBound;
color c;
EnemyFish() {
super();
wave = random(TWO_PI);
waveSpeed = random(0.1, 0.5);
amp = random(1, 4);
enemyBound = 50;
updateSize(random(0.3, 0.9));
c = color(random(255), random(10), 150);
}
EnemyFish(float xpos, float ypos, float velXa, float velYa) {
this();
x = xpos;
y = ypos;
velX = velXa;
velX = velYa;
}
void update() {
wave += waveSpeed;
y += amp * sin(wave);
super.update();
if (traceTimer == 0) {
fishList.remove(this);
spawnNewEnemyFish(fishList);
}
}
void bounce(Fish other) {
float angle = atan2(y - other.y, x - other.x);
velX = 2 * cos(angle);
velY = 2 * sin(angle);
other.velX = 2 * cos(angle - PI);
other.velY = 2 * sin(angle - PI);
}
void dies() {
super.dies();
c = color(100);
}
void spawnNewEnemyFish(ArrayList fishList) {
if (random(0, 2) < 1) {
fishList.add(new EnemyFish(-25, random(100, height-100), random(1, 4), random(-2, 2)));
} else {
fishList.add(new EnemyFish(width+25, random(100, height-100), random(-1, -4), random(-2, 2)));
}
}
//change this method for enemyFish wall collision
void checkWalls() {
//right and left wall
if (x > width + enemyBound || x < -enemyBound) {
dies();
}
//bottom wall
if (y > height - bSize/4) {
y = height - bSize/4;
velY *= -1;
}
//top wall
if (y < bSize/4) {
y = bSize/4;
velY *= -1;
}
}
void draw() {
pushMatrix();
translate(x, y);
scale(fishScale);
if (velX<0) {
scale(-1, 1);
}
//fish
fill(c);
arc(30, 0, 60, 30, -PI/2, PI/2);
quad(30, -15, 30, 15, -50, 5, -50, -19);
quad(-50, -10, -50, 5, -70, 10, -69, 8);
stroke(3);
noFill();
curve(300, 100, 35, -15, -70, 35, 100, 270);
curve(300, 100, 30, -10, -70, 35, 100, 270);
curve(300, 100, 30, -5, -70, 35, 100, 270);
curve(300, 100, 30, 0, -70, 35, 100, 270);
curve(300, 100, 30, 5, -70, 35, 100, 270);
curve(300, 100, 30, 10, -70, 35, 100, 270);
curve(300, 100, 30, 15, -70, 35, 100, 270);
fill(0, 0, 0);
ellipse(40, -5, 6, 6);//eye
fill(229, 190, 157);
triangle(-66, 35, -40, 50, -40, 60);//tail
triangle(-70, 33, -40, 70, -40, 90);//tail
triangle(30-10, 30-16, 30-40, 30-20, 30-35, 30-10);//down fin
curve(30-20, 50, 30-80, 30-40, -30, 30-48, 30+20, 30+20);
curve(30*0, 0, 30-53, 30-48, 30-40, 30-48, 30, 30+10);
popMatrix();
}
}

Top Reply