graphical strange results with blend() function, EXCLUSION mode

Programming Questions

steppog

graphical strange results with blend() function, EXCLUSION mode

in Programming Questions • 3 years ago

Hi all,

I guess my first problem is in relation with following previous discussions (unfortunately I am not abble to understand them totally) :

http://processing.org/bugs/bugzilla/132.html

http://code.google.com/p/processing/issues/detail?id=133&can=1&q=blend&colspec=ID

While using EXCLUSION mode of the blend() function, with only black and white, I got quickly greys with the code bellow :

PGraphics img1;
int nb = 2;
int x, y, a;
boolean bStop;

void setup() {
size(400, 400, P2D);
background(0);
img1 = createGraphics(400, 400, P2D);
img1.ellipseMode(CENTER);
img1.fill(255);
img1.noStroke();
smooth();
}

void draw() {

img1.beginDraw();
img1.background(0);
x = width/nb * int (random(nb+1));
y = int (width/nb * int (random(nb+1)));
a = width/nb*2;
img1.ellipse(x,y,a,a);
img1.endDraw();

blend(img1, 0, 0, width, height, 0, 0, width, height, EXCLUSION);
}

void keyPressed(){
bStop = !bStop;
if (bStop)
noLoop();
else
loop();
}

Another trouble is that it creates outlines around identical superimposed forms as positions and sizes are strictly the same between scrImg and the display window.

And it curiously seems to work better with :

blend(img1, 0, 0, width, height, 0, 0, width -1, height-1, EXCLUSION);

Thank you for your help!

Replies(4)

davbol

Re: graphical strange results with blend() function, EXCLUSION mode

3 years ago

What you're experiencing is accumulated rounding errors. The various blend functions as implemented in Processing all have a tiny bit of error as a tradeoff for overall performance. (it comes from using shift operations to approximate divisions) Normally this tiny error isn't noticeable, the calculated value is typically off by one of the 'ideal' value, but when you use it like your example, repeatedly applying the same operation frame after frame, then eventually those errors will become noticeable.

Exclusion is a particularly bad case, because this type of 'rounding error' occurs twice, both in the blend equation itself, as well as in the alpha equation (which is present in all blend modes). So you'll notice the accumulated errors even faster with this mode.

FWIW, if you're up to the challenge, you can rip out the guts of blit_resize() from PImage.java, and reimplement your own custom version just for blend_exclusion(). The two changes necessary to fix the rounding in blend_exclusion are:

repeat for all three color channels..

old version (where last term is equivalent to "/ 128", which is 'fast but wrong'):

int cr = ar + br - ((ar * br) >> 7);
new version (last term equiv to / 127.5 which is 'slow but right')

int cr = ar + br - ((2 * ar * br) / 255);

2) in the alpha blending equation replace all three ">> 8" with "/ 255"

This version will accumulate far longer (perhaps indefinately) before any integer errors become significant enough to notice.

steppog

Re: graphical strange results with blend() function, EXCLUSION mode

3 years ago

Thanks for the answer!

Unfortunately I don't believe I am ready for the challenge to change PImage.java code, even if the changes are very detailled in your answer... Perhaps one day, an option for "ideal" values should exist?

Also, do accumulated rounding errors explain outlines arounds identical forms?

Thx.

davbol

Re: graphical strange results with blend() function, EXCLUSION mode

3 years ago

>> Also, do accumulated rounding errors explain outlines arounds identical forms?

In part. Though for that aspect of your problem, they're the symptom not the cause - they merely expose another problem. The real culprit appears to be a related bug in blend()'s coordinate scaling calculations. I'd suggest you submit it as a proper bug report, so fry can properly investigate; here's some "test-bed" code you can use/submit if you choose:

// purpose: to demonstrate a scaling problem in blend()
size(500,500,P2D);
PGraphics offscreen = createGraphics(width,height,P2D);
beginRecord(offscreen);
background(0);
fill(255);
noStroke();
ellipse(width/2,height/2,width-2,height-2);
endRecord();
// these two should be identical (duh?)
save("onscreen.png");
offscreen.save("offscreen.png");
// this works correctly as far as scaling, same a previos two
// (intended to help 'isolate' scaling problem to blend())
image(offscreen,0,0,width,height);
save("blitted.png");
// this SHOULD be functionally the same as image() above, but...
// this DOES NOT work correctly, as there is a set of
// "one-too-big" errors in PImage.blend() at/around
// line 1492 where sx2/sy2/dx2/dy2 are calculated:
blend(offscreen,0,0,width,height,0,0,width,height,BLEND);
save("blended.png");
// this corrects the scaling, by "hacking" in "one-too-small"
// values that then calculate "one-too-big", so the scaling factor
// is calculated correctly, but problem then is that output
// extent is incorrect (see red fringe)
background(255,0,0);
blend(offscreen,0,0,width-1,height-1,0,0,width-1,height-1,BLEND);
save("blended_hack.png");
exit();
// now layer the various images in Photoshop to
// compare pixels at edges of ellipse

steppog

Re: graphical strange results with blend() function, EXCLUSION mode

3 years ago

Done :

http://code.google.com/p/processing/issues/detail?id=285&q=blend&colspec=ID

Top Reply