GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

zumbaree

GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

in Contributed Library Questions • 3 years ago

Hi All,
A question from relative newb: I'm trying to achieve the following:
draw left and right eye onto seperate textures using GLGraphicsOffScreen, than display them one on top of another using line interlaced masking (for my stereoscopic screen), and I think I'm stuck.
I don't feel fully ready to get into low-level GL calls yet, and GLGraphics seems like a good choice, I cant figure out however if it's possible to affect alpha only. Ideally I would draw my interlace pattern once and just 'freeze' alpha channel somehow, so following drawing methods ('line' and 'rect' mostly) would not affect the pattern.

The idea is that if later on I swich to a different displaying technique having both eyes in two offscreen buffers is not a bad starting point for further work but for now would just want to see what I'm doing on my 3D screen (which displays left and right eye in a row interlaced fashion)

I'm trying some dirty workarounds at the moment :

alphaImg=loadImage("alpha.jpg");
texture1=loadImage("random_image.jpg");
texture1.mask(alphaImg);
texture1.loadPixels();
texture2.putBuffer(texture1.pixels);

which does seem to load alpha values correctly, but as soon as I do ...

texture2=glg1.getTexture();

...it's (obviously) gone and doing any of that (based on offscreen example)...

glg1.beginDraw();
glg1.ellipse(random(0, glg1.width), random(0, glg1.height), random(10, 50), random(10, 50));
glg1.endDraw();

...just overwrites my buffer (adding some rubbish in the background too). Funny thing is that even if I only do getTexture once in the Setup, it still updates the texture as I draw onto the glg1

So the question is: is there anything I can use (term FBO sits in my head but I don't want to sound silly trying to put it into a sentence) that would keep my alpha and use it for masking the display of the second texture?

I'd rather leave my drawing to the library but if I need to learn manual GL now - that's what I'll have to do.

Am I even barking at the right tree?
Thanks a lot for any tips

Replies(13)

andres

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

3 years ago

I think the best way to do this with glgraphics would be to use a GLTextureFilter that blends your two textures into the output by alternatively intercalating lines or bands from each texture.

I wrote a simple example that shows how to do this. It is not included in the latest package of glgraphics yet, but you can get it from the trunk.

zumbaree

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

3 years ago

Hi Andres
Thanks a lot for a quick and in-depth answer!
GLTextureFilter does indeed seem like the most elegant option (and I guess it can be adapted to do colour corrected anaglyph too if someone wanted to)
I do however have issues trying to run your example:

Fragment shader BandedBlend.glsl compilation:
ERROR: 0:11: '=' : cannot convert from 'float' to 'int'
ERROR: 0:13: 'mod' : no matching overloaded function found
ERROR: 0:13: '==' : wrong operand types no operation '==' exists that takes a left-hand operand of type 'const float' and a right operand of type 'const int' (or there is no acceptable conversion)

GLSL program validation:
ERROR: One or more attached shaders not successfully compiled

Error in filter parameter band_size: no valid opengl ID.
OpenGL error 1282 at render_triangles in: invalid operation

andres

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

3 years ago

Strange, it seems that you opengl driver comes with an old glsl compiler which doesn't support the mod function. Replace the code in data/BandedBlend.glsl with this one:

uniform sampler2D src_tex_unit0;
uniform sampler2D src_tex_unit1;
uniform int band_size;
uniform vec2 dest_tex_size;
void main(void) {
    vec2 tex_coords = gl_TexCoord[0].st;

    int n = int(tex_coords.t * dest_tex_size.y);
    int r = n / band_size;
    int q = r / 2;
    float f = r / 2.0;
    float diff = f - q;

    if (abs(diff) < 0.01) {
        gl_FragColor = texture2D(src_tex_unit0, tex_coords.st).rgba;
    } else {
        gl_FragColor = texture2D(src_tex_unit1, tex_coords.st).rgba;
    }
}

zumbaree

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

3 years ago

Unfortunately, this hasn't helped much, the errors get even weirder

Fragment shader BandedBlend.glsl compilation:
ERROR: 0:11: '/' : wrong operand types no operation '/' exists that takes a left-hand operand of type 'int' and a right operand of type 'const float' (or there is no acceptable conversion)
ERROR: 0:11: '=' : cannot convert from 'int' to 'float'
ERROR: 0:12: '-' : wrong operand types no operation '-' exists that takes a left-hand operand of type 'float' and a right operand of type 'int' (or there is no acceptable conversion)

andres

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

3 years ago

What graphics card are you using? on what OS?

zumbaree

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

3 years ago

I had that information in my post but somehow it disappeared, sorry

I'm on mac pro with ATI RadeonX1900, on Leo 10.5.8
I'll try on my mbp when I get home

zumbaree

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

3 years ago

tested on mbp with GeForce 8600M GT on 10.6.4 and it's the same on both glsl codes

andres

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

3 years ago

I tested this shader on an integrated Intel X3100, so I'm surprised to see it doesn't work on nvidia. I'll test a macbook tonight.

andres

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

3 years ago

Ok, I reproduced your errors on a macbook pro with a geforce 320M. And the following glsl shader works as expected on that machine:

uniform sampler2D src_tex_unit0;
uniform sampler2D src_tex_unit1;
uniform int band_size;
uniform vec2 dest_tex_size;
void main(void) {
    vec2 tex_coords = gl_TexCoord[0].st;

    int n = int(tex_coords.t * dest_tex_size.y);
    int r = n / band_size;
    int q1 = int(r / 2);
    float q2 = float(r) / 2.0;
    float d = float(q1) - q2;
    if (d == 0.0) {
        gl_FragColor = texture2D(src_tex_unit0, tex_coords.st).rgba;
    } else {
        gl_FragColor = texture2D(src_tex_unit1, tex_coords.st).rgba;
    }
}

zumbaree

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

3 years ago

Brilliant, works like a charm!
Thanks a lot, love you ; )

As I know I will only ever need to use band size of 1, I've stripped out your band_size parameter

uniform sampler2D src_tex_unit0;
uniform sampler2D src_tex_unit1;
uniform vec2 dest_tex_size;
void main(void) {
    vec2 tex_coords = gl_TexCoord[0].st;
    int n = int(tex_coords.t * dest_tex_size.y);
    int q1 = int(n / 2);
    float q2 = float(n) / 2.0;
    float d = float(q1) - q2;
    if (d == 0.0) {
        gl_FragColor = texture2D(src_tex_unit0, tex_coords.st).rgba;
    } else {
        gl_FragColor = texture2D(src_tex_unit1, tex_coords.st).rgba;
    }
}

My guess is that it will improve performance but not significantly.

Anyway, thanks again for your time, and for writing a great library too!

zumbaree

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

2 years ago

Hi again
Thanks again for your help on this Andres.
I now found that there will only be an anaglyph setup for stereo display for my first performance with the sketch, so I'm trying to adopt some glsl shaders to mix rgb channels

ideally I'd want something like
Output[R] =(Left[R]x456 + Left[G]x500 + Left[B]x176 + Right[R]x-43 + Right[G]x[-88] + Right[B]x[-2] ) / 1000
Output[G] =(Left[R]x[-40] + Left[G]x[-38] + Left[B]x[-16] + Right[R]x378 + Right[G]x734 + Right[B]x[-18]) / 1000
Output[B] =(Left[R]x[-15] + Left[G]x[-21] + Left[B]x[-5] + Right[R]x[-72] + Right[G]x[-113] + Right[B]x1226) / 1000

but I would be happy to even have
out.r = left.r;
out.b = right.b;

I have found some shader codes as examples:

uniform sampler2D left, right;

void main()
{

    vec3 col, coeff = vec3(0.15, 0.15, 0.7);
    col.r = left.r;
    col.g = left.g;
    col.b = dot(right, coeff);

    gl_FragColor = vec4(col, 1.0);
}

throws errors while compiling
or this one

sampler2D input1 : register(S0); // right image input
sampler2D input2 : register(S1); // left image input

float4 main(float2 uv : TEXCOORD) : COLOR
{
    float4 Color1;
    Color1 = tex2D( input1 , uv.xy);

    float4 Color2;
    Color2 = tex2D( input2 , uv.xy);

    Color1.r = Color2.r;
    Color1.g = Color1.g;
    Color1.b = Color1.b;
    Color1.a = max(Color1.a,Color2.a);

        return Color1;
}

throws errors when compiling

The best I got to so far (at least it compiles) is

uniform sampler2D tex_left, tex_right;

void main()
{
    vec3 left = texture2D(tex_left, gl_TexCoord[0].st).rgb;
    vec3 right = texture2D(tex_right, gl_TexCoord[0].st).rgb;
    vec3 col;
    col[0] = left[0];
    col[1] = left[1];
    col[2] = right[2];

    gl_FragColor = vec4(col, 1.0);
}

but it doesn't work either (only outputs one texture). Any help appreciated. Thank you

andres

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

2 years ago

A simple GLTextureFilter that does the texture mixing you mention could be:

<filter name="Channel mixer">
<description>Custom mix between two textures</description>
<fragment>BandedBlend.glsl</fragment>
<textures input="2" output="1"></textures>
</filter>

(the filter's xml), and the shader itself:

uniform sampler2D src_tex_unit0;
uniform sampler2D src_tex_unit1;
void main(void) {
vec2 tex_coords = gl_TexCoord[0].st;
vec3 color0 = texture2D(src_tex_unit0, tex_coords.st).rgb;
vec3 color1 = texture2D(src_tex_unit0, tex_coords.st).rgb;
gl_FragColor = vec4((color0.r * 456.0 + color0.g * 500.0 + color0.b * 176.0 - color1.r * 43.0 - color1.g * 88.0 - color1.b * 2.0) / 1000.0,
(-color0.r * 40.0 - color0.g * 38.0 - color0.b * 16.0 + color1.r * 378.0 + color1.g * 734.0 - color1.b * 18.0) / 1000.0,
(-color0.r * 15.0 - color0.g * 21.0 - color0.b * 5.0 - color1.r * 72.0 - color1.g * 113.0 + color1.b * 1226.0) / 1000.0,
1);
}

zumbaree

Re: GLGraphicsOffScreen and seperate alpha for stereoscopic 3D (GlGraphics)

2 years ago

Thanks very much Andres

At first I couldn't get it to work but then I realised its just src_tex_unit0 used twice in your code rather than src_tex_unit1 so following code does work (for anaglyph.glsl)

uniform sampler2D src_tex_unit0;
uniform sampler2D src_tex_unit1;
void main(void) {
vec2 tex_coords = gl_TexCoord[0].st;
vec3 color0 = texture2D(src_tex_unit0, tex_coords.st).rgb;
vec3 color1 = texture2D(src_tex_unit1, tex_coords.st).rgb;
gl_FragColor = vec4((color0.r * 456.0 + color0.g * 500.0 + color0.b * 176.0 - color1.r * 43.0 - color1.g * 88.0 - color1.b * 2.0) / 1000.0,
(-color0.r * 40.0 - color0.g * 38.0 - color0.b * 16.0 + color1.r * 378.0 + color1.g * 734.0 - color1.b * 18.0) / 1000.0,
(-color0.r * 15.0 - color0.g * 21.0 - color0.b * 5.0 - color1.r * 72.0 - color1.g * 113.0 + color1.b * 1226.0) / 1000.0,
1);
}

Thank you so much, you saved my day again ;)

Top Reply