Help creating frames

Programming Questions

gloopical

in Programming Questions • 6 months ago

Hey guys, first time posting.

I'm pretty new to processing and trying to get into generative art. Hit a bit of a bump today when I can't seem to get it to save any of my results.

Ideally I want it to just generate frames, and I've done this before with others, just for some reason this one doesn't want to do as it's told. The visual output is as I want it (I realise it looks weird, it is meant to be like that) but I can't get it to even save for some reason. Ended up resorting to doing it one frame at a time and trying to get it to save on hitting enter but even that isn't working. And I want the results to be bigger than my screen resolution so print screening isn't even an option.

Here's the code (it might look a bit... odd, I can't quite remember what I ended up doing to it when I had my little angry moment but I've checked and it's still coming up with what I want on the visual end) :

float xstart, xnoise, ynoise;

void setup(){

size(2000,1000);

frameRate(24);

smooth();

background(255);

xstart=random(10);

xnoise=xstart;

ynoise=random(10);

for(int y=0;y<=height;y+=5){

ynoise+=0.1;

xnoise=xstart;

float lastx=-999;

float lasty=-999;

for(int x=0; x<=width;x+=5){

xnoise+=0.01;

drawPoint(x,y,noise(xnoise,ynoise));

stroke(220);

lastx=x;

lasty=y;

}

void drawPoint(float x,float y, float noiseFactor){

if(width>=2000){

float len=10*noiseFactor;

rect(x,y,len,len);

}

void keyPressed(){

if(keyCode == ENTER){

saveFrame("screen-####.jpg");

}

If anyone has any idea I will be forever grateful.

Thanks,

Gemma

Replies(14)

amnon.owed

Re: Help creating frames

6 months ago

For keyPressed() events you need a draw() loop:

void draw() {
}

In your current sketch the image is generated once, so the sketch is static and non-interactive. In that case a keyPressed() method has no point and the saveFrame could be placed at the end of setup() as well.

You might also be interested in methods like noLoop(), loop(), redraw() etc. See the reference.

GoToLoop

Re: Help creating frames

6 months ago

I dunno if I understood it right. But here's a fix I've come up with.

And if you wanna draw on something bigger than the available screen resolution,

just use a PGraphics instance for it!

[EDIT 2013/Apr/07] : replaced "global" field variables by constant ones!

// http://forum.processing.org/topic/help-creating-frames

final static byte  DIM = 15, HALF_DIM = DIM>>1;
final static float XINC = .01, YINC = .1;
final static color BG = -1, FG = 220;

void setup() {
  size(1000, 500);
  noLoop();
  smooth();
  stroke(FG);
}

void draw() {
  background(BG);

  float noiseX, startX = random(DIM);
  float noiseY = random(DIM);

  for (int y=0; y<height; y+=HALF_DIM) {
    noiseY += YINC;
    noiseX = startX;

    for (int x=0; x<width; x+=HALF_DIM) {
      noiseX += XINC;
      drawPoint(x, y, noise(noiseX, noiseY), DIM);
    }
  }
}

void drawPoint(float x, float y, float noiseFactor, int amp) {
  float len = noiseFactor * amp;
  rect(x, y, len, len);
}

void keyPressed() {
  redraw();
  if (key == ENTER | key == RETURN)   saveFrame("screen-####.jpg");
}

gloopical

Re: Help creating frames

6 months ago

Thank you so much, both of you - GoToLoop, the code you gave me works flawlessly now. Thank you so much.

The weird thing is, my original code had the saveFrame but it wasn't saving for some reason which I still haven't been able to figure out. Very strange. I'm sure it was something fairly trivial however. I'll get there eventually!

Once again, thanks to you both - it's quite tricky starting out in this program, but knowing there's a good community that can point me in the right direction is a relief. I'll try and return the favour when (um, well, if) I'm a bit more knowledgeable.

Thank you so much!

Gemma

amnon.owed

Re: Help creating frames

6 months ago

The weird thing is, my original code had the saveFrame but it wasn't saving for some reason which I still haven't been able to figure out. Very strange. I'm sure it was something fairly trivial however. I'll get there eventually!

See my above answer. If you add a draw loop to your code, it will save as well.

void draw() {
}

However, GoToLoop's code example is a much more elegant and sensible solution.

GoToLoop

Re: Help creating frames

6 months ago

Made some more tweaks, in order the program becomes parameterized w/ constants.

gloopical

Re: Help creating frames

6 months ago

Hey again, I've been having a fiddle about with it some more and once again I'm probably missing something very, very obvious but here goes anyway. I've managed to do this on other bits but still not on this one.

Managed to get it to continuously render frames without having to press enter, but still having trouble getting said frames to save.

Here's what I've got:

void setup() {
size(2000, 1000);
frameRate(24);
smooth();
stroke(200);
xstart=random(10);
ystart=random(10);
}
void draw() {
background(-1);
xnoise = xstart = random(10);
ynoise = ystart = random(10);
for (int y=0; y<=height; y+=5) {
ynoise += .1;
xnoise = xstart;
for (int x=0; x<=width; x+=5) {
xnoise += .01;
drawPoint( x, y, noise(xnoise, ynoise) );
}
}
}
void drawPoint(float x, float y, float noiseFactor) {
float len = 10*noiseFactor;
rect(x, y, len, len);
}
void keyPressed() {
redraw();
saveFrame("screen-####");
}

I realise that what I have at the end doesn't work, that was once again pretty much a result of me trying absolutely anything to get it to work. So if it looks a bit "well, duh", that's why.

Like I said... I'm reaaaaally new to this.

quarks

Re: Help creating frames

6 months ago

I tried your code after adding the line

float xstart, ystart,xnoise,ynoise;

and it saved a frame everytime I pressed a key. The image file format was tif because you did not specify another type., also the #### was replaced by the current frame number so did not get 001, 002, 003... because the frames and continually being redrawn.

When you say it didn't work could you be more specific as to what went wrong.

GoToLoop

Re: Help creating frames

6 months ago

In my version, I use noLoop() to turn off draw() auto callback!

So, until a user hits some key, the program doesn't do anything!

Once a key is pressed, draw() is set to be called once ( w/ redraw() ) and a new drawing is rendered!

And if that key also happens to be an ENTER, it saves current frame as well.

Thus, it is a key press event driven based program!

Now, if you want to continually rendering frames, no matter whether a key is being pressed or not,

you have to comment out or remove noLoop(), of course!

But then, you also have to determine the frequency a frame is saved!

Lest your HD is gonna fill up pretty fast!

One of the mechanisms is frameRate(), which determines the FPS of draw() calls.

I see you've already set it to 24 FPS.

Now, since your program is not key event based anymore, function keyPressed() is not so useful to ya now.

Instead, you can check whether a key is being pressed using internal variable -> keyPressed.

Pay attention function keyPressed() is not the same as variable keyPressed!

So, inside draw(), you make an -> if (keyPressed) saveFrame("screen-####.jpg");

But beware that you'll get 24 frame saves per second! Since you got a frameRate(24)!

Now, here's a trick: you can use operator % against variable frameCount to skip some frame saves.

Here's how -> if (keyPressed & frameCount % 4 == 0) saveFrame("screen-####.jpg");

It means that if the rest of the division of frameCount by 4 is not 0, you got no saveFrame().

So, outta 4 draw() calls, you got 1 saveFrame()!

That is, if a key is being pressed as well!

gloopical

Re: Help creating frames

6 months ago

Huh, that is already on my code, I must have just missed that out when copying and pasting. Sorry!

I also had .jpg after the screen-#### but I know I did miss it off at one point, then I did some ctrl z-ing... and completely forgot. But it wasn't working with either of those anyway.

Well, the problem is that when the program is run, it generates the frames continuously without any intervention but isn't saving them at all for some reason. Which is odd considering I have the saveFrame function in there.

gloopical

Re: Help creating frames

6 months ago

Ahhh, ok I didn't realise there was a difference there.

This is starting to make a lot more sense now, I'll give this a go!

... Hm, I'm fairly sure now that I'm still doing this wrong. Sorry for being a pain in... well, for being a pain :P

Once again, this is what I have at the moment, and I'm fairly sure that what I'm doing with that redraw at the end isn't quite right, but don't know if that's the problem.

float xstart, xnoise, ystart, ynoise;
void setup() {
size(2000, 1000);
frameRate(24);
smooth();
stroke(200);
xstart=random(10);
ystart=random(10);
}
void draw() {
background(-1);
xnoise = xstart = random(10);
ynoise = ystart = random(10);
for (int y=0; y<=height; y+=5) {
ynoise += .1;
xnoise = xstart;
for (int x=0; x<=width; x+=5) {
xnoise += .01;
drawPoint( x, y, noise(xnoise, ynoise) );
}
}
}
void drawPoint(float x, float y, float noiseFactor) {
float len = 10*noiseFactor;
rect(x, y, len, len);
}
if(keyPressed){
saveFrame("screen-####.jpg");
}
redraw();

Thanks for putting up with this guys. I'm usually a quick learner but I think I can safely say that this is the exception right here...

GoToLoop

Re: Help creating frames

6 months ago

I know my explanation above was very long and boring!

But as I've already implied there, redraw() is only relevant when used in conjunction w/ noLoop()!

Also, you can't have runaway statements like that outta the scope of some function!

Pay attention you let if(keyPressed) ... and redraw() outside any scope of a function/method!

That is, they don't belong to any functions!!!

I advise you to take my example above which is working already,

and modified it as it's always continually re-rendering.

gloopical

Re: Help creating frames

6 months ago

Hm, I was using yours to modify from, originally though it was just rendering new frames when I pressed enter, otherwise it waited for me to do something; then I fiddled around to get it constantly making new ones.

Ah, I get what you mean by inside functions now. At least I think. Tried the:

if(keyPressed){

saveFrame("screen-####.jpg");

... inside of the void draw function, and then in the void drawPoint function, but still not saving. I'm starting to like the idea of having these as a series of still images to be honest, in which case, your original modifications will work perfectly as I won't need anywhere near as many frames as when animating, ten would probably do. Just annoyed that I can't get my head round this. Feeling very silly!

GoToLoop

Re: Help creating frames

6 months ago

Well, here's my example modified to keep rendering all the time.

Hold down any key to start saving, skipping SKIP - 1 times outta FPS frames!

To tweak program's behavior, just change those final constant values!

// http://forum.processing.org/topic/help-creating-frames

final static byte DIM = 15, HALF_DIM = DIM>>1;
final static byte FPS = 4, SKIP = 2;

final static float XINC = .01, YINC = .1;
final static color BG = -1, FG = 220;

final static String FILE = "screen-####.jpg";

void setup() {
  size(1000, 500);
  frameRate(FPS);
  smooth();
  stroke(FG);
}

void draw() {
  background(BG);

  float noiseX, startX = random(DIM);
  float noiseY = random(DIM);

  for (int y=0; y<height; y+=HALF_DIM) {
    noiseY += YINC;
    noiseX = startX;

    for (int x=0; x<width; x+=HALF_DIM) {
      noiseX += XINC;
      drawPoint(x, y, noise(noiseX, noiseY), DIM);
    }
  }

  if (keyPressed & frameCount % SKIP == 0)    saveFrame(FILE);
}

void drawPoint(float x, float y, float noiseFactor, int amp) {
  float len = noiseFactor * amp;
  rect(x, y, len, len);
}

gloopical

Re: Help creating frames

6 months ago

Ah, that's working beautifully now. Thank you so so much GoToLoop! You've been a fantastic help. I apologise for not getting it quicker, my brain has been a bit... well, gone... these last few days. Thanks for your patience.

Top Reply