/* Move Object Example (v2.40)
 * by GoToLoop (2012/Dec)
 *
 * http://forum.processing.org/topic/keypressed-problem
 *
 * http://forum.processing.org/topic/
 * how-to-move-an-object-diagonally-using-keycode
 *
 * http://forum.processing.org/topic/
 * how-do-i-make-an-object-disappear-upon-collision
 *
 * http://studio.processingtogether.com/sp/pad/export/ro.9bY07S95k2C2a/latest
 */

// Object's variables:
static int x, y;     // positions
static int w, h;     // dimensions
static int ww, hh;   // radii
static int gw, gh;   // canvas - radii
boolean ballOrBox;   // current shape

// Object's constants:
final static byte  SPX  = 30, SPY = 20; // speed movement
final static byte  BOLD = 4;            // border thickness
final static color COLOUR = #0000FF;    // #blue

// General constants:
final static byte  FPS = 60;
final static color BG  = #FFFF00;       // #yellow

// General boolean variables:
static boolean north, south, west, east;

static final void initVars(int wdt, int hgt) {
  x = wdt>>1;    // center of screen 
  y = hgt>>1;

  w = wdt/10;    // 1/10th size of screen
  h = hgt/10;

  ww = w>>1;     // distances from center (radii)
  hh = h>>1;

  gw = wdt - ww; // diff. of (canvas dimensions - obj. radii)
  gh = hgt - hh;
}

void setup() {
  size(800, 600);
  smooth();            // turn on drawing smoothness
  frameRate(FPS);      // set frames / second

  rectMode(CENTER);    // coordinates are relative from center
  ellipseMode(CENTER);

  fill(COLOUR);        // object's paint color
  stroke(0);           // #black
  strokeWeight(BOLD);  // object's border thickness

  initVars(width, height);
}

void draw() {
  background(BG);

  moveObject();
  confineToEdges();
  displayObject();
}

void keyPressed() {
  final int k = keyCode;

  if (k == ' ' | k == ENTER | k == RETURN)
    ballOrBox = !ballOrBox;

  else setDirection(k, true);
}

void keyReleased() {
  setDirection(keyCode, false);
}

static final void setDirection(int k, boolean decision) {
  if      (k == UP    | k == 'W')   north = decision;
  else if (k == DOWN  | k == 'S')   south = decision;
  else if (k == LEFT  | k == 'A')   west  = decision;
  else if (k == RIGHT | k == 'D')   east  = decision;
}

static final void moveObject() {
  x += (east?  SPX : 0) - (west?  SPX : 0);
  y += (south? SPY : 0) - (north? SPY : 0);
}

static final void confineToEdges() {
  x = constrain(x, ww, gw);
  y = constrain(y, hh, gh);
}

void displayObject() {
  if (ballOrBox)    ellipse(x, y, w, h);
  else              rect(x, y, w, h);
}

/*
 #####################################
 ##           Evolution Sim         ##
 ##      Created by: Dr. Bacon      ##
 #####################################
 
 (2012/Nov)
 
 http://forum.processing.org/topic/why-won-t-this-code-work
 http://www.openprocessing.org/sketch/78545
 http://studio.processingtogether.com/sp/pad/export/ro.96-VhVDOO989P/latest
 
 This simulation was designed to simulate the
 basic ideas behind natural selection and
 outline them with organismss with a very simple genome.
 Once the simulation is run, there are no controls. One
 of the main flaws of this project is that there is no
 graphical user interface for fiddling with the starting
 values, and it must be tinkered with from within the code.
 Do with the code what you will.
 
 Also, thanks very much to Daniel Shiffman for providing me with Zoog,
 it strangely improves the way I feel about the whole sketch.
 */

// private static final short FOODS_INTERV = 3000;
// private static final short ENERGY_LVl   = 100;

static final short FOOD_SZ = 12;

static final short ORG_WD = 32, ORG_HG = 88;
static final short ORG_SPX = 6, ORG_SPY = 3;

static final short FOOD_NUM = 50, ORG_NUM = 10;

static final Food[] foods = new Food[FOOD_NUM];
static final Organism[] organisms = new Organism[ORG_NUM];

void setup() {
  size(700, 500);
  frameRate(50);
  smooth();

  ellipseMode(CENTER);
  rectMode(CENTER);

  stroke(Organism.FG);

  for (int i=0; i!=FOOD_NUM; foods[i++] = new Food(FOOD_SZ, 10).place());

  for (int i=0; i!=ORG_NUM; organisms[i++] = 
  new Organism(ORG_WD, ORG_HG, ORG_SPX, ORG_SPY, 100, 50, 1).place());
}

void draw() {
  background(Organism.BG);

  for (Food food: foods)          food.display();
  for (Organism org: organisms)   org.all();
}

class Food {
  short x, y;
  short rad, hp;

  Food (int radius, int energy) {
    rad = (short) radius;
    hp  = (short) random(1, energy+1);
  }

  Food place() {
    x = (short) random(rad, width-rad);
    y = (short) random(rad, height-rad);

    return this;
  }

  void display() {
    fill(Organism.FG);
    ellipse(x, y, rad, rad);
  }
}

class Organism {
  static final color BG = 0, FG = -1, BODY_C = 0200;

  short x, y, w, h;
  short xSpd, ySpd;
  short eLvl, eLvlReq, eSurv;

  Organism (
  int iWidth, int iHeight, int ixSpd, int iySpd, 
  int ieLvl, int ieReq, int ieSurv )
  {
    xSpd = (short) ( random(1, ixSpd+1) * (random(2)<1 ? -1 : 1) );
    ySpd = (short) ( random(1, iySpd+1) * (random(2)<1 ? -1 : 1) );

    w  = (short) iWidth;
    h  = (short) iHeight;

    eLvl = (short) ieLvl;
    eLvlReq = (short) ieReq;
    eSurv = (short) ieSurv;
  }

  Organism place() {
    x = (short) random(w, width  - w);
    y = (short) random(h, height - h);

    return this;
  }

  void display() {
    fill(BODY_C);
    rect(x, y, w/3, h/3); //Body

    fill(FG);
    ellipse(x, y - (h>>2), w*7 >> 3, w*7 >> 3);  //Head

    fill(BG);
    ellipse(x - (w>>2), y - (h>>2), w/3, h/5);   //Eyes
    ellipse(x + (w>>2), y - (h>>2), w/3, h/5);

    line(x - w/6, y + h/6, x - w/3, y + (h>>2)); //Legs
    line(x + w/6, y + h/6, x + w/3, y + (h>>2));
  }

  void update() {
    if ((x += xSpd) < w>>1  | x > width  - (w>>1))   xSpd *= -1;
    if ((y += ySpd) < h/2.4 | y > height - (h>>2))   ySpd *= -1;
  }

  void all() {
    update();
    display();
  }
}