Help with chasing the mouse cursor at a constant speed

Programming Questions

skeeners

Help with chasing the mouse cursor at a constant speed

in Programming Questions • 7 months ago

Hello

I'm trying to make a program where an object (for now a rectangle) follows and chases the mouse cursor at a constant speed. I've done a quick search and all I seem to find is the code below -

xpos = xpos + (mouseX - xpos)/n;
ypos = ypos + (mouseY - ypos)/n;

The code does chase the mouse but quickly accelarates when far from the cursor and decelarates when close to cursor.

Any help will be greatly appreciated.

Thanks

Replies(4)

quarks

Re: Help with chasing the mouse cursor at a constant speed

7 months ago

// two new variables
float speed = 20, angle;

then in draw() // Calculate the direction to travel

angle a= atan2(mouseY - ypos, mouseX - xpos);
// Move in that direction at the spedd specified.
xpos = xpos + speed * cos(angle);
ypos = ypos + speed * sin(angle);

skeeners

Re: Re: Help with chasing the mouse cursor at a constant speed

7 months ago

Thanks for replying quarks. I tried implementing your code but came across a problem, where there seems to be 2 rectangles erratically chasing the cursor. The image below shows this (I removed background(); to show the path of rectangle)

My code

int size = 10;
float xpos;
float ypos;
float speed = 20;
float angle;
void setup()
{
size(400,400);
xpos=50;
ypos=50;
}
void draw()
{
background(255);
angle = atan2(mouseY - ypos, mouseX - xpos);
xpos = xpos + speed * cos(angle);
ypos = ypos + speed * sin(angle);
rect(xpos, ypos, size, size);
}

quarks

Re: Help with chasing the mouse cursor at a constant speed

7 months ago

The jitter is caused when the distance between the current position of the mouse and the rectangle is much smaller than the speed. The solution is only to move the rectangle if it is too far from the mouse.

I have modified your code to get rid of the jitter.

int size = 10;
float xpos;
float ypos;
float speed = 4;
float angle;
void setup() {
size(400, 400);
cursor(CROSS);
xpos=50;
ypos=50;
}
void draw() {
background(255);
if (abs(xpos - mouseX) > 2 || abs(ypos - mouseY) > 2) {
angle = atan2(mouseY - ypos, mouseX - xpos);
xpos = xpos + round(speed * cos(angle));
ypos = ypos + round(speed * sin(angle));
}
rect(xpos, ypos, size, size);
}

skeeners

Re: Help with chasing the mouse cursor at a constant speed

7 months ago

Thank you very much quarks

Top Reply