gwoptics rolling graph of accelerometer

jonpeters..

gwoptics rolling graph of accelerometer

in Contributed Library Questions • 1 year ago

I am trying to create a live graph of accelerometer readings using the gwoptics library. The problem is I am not sure the best way pass the serial readings to the gwoptics eq class. The only way I could get it to work, is to read the serial string inside the eq class definition. However this seems very sloppy, ideally I would like to read the serial string in draw(), split it up and pass each axis variable to a respective eq class, I just can't get it to work. I modified the example code provided with the library. The the "working" code is below. I am pretty new to programming and processing so any help at all is appreciated, thanks.

import processing.serial.*;
import org.gwoptics.graphics.graph2D.Graph2D;
import org.gwoptics.graphics.graph2D.traces.ILine2DEquation;
import org.gwoptics.graphics.graph2D.traces.RollingLine2DTrace;
float inByteX;
float inByteY;
float inByteZ;
String xAxis;
String yAxis;
String zAxis;
String accelReadings;
String splitReadings[];
Serial myPort;
RollingLine2DTrace r,r2,r3;
Graph2D g;
void setup(){
size(600,300);
println(Serial.list());
myPort = new Serial(this, Serial.list()[0], 57600);
r = new RollingLine2DTrace(new eq(),25,.025f);
r.setTraceColour(0, 255, 0);
g = new Graph2D(this, 400, 200, false);
g.setYAxisMax(600);
g.addTrace(r);
g.position.y = 50;
g.position.x = 100;
g.setYAxisTickSpacing(100);
g.setXAxisMax(5f);
}
void draw(){
print(xAxis);
print(",");
print(yAxis);
print(",");
println(zAxis);
background(255);
g.draw();
}
class eq implements ILine2DEquation{
public double computePoint(double x,int pos) {
accelReadings = myPort.readStringUntil('\n');
splitReadings = splitTokens(accelReadings, ",");
xAxis = splitReadings[0];
yAxis = splitReadings[1];
zAxis = splitReadings[2];
inByteX = float(xAxis);
return inByteX;
}
}

Replies(4)

eldiegoefe

Re: gwoptics rolling graph of accelerometer

1 year ago

I´m new to Processing, too (and not very skilled about programming). Anyway, I wanted to suggest you to take a look at the "Blank2DCanvas" examples. They show how to plot arrays of data (like the ones you probably get from your port) instead of math functions.

Any other advice from people here will be double welcomed.

DB_87

Re: gwoptics rolling graph of accelerometer

1 year ago

So for this sort of problem the RollingLine2DTrace is probably better as it handles the timing for you so you're not constantly calling the serial function, it was originally written for this sort of scenario. So the way the RollingLine2DTrace works is that the first one you add becomes the master trace. Each time the timer ticks the master trace calls its equation and it then goes off and updates all the other traces so that they all update in sync, the downside to this is you can't have multiple traces updating at different times. You can use this to read the serial in the master thread's equation and then store the data so that the other traces just need to return a value. I modified your code to show how this works, but swapped out the serial read for a generated function.

Hope this helps!

import processing.serial.*;
import org.gwoptics.graphics.graph2D.Graph2D;
import org.gwoptics.graphics.graph2D.traces.ILine2DEquation;
import org.gwoptics.graphics.graph2D.traces.RollingLine2DTrace;
float inByteX;
float inByteY;
float inByteZ;
String xAxis;
String yAxis;
String zAxis;
String accelReadings;
String splitReadings[];
Serial myPort;
RollingLine2DTrace rx,ry,rz;
Graph2D g;
int t=0;
String genData(){
return sin(t*2.0*PI/100.0) + "," + sin(t*2.5*PI/100.0) + "," + sin(t*3.0*PI/100.0);
}
void setup(){
size(600,300);
// println(Serial.list());
//myPort = new Serial(this, Serial.list()[0], 57600);
rx = new RollingLine2DTrace(new eq_x(),25,.025f);
rx.setTraceColour(255, 0, 0);
ry = new RollingLine2DTrace(new eq_y(),25,.025f);
ry.setTraceColour(0, 255, 0);
rz = new RollingLine2DTrace(new eq_z(),25,.025f);
rz.setTraceColour(0, 0, 255);
g = new Graph2D(this, 400, 200, false);
g.setYAxisMin(-1.2);
g.setYAxisMax(1.2);
g.addTrace(rx);
g.addTrace(ry);
g.addTrace(rz);
g.position.y = 50;
g.position.x = 100;
g.setYAxisTickSpacing(0.4);
g.setXAxisMax(5f);
}
void draw(){
t++;
print(xAxis);
print(",");
print(yAxis);
print(",");
println(zAxis);
background(255);
g.draw();
}
class eq_x implements ILine2DEquation{
public double computePoint(double x,int pos) {
accelReadings = genData();//myPort.readStringUntil('\n');
splitReadings = splitTokens(accelReadings, ",");
xAxis = splitReadings[0];
yAxis = splitReadings[1];
zAxis = splitReadings[2];
return float(xAxis);
}
}
class eq_y implements ILine2DEquation{
public double computePoint(double x,int pos) {
return float(yAxis);
}
}
class eq_z implements ILine2DEquation{
public double computePoint(double x,int pos) {
return float(zAxis);
}
}

jonpeters..

Re: gwoptics rolling graph of accelerometer

1 year ago

Thanks DB! That helps a lot. Could you clue me in on how the tick intervals work? I don't understand the "f" part in

g.setXAxisMax(5f);

and

rx = new RollingLine2DTrace(new eq_x(),25,.025f);

I realized another reason I was struggling to figure this out (in case anyone cares), was there wasn't always more data waiting to be read when I would do the serial read. I changed the code (on both ends) so that data is only sent (from arduino) when a character is received from the processing sketch. This seems to run really well, but I still occasionally see Null Pointer errors flash across the terminal window. I thought I could remedy this by using a serialEvent, so the data is only read and stored when it is actually there, but the graph doesn't seem as clean with this method. Would be happy to hear if anyone has any input on this. Here is the code:

import processing.serial.*;
import org.gwoptics.graphics.graph2D.Graph2D;
import org.gwoptics.graphics.graph2D.traces.ILine2DEquation;
import org.gwoptics.graphics.graph2D.traces.RollingLine2DTrace;
String xAxis,yAxis,zAxis;
String accelReadings;
String splitReadings[];
float xData,yData,zData;
Serial myPort;
RollingLine2DTrace rx,ry,rz;
Graph2D g;
int t=0;
//String genData(){
// return sin(t*2.0*PI/100.0) + "," + sin(t*2.5*PI/100.0) + "," + sin(t*3.0*PI/100.0);
//}
void setup(){
size(600,300);
println(Serial.list());
myPort = new Serial(this, Serial.list()[0], 57600);
myPort.write(1); //request data string
myPort.bufferUntil('\n');
rx = new RollingLine2DTrace(new eq_x(),20,.025f);
rx.setTraceColour(255, 0, 0);
ry = new RollingLine2DTrace(new eq_y(),20,.025f);
ry.setTraceColour(0, 255, 0);
rz = new RollingLine2DTrace(new eq_z(),20,.025f);
rz.setTraceColour(0, 0, 255);
g = new Graph2D(this, 400, 200, false);
g.setYAxisMin(200);
g.setYAxisMax(500);
g.addTrace(rx);
g.addTrace(ry);
g.addTrace(rz);
g.position.y = 50;
g.position.x = 100;
g.setYAxisTickSpacing(100);
g.setXAxisMax(5f);
}
void draw(){
t++;
print(xAxis);
print(",");
print(yAxis);
print(",");
println(zAxis);
background(255);
g.draw();
}
class eq_x implements ILine2DEquation{
public double computePoint(double x,int pos) {
myPort.write(1); //request data string
readSerialData();//read, split, and update stored values
return float(xAxis);
}
}
class eq_y implements ILine2DEquation{
public double computePoint(double x,int pos) {
return float(yAxis);
}
}
class eq_z implements ILine2DEquation{
public double computePoint(double x,int pos) {
return float(zAxis);
}
}
void readSerialData(){
String accelReadings =myPort.readStringUntil('\n'); //genData();
String [] splitReadings = splitTokens(accelReadings, " ,");
xAxis = splitReadings[0];
yAxis = splitReadings[1];
zAxis = splitReadings[2];
}
//
//void serialEvent (Serial myPort) {
//readSerialData();
//}

mallemang

Re: gwoptics rolling graph of accelerometer

10 months ago

is it possible to stop/resume the RollingLine2DTrace from scrolling on command...ie: using keyPressed() ??

Top Reply