help getting started with visualising gain

Core Library Questions

joshmyc

help getting started with visualising gain

in Core Library Questions • 1 year ago

i'm trying to get an ellipse's radius to increase.decrease according to the amplitude of an audio file. I have found this example in minim, which uses BeatDetect. Will modifying this example work, or should i use some sort of Fourier transform to get the ampiltude of the audio?

import ddf.minim.*;
import ddf.minim.analysis.*;
Minim minim;
AudioPlayer song;
BeatDetect beat;
float eRadius;
void setup()
{
size(200, 200, P3D);
minim = new Minim(this);
song = minim.loadFile("davis.aif", 2048);
song.play();
// a beat detection object song SOUND_ENERGY mode with a sensitivity of 10 milliseconds
beat = new BeatDetect();
ellipseMode(CENTER_RADIUS);
eRadius = 20;
}
void draw()
{
background(0);
beat.detect(song.mix);
float a = map(eRadius, 20, 80, 60, 255);
fill(60, 255, 0, a);
if ( beat.isOnset() ) eRadius = 80;
ellipse(width/2, height/2, eRadius, eRadius);
eRadius *= 0.95;
if ( eRadius < 20 ) eRadius = 20;
}
void stop()
{
// always close Minim audio classes when you are finished with them
song.close();
// always stop Minim before exiting
minim.stop();
super.stop();
}

Replies(3)

jbum

Re: help getting started with visualising gain

1 year ago

Beat Detect is high level (meaning very easy to use) and is good if you want to track a bass drum or snare or high hat, or something like that. It is based on a lower level routine called FFT (which is indeed a Fourier Transform), for which there is also some example code with the Minim library (ForwardFFT). If you wish to monitor the levels yourself, you can create an AudioListener object and look at the sample values directly.

I've posted some sample code that uses FFT in various ways (such as setting the width of a set of ovals) in my class materials archive:

http://krazydad.com/processing_music/

joshmyc

Re: help getting started with visualising gain

1 year ago

have modified example from http://krazydad.com/processing_music/ (thanks to jbum). How can i switch the transparency so it decreases with gain (at the moment the higher the gain, the lower the transparency level)..

import ddf.minim.*;
import ddf.minim.analysis.*;
int m = 1;
int rad=25;
Minim minim;
AudioSource signal;
FFT fft;
AudioOutput out;
boolean over1 = false;
boolean selected1 = false;
int pos1X, pos1Y;
int offset1X, offset1Y;
float[] dots = new float[m+1];
void setup()
{
size(800, 800);
minim = new Minim(this);
pos1X = width/2;
pos1Y = height/2;
AudioPlayer player = minim.loadFile("conga.mp3", 1024);
player.loop();
signal = (AudioSource) player;
AudioOutput out = minim.getLineOut();
fft = new FFT(signal.bufferSize(), signal.sampleRate());
noStroke();
ellipseMode(CENTER);
smooth();
for (int i = 0; i <= m; ++i) {
dots[i] = 0;
}
}
void draw()
{
int specSize = fft.specSize();
background(0);
fft.forward(signal.mix);
for (int i = 0; i < min(m, specSize); i++)
{
float v = fft.getBand(i);
dots[i] += v/specSize;
dots[i] *= .98;
float rv = constrain(dots[i], 0, 1);
//fill (255, 0, 0, rad*5*rv);
fill (255, 0, 0, pos1Y*rv);
strokeWeight(3);
stroke(255,0,0,150);
ellipse(pos1X, pos1Y, rad*2, rad*2);
}
float valGain = map(pos1Y, 0, height, 6, -48);
signal.setGain(valGain);
}
void stop()
{
signal.close();
minim.stop();
super.stop();
}
void mouseMoved() {
over1 = false;
if (sqrt(sq(mouseX-pos1X)+sq(mouseY-pos1Y))<=rad) {
over1 = true;
}
}
void mousePressed() {
if (over1) {
selected1 = true;
offset1X = pos1X-mouseX;
offset1Y = pos1Y-mouseY;
}
}
void mouseReleased() {
selected1 = false;
}
void mouseDragged()
{
if (selected1) {
pos1X = max(0, min(mouseX+offset1X, width));
pos1Y = max(0, min(mouseY+offset1Y, height));
}
}

jbum

Re: help getting started with visualising gain

1 year ago

The two lines that affect the transparency of the dots, based on the audio are:

float rv = constrain(dots[i], 0, 1);

fill (255, 0, 0, pos1Y*rv);

So rv is going from 0 to 1. You want it to go from 1 to 0. Which is

1 - rv

So...

float rv = constrain(dots[i], 0, 1);

fill (255, 0, 0, pos1Y*(1-rv));

Is one way to do it...

Top Reply