Having trouble using map() with variables shared between classes (beginner)

Programming Questions

animan

Having trouble using map() with variables shared between classes (beginner)

in Programming Questions • 1 year ago

Hi,

I'm learning OOP and I'm having trouble getting map() to work using variables shared between classes. Here's what's giving me trouble:

Ball ball1;
Ball ball2;
Slider slider1;
Slider slider2;
void setup() {
ball1 = new Ball(1,1,1,1.5);
ball2 = new Ball(100,100,2,2.5);
slider1 = new Slider(ball1.xSpeed,ball1.ySpeed,449,474);
slider2 = new Slider(ball2.xSpeed,ball2.ySpeed,474,height);
}
void draw() {
ball1.update();
ball1.draw();
ball2.update();
ball2.draw();
slider1.draw();
slider2.draw();
//etc.
}
void mouseDragged() {
slider1.mouseDragged();
slider2.mouseDragged();
}
class Ball {
float x = 1;
float y = 1;
float xSpeed = 0;
float ySpeed = 0;
Ball(float tempX, float tempY, float tempXSpeed, float tempYSpeed) {
x = tempX;
y = tempY;
xSpeed = tempXSpeed;
ySpeed = tempYSpeed;
}
//etc.
}
class Slider {
float sliderXSpeed = 0;
float sliderYSpeed = 0;
float sliderTop = 0;
float sliderBottom = 0;
Slider(float tempSliderXSpeed, float tempSliderYSpeed, float tempSliderTop, float tempSliderBottom) {
sliderXSpeed = tempSliderXSpeed;
sliderYSpeed = tempSliderYSpeed;
sliderTop = tempSliderTop;
sliderBottom = tempSliderBottom;
}
void draw() {
// Draw slider
fill(0);
rect(0, sliderTop, width, buttonHeight);
for (int section = 0; section < width; section = section + 10) {
line(section, sliderTop, section, height);
}
fill(255);
// Draw slider bar
float m = map(sliderXSpeed, 0, 10, 0, width);
rect(abs(m)-5, sliderTop, 10, buttonHeight);
}
void mouseDragged() {
if (mouseX > 0 && mouseX < width && mouseY > sliderTop && mouseY < sliderBottom) {
if (sliderXSpeed > 0 && sliderYSpeed > 0) {
float positivemX = map(mouseX, 0, width, 0, 10);
float positivemY = map(mouseX, 0, width, 0, 15);
sliderXSpeed = positivemX;
sliderYSpeed = positivemY;
}
if (sliderXSpeed < 0 && sliderYSpeed < 0) {
float negativemX = map(mouseX, 0, width, 0, -10);
float negativemY = map(mouseX, 0, width, 0, -15);
sliderXSpeed = negativemX;
sliderYSpeed = negativemY;
}
if (sliderXSpeed > 0 && sliderYSpeed < 0) {
float positivemX = map(mouseX, 0, width, 0, 10);
float negativemY = map(mouseX, 0, width, 0, -15);
sliderXSpeed = positivemX;
sliderYSpeed = negativemY;
}
if (sliderXSpeed < 0 && sliderYSpeed > 0) {
float negativemX = map(mouseX, 0, width, 0, -10);
float positivemY = map(mouseX, 0, width, 0, 15);
sliderXSpeed = negativemX;
sliderYSpeed = positivemY;
}
}
}
}

The variables sliderXSpeed and sliderYSpeed are using variables from another class (Ball). SliderXSpeed is working in "float m = map(sliderXSpeed, 0, 10, 0, width);" but not in mouseDragged() below it. I'm not sure if this has to do with how I'm using mouseDragged() or map() or because of how I'm assigning the variables positivemX etc. to sliderXSpeed etc.

Thanks for your help!

Replies(3)

PhiLho

Re: Having trouble using map() with variables shared between classes (beginner)

1 year ago

What is "not working"?
We cannot run your code, which is incomplete.
Do you have a compilation error? Not the behavior you expect? If so, what do you expect, and what do you get?
You started to reduce the code, that's not a bad idea, but either reduce it to something runnable, or even make a small independent sketch showing better what is your specific issue.

animan

Re: Re: Having trouble using map() with variables shared between classes (beginner)

1 year ago

The code creates two horizontal sliders that are meant to control the speeds of two balls. The sketch runs without error, and a short vertical bar mapped to the slider can be moved back and forth (this bar is created by a map with

float m = map(sliderXSpeed, 0, 10, 0, width);
rect(abs(m)-5, sliderTop, 10, buttonHeight);

and it works). The problem I'm encountering is that, while the bars on both sliders move, moving them doesn't change the speeds of the balls. This is what I intend for the map() function in mouseDragged() to do. Here is the full code that I'm working on if running the sketch will help:

// Stop button position
float sButtonX = 0;
// Play button position
float pButtonX = 250;
// Coordinates shared by both buttons
float buttonY = 424;
float buttonWidth = 250;
float buttonHeight = 25;
float buttonBottom = 449;
// Circle will not move at start
boolean moving = false;
Ball ball1;
Ball ball2;
Slider slider1;
Slider slider2;
void setup() {
size(500,500);
smooth();
ball1 = new Ball(1,1,1,1.5);
ball2 = new Ball(100,100,2,2.5);
slider1 = new Slider(ball1.xSpeed,ball1.ySpeed,449,474);
slider2 = new Slider(ball2.xSpeed,ball2.ySpeed,474,height);
}
boolean button() {
// Freeze circle on button press
if (mouseX > sButtonX && mouseX < buttonWidth && mouseY > buttonY && mouseY < buttonBottom) {
moving = false;
}
// Move circle on button press
if (mouseX > pButtonX && mouseX > buttonWidth && mouseY > buttonY && mouseY < buttonBottom) {
moving = true;
rect(pButtonX,buttonY,buttonWidth,buttonHeight);
}
return true;
}
void draw() {
background(0);
ball1.update();
ball1.draw();
ball2.update();
ball2.draw();
slider1.draw();
slider2.draw();
stroke(255);
strokeWeight(2);
// Stop button color feedback on press
if (!moving) {
fill(255,0,0);
}
else {
fill(0);
}
// Draw stop button
rect(sButtonX,buttonY,buttonWidth,buttonHeight);
if (!moving) {
fill(0);
stroke(255);
}
else {
fill(255);
}
rect(119,430,12,12);
// Play button color feedback on press
if (moving) {
fill(75,162,30);
}
else {
fill(0);
}
// Draw play button
rect(pButtonX,buttonY,buttonWidth,buttonHeight);
if (moving) {
fill(0);
}
else {
fill(255);
}
triangle(369,430,369,442,381,436);
}
void mousePressed() {
button();
}
void mouseDragged() {
slider1.mouseDragged();
slider2.mouseDragged();
}
class Ball {
// Circle positions, radius, and speed
float x = 1;
float y = 1;
float r = 50;
float xSpeed = 0;
float ySpeed = 0;
Ball(float tempX, float tempY, float tempXSpeed, float tempYSpeed) {
x = tempX;
y = tempY;
xSpeed = tempXSpeed;
ySpeed = tempYSpeed;
}
void draw() {
fill(255);
// Draw circle
ellipse(x+r/2, y+r/2, r, r);
}
// Circle will move when "moving" becomes true (see below)
void update() {
if (moving) {
x = x + xSpeed;
y = y + ySpeed;
}
// Reverse direction when the circle hits an edge
if (x > width-r) {
xSpeed = xSpeed*-1;
x = width-r;
}
if (x < 0) {
xSpeed = xSpeed*-1;
x = 0;
}
if (y > buttonY-r) {
ySpeed = ySpeed*-1;
y = buttonY-r;
}
if (y < 0) {
ySpeed = ySpeed*-1;
y = 0;
}
}
}
class Slider {
float sliderXSpeed = 0;
float sliderYSpeed = 0;
float sliderTop = 0;
float sliderBottom = 0;
Slider(float tempSliderXSpeed, float tempSliderYSpeed, float tempSliderTop, float tempSliderBottom) {
sliderXSpeed = tempSliderXSpeed;
sliderYSpeed = tempSliderYSpeed;
sliderTop = tempSliderTop;
sliderBottom = tempSliderBottom;
}
void draw() {
// Draw slider
fill(0);
rect(0, sliderTop, width, buttonHeight);
for (int section = 0; section < width; section = section + 10) {
line(section, sliderTop, section, height);
}
fill(255);
// Draw slider bar
float m = map(sliderXSpeed, 0, 10, 0, width);
rect(abs(m)-5, sliderTop, 10, buttonHeight);
}
void mouseDragged() {
// Adjust circle speed.
if (mouseX > 0 && mouseX < width && mouseY > sliderTop && mouseY < sliderBottom) {
if (sliderXSpeed > 0 && sliderYSpeed > 0) {
float positivemX = map(mouseX, 0, width, 0, 10);
float positivemY = map(mouseX, 0, width, 0, 15);
sliderXSpeed = positivemX;
sliderYSpeed = positivemY;
}
if (sliderXSpeed < 0 && sliderYSpeed < 0) {
float negativemX = map(mouseX, 0, width, 0, -10);
float negativemY = map(mouseX, 0, width, 0, -15);
sliderXSpeed = negativemX;
sliderYSpeed = negativemY;
}
if (sliderXSpeed > 0 && sliderYSpeed < 0) {
float positivemX = map(mouseX, 0, width, 0, 10);
float negativemY = map(mouseX, 0, width, 0, -15);
sliderXSpeed = positivemX;
sliderYSpeed = negativemY;
}
if (sliderXSpeed < 0 && sliderYSpeed > 0) {
float negativemX = map(mouseX, 0, width, 0, -10);
float positivemY = map(mouseX, 0, width, 0, 15);
sliderXSpeed = negativemX;
sliderYSpeed = positivemY;
}
}
}
}

Thanks!

PhiLho

Re: Having trouble using map() with variables shared between classes (beginner)

1 year ago

Aaah, I see better now. The problem is that you made a quite common incorrect assumption:
slider1 = new Slider(ball1.xSpeed,ball1.ySpeed,449,474);
slider2 = new Slider(ball2.xSpeed,ball2.ySpeed,474,height);
With these calls, you pass the current value in the call, but there no further connection with the class' fields: it is a one way communication, only at call time. No binding in Java (not directly, at least).

Since a slider is directly connected to a ball, one of the best ways to handle this is just to pass the corresponding ball as parameter, instead of passing the speeds: here, you pass a reference to the ball, so update of its values will update the corresponding values (objects work differently from primitive values like ints or floats).

So, remove sliderXSpeed and Y too, add a Ball field, set it in the constructor. Where you have sliderXSpeed update, update instead ball.xSpeed directly, etc.

Side note: about sliderXSpeed name: since it is inside a Slider class, the "slider" part is a bit redundant, and annoying to type in the PDE...