Define "dialog tree"...

If you need a user interface, you can check the GUI libraries made for Processing, there are 3 to 5 of them.

I'll check that out.

dialog trees are conversations with multiple choices and outcomes. Each response branches out from the first exchange in dialog, often ending up with two or more endings.

Ex. this is a dialog tree outside of coding (what I need help with putting into the game)
John - Hey Saxie, where's everybody?
Saxie - Huh What? Oh, its you.Look John, I don't know.
      I've actually been preoccupied with a problem of my own.(go to John response 1)
    John response 1 - 1.Problem? (go to saxie response)
    John response 1 - 2.Well, good luck with that.(exit dialog)
Saxie response - Yeah, I can't seem to find my petunias.I've been looking for them all day.(go to John response 2)
    John response 2 1.How the hell do you lose petunias?(go to saxie response 1)
           John response 2 2.Do you need help finding them?(Go to saxie response 2)
        John response 2 3.That's too bad. (exit dialog)
Saxie response 1 - I don't know, maybe someone stole them? They're pretty special flowers.
                   I've been raising them for a show.(go to john response 3)
    John response 3 1.Do you need help finding them?(go to saxie response 2)
    John response 3 2.A jackass like you raising plants for some show? Stop wasting my time.(end dialog)
Saxie response 2 - Help? Yes, help would be good. Can you look around the city for them? I spent a long time nursing those flowers.
    John response 4 1.Sure.(go to saxie response 3)
    John response 4 2.Find your own damn flowers.(go to saxie response 4)
Saxie response 3 - thanks. And hey, you'll get some good exercise. (go to john response 5)
Saxie response 4 - Well! I guess you can't expect a monster to do anything out of the goodness of their heart.(end dialog)
    john response 5 - Screw you.(end dialog) (quest start)

cool.

can the user make the choice in word balloon or in an extra menu?

oh, it's "Dialogue"

This is what I had in mind. I hope it makes sense ;w;

instead of using up/down and "s" also mouse is possible

check the GUI libraries made for Processing, there are 3 to 5 of them.

sorry, I can't help you with that tree structure...

Here is a way to implement the dialog tree:

1. DialogLine[] dialogLines =
2. {
3.   new DialogLine("A", "Hello", "B", "C", "D"),
4.   new DialogLine("B", "Go away", "."),
5.   new DialogLine("C", "Hi, how are you?", "E", "F"),
6.   new DialogLine("D", "Who are you?", "G", "H"),
7.   new DialogLine("E", "Fine, and you?", "!"),
8.   new DialogLine("F", "Not so well...", "!"),
9.   new DialogLine("G", "I am John, do you remember me?", "I", "J"),
10.   new DialogLine("H", "Sorry, that's a mistake", "."),
11.   new DialogLine("I", "Hi, John", "C", "K"),
12.   new DialogLine("J", "Not at all, goodbye", "."),
13.   new DialogLine("K", "Nice to see you", "."),
14.   new DialogLine(".", "The END"),
15.   new DialogLine("!", "To Be Continued"),
16. };
17. // The dialog lines indexed by their id, for easy lookup
18. HashMap<String, DialogLine> dialogTree = new HashMap<String, DialogLine>();
19. // The line currently displayed
20. DialogLine currentLine;
21. // The dialog so far
22. ArrayList<String> dialog = new ArrayList<String>();
23.  
24. void setup ()
25. {
26.   size(400, 800);
27.   smooth();
28.   for (DialogLine dl : dialogLines)
29.   {
30.     dialogTree.put(dl.id, dl);
31.   }
32.   currentLine = dialogTree.get("A");
33.   dialog.add(currentLine.line);
34. }
35.  
36. void draw ()
37. {
38.   background(255);
39.   fill(#004499);
40.   textSize(20);
41.   text(currentLine.line, 10, 30);
42.  
43.   // Display the choice of answers
44.   fill(#0077EE);
45.   textSize(15);
46.   int y = 60;
47.   int toChoose = 1;
48.   for (String ch : currentLine.choices)
49.   {
50.     DialogLine choice = dialogTree.get(ch);
51.     text(toChoose++ + ": " + choice.line, 20, y);
52.     y += 22;
53.   }
54.  
55.   // Display the history of the dialog
56.   fill(#0055AA);
57.   textSize(12);
58.   y = 200;
59.   for (String line : dialog)
60.   {
61.     text(line, 20, y);
62.     y += 20;
63.   }
64. }
65.  
66. void keyPressed()
67. {
68.   int choiceNb = currentLine.choices.length;
69.   int choice = key - '1';
70.   if (choice < 0 || choice >= choiceNb)
71.     return; // Ignore
72.    
73.   String choiceId = currentLine.choices[choice];
74.   DialogLine chosenAnswer = dialogTree.get(choiceId);
75.   if (chosenAnswer != null)
76.   {
77.     currentLine = dialogTree.get(choiceId);
78.     dialog.add(currentLine.line);
79.   }
80. }
81.  
82. /**
83.  * A dialog line: an id, the line itself, and a list of choices,
84.  * ie. of possible answers to this line.
85.  */
86. class DialogLine
87. {
88.   String id;
89.   String line;
90.   String[] choices;
91.  
92.   DialogLine(String i, String l, String... c)
93.   {
94.     id = i;
95.     line = l;
96.     choices = c;
97.   }
98.  
99.   String toString()
100.   {
101.     return id + " - " + line + " (" + choices.length + ")";
102.   }
103. }

Primitive, and need some fixes (the user probably shouldn't choose the answers for both speakers) but that's the spirit.

[EDIT] I fixed a bad branching, added one line looping in the dialog (that's no longer a tree but a graph!), renamed the class, added an history and some comments.
Making the computer to choose a random answer every other time is quite easy to add, actually.