There are different ways. You can use things like pixels, vertices, shaders, masking etc. So lines are definitely not the only option. What do you mean by "the gradient function"? It sounds like you have some other program in mind which has such a function, perhaps illustrator or photoshop? These programs have linear and radial gradients that can be simply recreated in Processing. Check the examples, OpenProcessing and/or the forum(s). I believe this has been done before.

Here is a proof-of-concept example that works under both Processing 1.5.1 and 2.0b7.

Code Example

1. PImage gradient;
2. PGraphics shape;
3. 
   
4. void setup() {
5.   size(500, 500);
6.   gradient = createImage(width, height, RGB);
7.   shape = createGraphics(width, height, JAVA2D);
8. }
9.  
10. void draw() {
11.   background(255);
12.   drawGradient();
13.   drawShape(8, 0.005);
14.   gradient.mask(shape);
15.   image(gradient, 0, 0);
16. }
17.  
18. void drawGradient() {
19.   colorMode(HSB, 300, 100, 100);
20.   gradient.loadPixels();
21.   for (int y=0; y<gradient.height; y++) {
22.     for (int x=0; x<gradient.width; x++) {
23.       int index = x + y * gradient.width;
24.       float distance = dist(x, y, mouseX, mouseY);
25.       gradient.pixels[index] = color(distance, 100, 100);
26.     }
27.   }
28.   gradient.updatePixels();
29.   colorMode(RGB, 255, 255, 255);
30. }
31.  
32. void drawShape(int numPoints, float speed) {
33.   shape.beginDraw();
34.   shape.background(0);
35.   shape.noStroke();
36.   shape.fill(255);
37.   shape.beginShape();
38.   float fc = frameCount * speed;
39.   float x = noise(fc+numPoints-1)*shape.width;
40.   float y = noise(fc+numPoints)*shape.height;
41.   shape.curveVertex(x, y);
42.   for (int i=0; i<numPoints; i++) {
43.     x = noise(fc+i)*shape.width;
44.     y = noise(fc+i+1)*shape.height;
45.     shape.curveVertex(x, y);
46.   }
47.   x = noise(fc)*shape.width;
48.   y = noise(fc-1)*shape.height;
49.   shape.curveVertex(x, y);
50.   shape.endShape();
51.   shape.endDraw();
52. }

thank you very much, Amnon!

I see that you're creating an image and updating the color of the pixels accordingly ...

learning ...

Before I forget ...

Thank you very much for your very kind and invaluable help and advices all the time!

Merry Xmas! and Wish you and all "Processingers" a happy, healthy, and prosperous new year!

- J

No problem and a happy new year to you as well.