glVertexAttribPointer and the PGL object in 2.0a6

Core Library Questions

billautom..

glVertexAttribPointer and the PGL object in 2.0a6

in Core Library Questions • 1 year ago

PGraphicsOpenGL mainGL; // the main screen

PGL pgl; // make raw GL calls here

mainGL = (PGraphicsOpenGL)g;

pgl = mainGL.beginPGL();

int numVerts = 32;

float[] verts = new float[numVerts*2]; //xyxyxyxyxyxy

for(int i = 0; i < verts.length; i++){

verts[i] = random(512.0);

}

FloatBuffer vertexBuffer = FloatBuffer.wrap(verts);

int[] vboIDs = new int[1];

pgl.glGenBuffers(1, vboIDs, 0);

pgl.glBindBuffer(pgl.GL_ARRAY_BUFFER, vboIDs[0]);

pgl.glBufferData(pgl.GL_ARRAY_BUFFER, numVerts*2*4, vertexBuffer, pgl.GL_STATIC_DRAW);

pgl.glBindBuffer(pgl.GL_ARRAY_BUFFER, vboIDs[0]);

pgl.glVertexAttribPointer(0, 2, pgl.GL_FLOAT, false, numVerts*2*4, 0);

pgl.glEnableVertexAttribArray(0);

mainGL.endPGL();

/////

pgl.glVertexAttribPointer(0, 2, pgl.GL_FLOAT, false, numVerts*2*4, 0);

What am I passing as the first argument here? I'm only familiar with the old way, I don't know what shader program I an querying to get the location of the vertex attributes. I'm trying to make OpenCL aware of these GL objects and PShape is getting in the way. Thanks!

Replies(2)

andres

Re: glVertexAttribPointer and the PGL object in 2.0a6

1 year ago

Hello, the first argument of the glVertexAttribPointer function is the location (in the shader program) of the vertex attribute you are passing the buffers to. You should call glVertexAttribPointer once the shader is bound, however the built-in shaders that Processing uses for rendering are only bound when the geometry is flushed to the video card. So, in order to do the rendering through low-level OpenGL calls, you currently need to add all the shader handling code within beginPGL/endPGL, something along these lines:

pgl = pg.beginPGL();
// Create shader program
int vert = pgl.glCreateShader(GL_VERTEX_SHADER);
pgl.glShaderSource(vert, vertSource);
...
int prog = pgl.glCreateProgram();
pgl.glAttachShader(prog, vert);
pgl.glAttachShader(prog, frag);
pgl.glLinkProgram(prog);
...
// Getting uniform and attribute locations
loc = pgl.glGetAttribLocation(prog, "inVertex");
...
// Bind shader
pgl.glUseProgram(prog);
// Copy data to video memory
pgl.glEnableVertexAttribArray(loc);
pgl.glVertexAttribPointer(loc, 2, GL_FLOAT, false, 4 * SIZEOF_FLOAT, data);
// Render
glDrawArrays(GL_TRIANGLE_STRIP, 0, 4);
// Clean-up
glDisableVertexAttribArray(loc);
pgl.glUseProgram(0);
// Done with low-level GL calls
pg.endPGL();

This is a good introductory tutorial on OpenGL programming using shaders.

andres

Re: glVertexAttribPointer and the PGL object in 2.0a6

1 year ago

I'd also like to note that the PShader API is still being straightened out.

One thing that it can be certainly very useful in these situations is the possibility to easily bind the built-in shaders in Processing and use them for low-level GL calls. I just committed some changes that allows precisely this. Although you won't be able to use this new API until the next release comes out (unless you want to build Processing by yourself from the trunk), here you have an example of how a sketch using low-level GL calls could end up looking like:

// Draws a triangle using low-level OpenGL calls.
import java.nio.FloatBuffer;
PGraphicsOpenGL pg;
PGL pgl;
PShader shader;
int vertLoc;
int colorLoc;
float[] vertices;
float[] colors;
FloatBuffer vertData;
FloatBuffer colorData;
void setup() {
size(400, 400, P3D);
pg = (PGraphicsOpenGL)g;
// Get the default shader that Processing uses to
// render flat geometry (w/out textures and lights).
shader = pg.getShader(PShader.FLAT);
vertices = new float[12];
vertData = PGL.allocateDirectFloatBuffer(12);
colors = new float[12];
colorData = PGL.allocateDirectFloatBuffer(12);
}
void draw() {
background(0);
// The geometric transformations will be automatically passed
// to the shader.
rotate(frameCount * 0.01f, width, height, 0);
updateGeometry();
pgl = pg.beginPGL();
shader.bind();
vertLoc = pgl.glGetAttribLocation(shader.glProgramObjectID, "inVertex");
colorLoc = pgl.glGetAttribLocation(shader.glProgramObjectID, "inColor");
pgl.glEnableVertexAttribArray(vertLoc);
pgl.glEnableVertexAttribArray(colorLoc);
pgl.glVertexAttribPointer(vertLoc, 4, PGL.GL_FLOAT, false, 0, vertData);
pgl.glVertexAttribPointer(colorLoc, 4, PGL.GL_FLOAT, false, 0, colorData);
pgl.glDrawArrays(PGL.GL_TRIANGLES, 0, 3);
pgl.glDisableVertexAttribArray(vertLoc);
pgl.glDisableVertexAttribArray(colorLoc);
shader.unbind();
pg.endPGL();
}
void updateGeometry() {
// Vertex 1
vertices[0] = 0;
vertices[1] = 0;
vertices[2] = 0;
vertices[3] = 1;
colors[0] = 1;
colors[1] = 0;
colors[2] = 0;
colors[3] = 1;
// Corner 2
vertices[4] = width/2;
vertices[5] = height;
vertices[6] = 0;
vertices[7] = 1;
colors[4] = 0;
colors[5] = 1;
colors[6] = 0;
colors[7] = 1;
// Corner 3
vertices[8] = width;
vertices[9] = 0;
vertices[10] = 0;
vertices[11] = 1;
colors[8] = 0;
colors[9] = 0;
colors[10] = 1;
colors[11] = 1;
vertData.rewind();
vertData.put(vertices);
vertData.position(0);
colorData.rewind();
colorData.put(colors);
colorData.position(0);
}

Top Reply