Help with automating my program

Programming Questions

graysonh95

Help with automating my program

in Programming Questions • 8 months ago

I am working on a project building off of the pointillism example. I am starting the point size at 100 and reducing it to 1 to get a clear image and at each different point size I am saving the pictures so I can assemble them later to show the overall product evolution. Here is a picture of one I have done already:

I showed this to my school art teacher and he thought it would be a good project to put in our areas art show/competition, but I need to use a photo of my own so this monkey one can't be used.

Currently I have the code set up so when I hit space it saves the frame, resets the background, and reduces the point size by one. The problem is that waiting for each picture to finish and pressing space for each picture takes a lot of time. I would like to add to the code so it can decide if it's done on its own. Like maybe by detecting if there was still pixels from the original background present. I'm not sure how to do this though. Here is my current code:

PImage BlueJelly;

void setup() {

size(2117, 1601);

BlueJelly = loadImage("BlueJelly.JPG");

imageMode(CENTER);

noStroke();

background(255);

pointsize = 100;

}

int pointsize;

void draw() {

display();

if (pointsize < 1) {

noLoop();

}

void display() {

int x = int(random(BlueJelly.width));

int y = int(random(BlueJelly.height));

color pic_color = BlueJelly.get(x, y);

fill(pic_color, 128);

ellipse(x, y, pointsize, pointsize);

}

void keyPressed() {

if (key == ' ') {

saveFrame("PixBlueJelly"+pointsize+".JPG");

background(255);

pointsize -= 1;

}

The "BlueJelly" is referring to a jelly fish picture.

Any help or suggestions on this would be greatly appreciated!

Thanks!

Replies(17)

asimes

Re: Help with automating my program

8 months ago

If you are using random to pick the next pixel it seems the only way to determine if the entire area is filled is by checking every pixel to see if it is not the background color. An alternative option would be to start with an ArrayList of every point, randomly picking one of those points, and removing it from the ArrayList. When the ArrayList is empty then you know every point has been used an the next image can be created.

graysonh95

Re: Re: Help with automating my program

8 months ago

I think I'll try looping through the pixels and checking for the background color. An Arraylist for every single pixel would take way to long if every single pixel would have to be selected randomly.

Thanks for the reply! :)

graysonh95

Re: Help with automating my program

8 months ago

Here's what I came up with in case anybody was wondering:

void check_background() {

int remaining = 0;

for (int x = 0; x < width; x++) {

for (int y = 0; y < height; y++) {

color background = get(x, y);

if (background == color(255, 255, 255)) {

remaining += 1;

}

if (remaining == 0) {

saveFrame("PixOrangeJelly"+pointsize+".png");

background(255);

pointsize -= 5;

}

asimes

Re: Re: Help with automating my program

8 months ago

If you still prefer to do it this way you could stop searching after you found one pixel that is the background color.

void check_background() {
boolean allCovered = true;
for (int i = 0; i < width*height; i++) {
int x = i%width;
int y = i/width;
color background = get(x, y); // pixels[i]
if (background == color(255, 255, 255)) { // 0xffffffff
allCovered = false;
break; // Stop looking
}
}
if (allCovered) {
saveFrame("PixOrangeJelly"+pointsize+".png");
background(255);
pointsize -= 5;
}
}

asimes

Re: Help with automating my program

8 months ago

Actually the ArrayList option would be the exact same speed as far as the random part goes and much, much faster for determining if you are finished. You would use random like this:

Edit: The older version missed points

int randomChoice = (int)random(allPoints.size());
int randomPoint = allPoints.get(randomChoice);
int x = randomPoint%width;
int y = randomPoint/width;

graysonh95

Re: Re: Help with automating my program

8 months ago

I don't understand the ArrayList function very well and am having trouble seeing how this would work. would this loop through and check every single pixel or would it just choose random pixels?

If it is choosing random pixels wouldn't there be a chance that it picks the same pixel wasting time in the process?

asimes

Re: Help with automating my program

8 months ago

No, the idea is that it does not pick the same point twice. Starting with an ArrayList of all the points (0 to width*height), randomly pick one, and then remove that element. You can pull x and y values out of the element as I wrote above. If the ArrayList is empty then every point has been picked.

Edit: Removing the element is what prevents picking the same point twice.

graysonh95

Re: Re: Help with automating my program

8 months ago

Oh ok that does make much more sense now. Ill try using that.
Thanks!

graysonh95

Re: Help with automating my program

8 months ago

Can you look over this code and tell me what you think?

I tried using your ArrayList help

PImage OrangeJelly;
ArrayList points;
void setup() {
size(949, 710);
OrangeJelly = loadImage("OrangeJelly.png");
imageMode(CENTER);
noStroke();
background(255);
frameRate(30);
pointsize = 15;
points = new ArrayList(width*height);
}
int pointsize;
void draw() {
display();
check_background();
}
void display() {
int x = int(random(OrangeJelly.width));
int y = int(random(OrangeJelly.height));
color pic_color = OrangeJelly.get(x, y);
fill(pic_color, 128);
ellipse(x, y, pointsize, pointsize);
}
void check_background() {
for (int i = points.size(); i > 0; i--) {
int randomPoint = (int)random(points.size());
int x = randomPoint%width;
int y = randomPoint/width;
color background = get(x, y);
if (background != color(255)) {
points.remove(i);
}
}
if (points.size() == 0) {
saveFrame("PixOrangeJelly"+pointsize/5+".png");
background(255);
pointsize -= 5;
points.size(width*height);
}
}

On line 49 there is an error when I try to run the program. Don't I need to fill the ArrayList again so it can run for the next picture?

I suppose this probably isn't how you would do that because there was an error. Do I need to have another for loop an add all of those points again?

EDIT: I changed line 49 to points = new ArrayList(width*height);

but now the program just isn't running at all

asimes

Re: Help with automating my program

8 months ago

I think you got the two ideas mixed up and you might want to look at tutorial on using ArrayLists.

I made an example that goes from black to white to represent background color to some image. The for loop in the code is not necessarily needed, but it speeds things up by selecting 100 random points per frame.

ArrayList<Integer> allPoints = new ArrayList<Integer>();
void setup() {
size(200, 200);
stroke(255);
reset();
}
void draw() {
boolean allCovered = true;
// The for loop is not needed, it just speeds things up
// Right now 100 points are picked per frame
for (int i = 0; i < 100; i++) {
if (allPoints.size() > 0) {
allCovered = false;
int randomChoice = (int)random(allPoints.size());
int randomPoint = allPoints.get(randomChoice);
int x = randomPoint%width;
int y = randomPoint/width;
// You'll probably replace this with ellipse
point(x, y);
allPoints.remove(randomChoice);
}
else break;
}
if (allCovered) reset();
// Progress
println((1-(float)allPoints.size()/(width*height))*100+"%");
}
void reset() {
background(0);
for (int i = 0; i < width*height; i++) allPoints.add(i);
}

graysonh95

Re: Re: Help with automating my program

8 months ago

The tutorial was confusing because it was dealing with a class. I adapted what you had above into my code and now it works so much faster and better!

Thank you so much for all of your time and answers!!

asimes

Re: Help with automating my program

8 months ago

You're welcome. Here's some useful things for ArrayLists (should be much easier to follow than the classes example):

ArrayList<Integer> example;
void setup() {
size(100, 100);
// Make a new ArrayList of type Integer (int)
example = new ArrayList<Integer>();
// Add some numbers
example.add(1);
example.add(2);
example.add(3);
print(example);
// Remove some numbers
example.remove(2); // This removes 3! Make sure that makes sense
print(example);
// See how many elements are in the ArrayList
print("Number of elements = "+example.size());
exit();
}

graysonh95

Re: Re: Help with automating my program

8 months ago

This is much easier to follow! Thanks

graysonh95

Re: Help with automating my program

8 months ago

I've been using the complete program a lot on different pictures and have noticed a minor problem that I have no clue where it's coming from in the code. When it is producing dots for smaller sizes (like 30 and down) it focuses most of the dots on a section on the top of the screen which takes away from the majority of the remaining picture.

PImage Monkey;
ArrayList<Integer> points = new ArrayList<Integer>();
ArrayList<Integer> usedPoints = new ArrayList<Integer>();
void setup() {
size(300, 259);
Monkey = loadImage("Monkey.jpeg");
imageMode(CENTER);
noStroke();
frameRate(30);
background(255);
start();
pointsize = 100;
}
int pointsize;
void draw() {
if (pointsize == 0) {
noLoop();
}
for (int i = 0; i < 100; i++) {
if (points.size() > 0) {
int randomChoice = (int)random(points.size());
int randomPoint = points.get(randomChoice);
int x = randomPoint%width;
int y = randomPoint/width;
color pic_color = Monkey.get(x, y);
fill(pic_color);
ellipse(x, y, pointsize, pointsize);
points.remove(randomChoice);
usedPoints.add(randomChoice);
}
}
next();
}
void start() {
for (int i = 0; i < width*height; i++) {
points.add(i);
}
}
void next() {
boolean white = false;
for (int i = 0; i < width*height; i++) {
int a = i%width;
int b = i/width;
color z = get(a, b);
if (z == color(255)) {
white = true;
break;
}
}
if (!white) {
reset();
}
}
void reset() {
saveFrame("Monkey"+(pointsize)+".jpeg");
pointsize -= 1;
background(255);
for (int i = 0; i < usedPoints.size(); i++) {
points.add(i);
usedPoints.remove(i);
}
}

If you try running the program you will be able to see what the problem is more clearly.

Any help would be great!

asimes

Re: Help with automating my program

8 months ago

Here is the culprit:

for (int i = 0; i < usedPoints.size(); i++)

The next time you add points you are only adding the amount that were used instead of width*height. If the screen is about 300*250 (75000) and you add less than that then every point is no longer an option, just some number of the first few lines. As this becomes more noticeable, the amount of available lines of points shrinks to just the top ones.

Edit: If you go up some posts, this was the same mistake I corrected 6 posts from the top

Also you can empty usedPoints like this:

ArrayList<Integer> example = new ArrayList<Integer>();
void setup() {
size(100, 100);
example.add(0);
example.add(1);
example.add(2);
println(example);
example.clear();
println(example);
exit();
}

graysonh95

Re: Re: Help with automating my program

8 months ago

I think I will have to empty the original points ArrayList before I add all of the pixels again. When I tried using your example from 6 posts from the top it was adding many doubled points because there was still a large amount of unused points in the list when I added width*height to the list. I can also get rid of my usedPoints ArrayList.

Thanks for the help! :)

asimes

Re: Help with automating my program

8 months ago

This might help show what is happening: http://processing.org/reference/pixels.html

Only about half the screen is pink in the image plus about half of the middle line. That is because only the first half of the lines plus some amount are being selected. The natural order there is left to right then down when you reach the end of the line. If that amount is less than width*height it stops before it reaches the bottom.

Top Reply