Help with key released

Programming Questions

rui.queir..

in Programming Questions • 4 months ago

I'm building an application on Processing using NyARToolkit, but my question is not directly about NyArToolkit but about a key released() method.

The thing is, I show a card and then I can do a few things if I press different keys. I press "X" and it shows one thing, I press "Y" and it shows another thing. The problem is, it shows the info from the last key pressed all the time.

If I change my AR card, it will immediatly show the info from the last key pressed. I would like to do something to release the key, something like: just show while i'm pressing the key, or have an "ESC" to stop showing everything.

I've been reading about the keyreleased() method but I didn't figured it yet out to put it to work.

By the way my method is like this:

if(key == "c") then
else if(key =="d") then...

Replies(2)

tfguy44

Re: Help with key released

4 months ago

boolean[] keysDown;
void setup(){
size(220,220);
keysDown = new boolean[26];
clearKeys();
}
void clearKeys(){
for( int i=0; i < keysDown.length; i++){
keysDown[i] = false;
}
}
void draw(){
background(0);
stroke(255);
for( int i=0; i < keysDown.length; i++){
if( keysDown[i] ){
line(i,0, i, height);
}
}
}
void keyPressed(){
if( key >= 'a' && key <= 'z' ){
keysDown[(key-'a')]=true;
}
if( key == ' ' ){
clearKeys();
}
}
void keyReleased(){
if( key >= 'a' && key <= 'z' ){
keysDown[(key-'a')]=false;
}
}

GoToLoop

Re: Help with key released

4 months ago

A tweaked version of tfguy44 . Click below to check it out online. Although it's malfunctioning there:

http://studio.processingtogether.com/sp/pad/export/ro.9sMuvRRTXcVG-/latest

However, offline Java version is OK:

/** * KeyReleased Example * by TFGuy44 (2013/May) * mod GoToLoop * * http://forum.processing.org/topic/help-with-key-released * http://studio.processingtogether.com/sp/pad/export/ro.9sMuvRRTXcVG-/latest */

final static byte NUM_KEYS_DOWN = 'z' - 'a' + 1;
final static boolean[] keysDown = new boolean[NUM_KEYS_DOWN];

final static byte  GAP = 15, BOLD = 2;
final static color BG = #4080A0, FG = #F0F040;

void setup() {
  size(NUM_KEYS_DOWN*GAP - GAP + BOLD*2, 150, P2D);
  noLoop();

  stroke(FG);
  strokeWeight(BOLD);
}

void draw() {
  background(BG);

  for (int i = 0; i != NUM_KEYS_DOWN; ++i)
    if (keysDown[i])
      line(i*GAP + BOLD, 0, i*GAP + BOLD, height);
}

void keyPressed() {
  redraw();

  final int k = keyCode;

  if (k >= 'A' & k <= 'Z')
    keysDown[k-'A'] = !keysDown[k-'A'];
}

void keyReleased() {
  keyPressed();
}

Top Reply