Having touble figuring out a grid problem

Programming Questions

adkins380

Having touble figuring out a grid problem

in Programming Questions • 7 months ago

I want to take the grid and be able to change the inside of one of the rectangles to a random color when you click inside of it, have made many attempts but cannot figure out how it is done. here is the grid i have.

int boxsize = 50;

int cols, rows;

void setup()

{

size(500, 500);

textAlign(CENTER);

textSize(24);

cols = width/boxsize;

rows = height/boxsize;

}

void draw() {

for (int i = 0; i < cols; i++) {

for (int j = 0; j < rows; j++) {

int x = i*boxsize;

int y = j*boxsize;

if (mouseX >= x && mouseX < x + boxsize &&

mouseY >= y && mouseY < y + boxsize)

{

fill(#1AC4FF);

}

else {

fill(255);

}

stroke(0);

rect(x, y, boxsize, boxsize);

}

any help is appreciated.

Replies(5)

Chrisir

Re: Having touble figuring out a grid problem

7 months ago

1st approach

you can also store the random color or change it only once

int boxsize = 50;
int cols, rows;
void setup()
{
size(500, 500);
textAlign(CENTER);
textSize(24);
cols = width/boxsize;
rows = height/boxsize;
}
void draw() {
for (int i = 0; i < cols; i++) {
for (int j = 0; j < rows; j++) {
int x = i*boxsize;
int y = j*boxsize;
if (mouseX >= x && mouseX < x + boxsize &&
mouseY >= y && mouseY < y + boxsize)
{
// fill(#1AC4FF);
if (mousePressed)
fill (random(0, 255), random(0, 255), random(0, 255));
}
else {
fill(255);
}
stroke(0);
rect(x, y, boxsize, boxsize);
}
}
}
//

adkins380

Re: Having touble figuring out a grid problem

7 months ago

how would i get the color to stay, if i clicked, make it so that that random color that comes out only changes if i click again or do a different button click. like if(mousePressed && (mouseButton == LEFT) and then if i added one for the right as well it would only change if i clicked again.

Chrisir

Re: Having touble figuring out a grid problem

7 months ago

to store the color you would need an 2D array and store and retrieve the color there

a 2D array is a grid of data. you tell it row and col and there is a color stored.

color [][] = new color [cols][rows] ;

if (mousePressed)
{
color [i][j] = color ( random(0, 255), random(0, 255), random(0, 255));
}

and use it with

fill ( color [i][j] );

e.g. in line 24

Chrisir

Re: Having touble figuring out a grid problem

7 months ago

like this....

sorry, I hadn't time earlier

//
int boxsize = 50;
int cols, rows;
color [][] colorGrid ;
int x;
int y;
//
void setup() {
// init
size(500, 500);
textAlign(CENTER);
textSize(24);
cols = width/boxsize;
rows = height/boxsize;
colorGrid = new color [cols][rows] ;
for (int i = 0; i < cols; i++) {
for (int j = 0; j < rows; j++) {
colorGrid [i][j] = color ( 255 );
} // for
} // for
} // func
//
void draw() {
// main function
for (int i = 0; i < cols; i++) {
for (int j = 0; j < rows; j++) {
x = i*boxsize;
y = j*boxsize;
fill ( colorGrid [i][j] ); // fill(#1AC4FF); // fill(255);
stroke(0);
rect(x, y, boxsize, boxsize);
} // for
} // for
} // func
//
void mouseReleased () {
// gets called automatically when Mouse is released.
// then checks which cell is pressed and set random color.
int x;
int y;
for (int i = 0; i < cols; i++) {
x = i*boxsize;
if (mouseX >= x && mouseX < x + boxsize) {
for (int j = 0; j < rows; j++) {
y = j*boxsize;
if (mouseY >= y && mouseY < y + boxsize) {
colorGrid [i][j] = color ( random(0, 255), random(0, 255), random(0, 255));
return; // leave function immediately
} // if
} // for
} // if
} // for
} // func
//

krashe1313

Re: Having touble figuring out a grid problem

2 months ago

fantastic tutorial. i was looking to accomplish something along these lines

Top Reply