help generating fanned out triangles

Programming Questions

ottenm

help generating fanned out triangles

in Programming Questions • 1 year ago

I'm trying to generate a bunch of random triangles like those I've drawn below. I want them to all share one point (might not be the origin), and to have different heights, and to point out in different directions .... but I can't figure out how to control the width of the bases, or how to keep their bases perpendicular to the shared point (so the triangles near the top of the screen have a vertical base, and the triangles near the left edge of the screen a have horizontal base). The overall placement is random, it doesn't matter if they overlap.

I started messing with sin/cos/radians, but not having any luck.

Thanks for any help.

Replies(3)

asimes

Re: help generating fanned out triangles

1 year ago

What I did was pick an angle from the origin at random (between 0 and HALF_PI). Then I picked a random distance (between width/2 and width). Then I put a point there which by comparison to your drawing would be the center of the base of a triangle. Then I extended a perpendicular line to the original random angle to make the length of the triangle base.

int numTri = 10;
int triBaseLength = 5;
float[] triX1 = new float[numTri];
float[] triX2 = new float[numTri];
float[] triY1 = new float[numTri];
float[] triY2 = new float[numTri];
void setup() {
size(400, 400);
smooth();
for (int i = 0; i < numTri; i++) {
float randAngle = random(0, HALF_PI);
float randDistance = random(width/2, width);
float x = cos(randAngle)*randDistance;
float y = sin(randAngle)*randDistance;
triX1[i] = x+cos(randAngle+HALF_PI)*triBaseLength;
triY1[i] = y+sin(randAngle+HALF_PI)*triBaseLength;
triX2[i] = x+cos(randAngle-HALF_PI)*triBaseLength;
triY2[i] = y+sin(randAngle-HALF_PI)*triBaseLength;
}
background(255);
for (int i = 0; i < numTri; i++) {
triangle(0, 0, triX1[i], triY1[i], triX2[i], triY2[i]);
}
}

ottenm

Re: help generating fanned out triangles

1 year ago

Awesome! Couldn't be happier.

Thanks for the help-

daftarcher

Re: help generating fanned out triangles

1 year ago

Hi there,

Thanks for the nice script Asimes.

I have made it a bit interactive by making minor changes to the script.

int numTri = 10;
int triBaseLength = 5;
float[] triX1 = new float[numTri];
float[] triX2 = new float[numTri];
float[] triY1 = new float[numTri];
float[] triY2 = new float[numTri];
void setup() {
size(400, 400);
smooth();
for (int i = 0; i < numTri; i++) {
float randAngle = random(0, HALF_PI);
float randDistance = random(width/2, width);
float x = cos(randAngle)*randDistance;
float y = sin(randAngle)*randDistance;
triX1[i] = x+cos(randAngle+HALF_PI)*triBaseLength;
triY1[i] = y+sin(randAngle+HALF_PI)*triBaseLength;
triX2[i] = x+cos(randAngle-HALF_PI)*triBaseLength;
triY2[i] = y+sin(randAngle-HALF_PI)*triBaseLength;
}
}
void draw(){
background(255);
for (int i = 0; i < numTri; i++) {
triangle(mouseX, mouseY, triX1[i], triY1[i], triX2[i], triY2[i]);
}
}

Line 27 could also be:

triangle(mouseX, mouseY, triX1[i]+ mouseX, triY1[i]+ mouseY, triX2[i]+ mouseX, triY2[i]+ mouseY);

Top Reply