Help me optimize my code please (Arduino, Serial & Firmata)

paul.stro..

Help me optimize my code please (Arduino, Serial & Firmata)

in Integration and Hardware • 4 months ago

Could somebody please glance at my code and tell me if I am making any obvious mistakes? Somehow it is introducing a significant amount of lag, which I cannot account for.

I am using two Arduinos. Arduino1 reads 8 capacitive sensors and sends them to my computer via serial connection. The other Arduino2 is running Firmata and controlls 8 motors.

If I am running the serial consule of Arduino, the readings from Arduino1 appear snappy and fast. In my own software however, it lags behind by ~500ms

Here is the code:

//handles the touch issues.
// incoming touch is a serial connection, outgoing touch runs via firmata
//array for storing incoming values, arranged according to evernote pins??
int[] incomingValues = new int[8];
//threshholds for deciding whether there is contact or not
int[] thresholds = new int[8];
//array for storing motor connections
int[] motorPins = new int[8];
import processing.serial.*; //import the Serial library
import cc.arduino.*;
Arduino arduino;
char end = '\n'; // /nl is the end of the message
String incomingString; // the string which is read
Serial port; // The serial port
String[] a; //string for temporarily storing the incoming values
void setup() {
println(Arduino.list()); //list all arduinos connected
arduino = new Arduino(this, Arduino.list()[3], 57600);
port = new Serial(this, Serial.list()[2], 9600);
incomingString = port.readStringUntil(end);
port.clear(); // function from serial library that throws out the first reading, in case we started reading in the middle of a string from Arduino
incomingString = null; // initially, the string will be null (empty)
//set all pins as output and set then low
for (int i = 0; i <= 13; i++) {
arduino.pinMode(i, Arduino.OUTPUT);
arduino.digitalWrite(i, Arduino.LOW);
}
//assign which motor is connected to wich pin (i.e. motor 0 is connected to pin 11)
motorPins[0] = 11;
motorPins[1] = 10;
motorPins[2] = 9;
motorPins[3] = 8;
motorPins[4] = 7;
motorPins[5] = 6;
motorPins[6] = 5;
motorPins[7] = 3;
//assign the thresholds for each sensor (i.e. if sensor 2 has a reading higher then 3 its a contact)
thresholds[0] = 1;
thresholds[1] = 2;
thresholds[2] = 3;
thresholds[3] = 2;
thresholds[4] = 2;
thresholds[5] = 2;
thresholds[6] = 2;
thresholds[7] = 2;
}
void draw() {
while (port.available () > 0) { //as long as there is data coming from serial port, read it and store it
incomingString = port.readStringUntil(end);
}
if (incomingString != null) { //if the string is not empty
a = split(incomingString, ", ");
//this is done in order to remap the incoming values so they are in the apropreate order
incomingValues[0] =int(a[6]);
incomingValues[1] =int(a[7]);
incomingValues[2] =int(a[0]);
incomingValues[3] =int(a[1]);
incomingValues[4] =int(a[2]);
incomingValues[5] =int(a[4]);
incomingValues[6] =int(a[3]);
incomingValues[7] =int(a[5]);
//print the values for debugging
for (int i = 0; i<8; i++) {
print(incomingValues[i]);
print(", ");
}
println();
}
//set the motors high or low, depending on if there is a touch or not
for (int i = 0; i<8; i++) {
if (incomingValues[i] - thresholds[i] > 0) {
arduino.digitalWrite(motorPins[i], Arduino.HIGH);
}
else {
arduino.digitalWrite(motorPins[i], Arduino.LOW);
}
}
}

Any suggestions on how to improve the code would be welcome. I would prefer not to change the code running on the Arduinos (there is a lot more going on, everything Arduino related is working fine, I am not 100% sure which version of the code is running on them :-/ ...)

Hope you can help me

Cheers

Replies(4)

paul.stro..

Re: Help me optimize my code please (Arduino, Serial & Firmata)

4 months ago

I tried taking away everything non essential - only reading the serial signal. It still is chunky and laggy.

//handles the touch issues.
// incoming touch is a serial connection, outgoing touch runs via firmata
//array for storing incoming values, arranged according to evernote pins??
int[] incomingValues = new int[8];
import processing.serial.*; //import the Serial library
char end = '\n'; // /nl is the end of the message
String incomingString; // the string which is read
Serial port; // The serial port
String[] a;
void setup() {
port = new Serial(this, Serial.list()[1], 9600);
incomingString = port.readStringUntil(end);
port.clear(); // function from serial library that throws out the first reading, in case we started reading in the middle of a string from Arduino
incomingString = null; // initially, the string will be null (empty)
}
void draw() {
while (port.available () > 0) { //as long as there is data coming from serial port, read it and store it
incomingString = port.readStringUntil(end);
}
if (incomingString != null) { //if the string is not empty
a = split(incomingString, ", ");
//this is done in order to remap the incoming values so they are in the apropreate order
//print the values for debugging
for (int i = 0; i<8; i++) {
print(a[i]);
print(", ");
}
println();
}
}

Any suggestions

GoToLoop

Re: Help me optimize my code please (Arduino, Serial & Firmata)

4 months ago

Dunno whether it's gonna be able to squeeze any performance outta it. But here's my take on it:

WARNING: Dunno nothing about Arduino and such!

// http://forum.processing.org/topic/help-me-optimize-my-code-please-arduino-serial-firmata

import cc.arduino.*;
Arduino arduino;

import processing.serial.*;
Serial port;

final static char   END = '\n'; 
final static String TOKEN = ", ";

final static short  NUM = 8, FPS = 100;

final static int[]  incomingValues = new int[NUM];

final static int[]  thresholds = {
  1, 2, 3, 2, 2, 2, 2, 2
};

final static int[]  motorPins  = {
  11, 10, 9, 8, 7, 6, 5, 3
};

void setup() {
  frameRate(FPS);

  println(Arduino.list() + END);
  arduino = new Arduino(this, Arduino.list()[3], 57600);

  port = new Serial(this, Serial.list()[2], 9600); 
  port.readStringUntil(END);
  port.clear();

  for (int i = 0; i != 14; i++) {
    arduino.pinMode(i, Arduino.OUTPUT);
    arduino.digitalWrite(i, Arduino.LOW);
  }
}

void draw() {
  if (port.available() < 1)   return;

  final String incomingString = port.readStringUntil(END);

  if (incomingString == null) return;

  final int[] a = int( split(incomingString, TOKEN) );

  incomingValues[0] = a[6];
  incomingValues[1] = a[7];
  incomingValues[2] = a[0];
  incomingValues[3] = a[1];
  incomingValues[4] = a[2];
  incomingValues[5] = a[4];
  incomingValues[6] = a[3];
  incomingValues[7] = a[5];

  for (int i = 0; i != NUM; i++)
    arduino.digitalWrite(motorPins[i], 
    incomingValues[i] - thresholds[i] > 0 ? 
    Arduino.HIGH : Arduino.LOW);

  println(incomingValues + END);
}

paul.stro..

Re: Help me optimize my code please (Arduino, Serial & Firmata)

4 months ago

cool thanks :-)

the FPS you add is the cruicial part. I come from arduino and the loop function (which is arduinos equivilant to the draw function) executes as fast as possible. apparently draw does not do that.

so in addition to your many fixes, using the serialEvent() function instead of coding everything inside the draw function should fix my issues.

*

just figured that part out.

Thanks for your input. lots of little things you do there, which I don't know of.

GoToLoop

Re: Help me optimize my code please (Arduino, Serial & Firmata)

4 months ago

Glad I was able to help you out a little!

If you don't understand anything about my modifications, don't fret to ask!

Top Reply