GLGraphics extention warnings

andres

Re: GLGraphics extention warnings

2 years ago

These warnings mean that you cannot use geometry shaders, and antialiased offscreen surfaces are not available. VBOs and lights should work ok, though.

ventai

Re: GLGraphics extention warnings

2 years ago

Right ok, thanks - will have to learn a bit more about those extensions.

I seem to have the lights doing something (when run outside of the beginGL()/endGL() of the GLModel render).

Do you have any advise on settings? At the moment they don't really seem to be doing anything, apart from illuminating from all angles,and not showing any of the surfaces of the 3D object.

I've played around with lightFalloff but nothing really seems to make a difference. Current settings: -

lights();
lightFalloff(1,1,0);
lightSpecular(255, 255, 255);

Cheers

______________________
www.systemarray.com

andres

Re: GLGraphics extention warnings

2 years ago

If you need to lit a GLModel object, then the lights should be called inside the beginGL()/endGL() block. See how this is done in the models/GLLights example that comes with the library.

The reason for this is that when the lighting functions are called outside beginGL()/endGL(), then they use the software implementation (i.e.: non-OpenGL lights).

I know this sounds quite convoluted, but due to architectural limitations of the OPENGL renderer on which GLGraphics is based, there is really no easy way to fully integrate OpenGL with the rest of the Processing API.

These issues are being taken of care with the new OPENGL2 renderer, though.

ventai

Re: GLGraphics extention warnings

2 years ago

I'm very much looking forward to playing with the new renderer. I can see lots of possibilities coming up :)

My light situation is a little odd. The only one that I can get to look any good (so that it shows the actual edges and surfaces) is the spotlight. I used the same technique as in the GLLights example.
It's just that when you hold the mouse in one position, and the cube looks well illuminated, as it rotates, it's almost as though the light rotates with it! Is that possible? (push and popMatrix didn't seem to make a difference)

I've been trying to decipher what's going on and can't get to the bottom of it.

Thanks for all the heads up on all this.

I've posted the code below if you're interested:-

import processing.opengl.*;
import codeanticode.glgraphics.*;

GLModel cube;
int numvertex= 24;
float rotx = PI/4;
float roty = PI/4;
float lightX, lightY, lightZ;

void setup()
{
size(640, 480, GLConstants.GLGRAPHICS);
background(255);
frameRate( 55 );
cube = new GLModel(this, numvertex, QUADS, GLModel.STREAM);

cube.initColors();

cube.beginUpdateVertices();
// Front face
cube.setLineWidth(108);
cube.updateVertex(0, -100, -100, +100);
cube.updateVertex(1, +100, -100, +100);
cube.updateVertex(2, +100, +100, +100);
cube.updateVertex(3, -100, +100, +100);
// Back face
cube.updateVertex(4, -100, -100, -100);
cube.updateVertex(5, +100, -100, -100);
cube.updateVertex(6, +100, +100, -100);
cube.updateVertex(7, -100, +100, -100);
// Rigth face
cube.updateVertex(8, +100, -100, +100);
cube.updateVertex(9, +100, -100, -100);
cube.updateVertex(10, +100, +100, -100);
cube.updateVertex(11, +100, +100, +100);
// Left face
cube.updateVertex(12, -100, -100, +100);
cube.updateVertex(13, -100, -100, -100);
cube.updateVertex(14, -100, +100, -100);
cube.updateVertex(15, -100, +100, +100);
// Top face
cube.updateVertex(16, +100, +100, +100);
cube.updateVertex(17, +100, +100, -100);
cube.updateVertex(18, -100, +100, -100);
cube.updateVertex(19, -100, +100, +100);
// Bottom face
cube.updateVertex(20, +100, -100, +100);
cube.updateVertex(21, +100, -100, -100);
cube.updateVertex(22, -100, -100, -100);
cube.updateVertex(23, -100, -100, +100);

cube.endUpdateVertices();

cube.beginUpdateColors();
for (int i = 0; i < numvertex; i++) {
    cube.updateColor(i, 211,203,203, 300);
}
cube.endUpdateColors();
cube.setTint(255);
}

void draw()
{
lightX = mouseX;
lightY = mouseY;
lightZ = -10.5;
background(255);

GLGraphics renderer = (GLGraphics)g;

renderer.beginGL();

float dirX = width/2 - lightX;
float dirY = height/2 - lightY;
float dirZ = 0 - lightZ;
float n = sqrt(dirX * dirX + dirY * dirY + dirZ * dirZ);
dirX /= n;
dirY /= n;
dirZ /= n;

pushMatrix();
spotLight(255, 255, 255, lightX, lightY, lightZ, dirX, dirY, dirZ, PI/2, 0.1);
popMatrix();
translate(width/2,height/2, -250);
rotateX(rotx);
rotateY(roty);
renderer.model(cube);

renderer.endGL();

roty+=0.0058;
rotx+=0.0059;
}

______________________
www.systemarray.com

ventai

Re: GLGraphics extention warnings

2 years ago

In order to try and solve the lighting issue; I've created a plane in the background to see where the light's shining.

Looking at the plane, with the mouse held in one position (after getting illumination on the cube), you can see that the light does not appear to be moving, but when you watch the cube when it's lit (for more than a few seconds), the light seems to move, but only on the cube.

Can someone please have a look as it's driving me a bit crazy :)

import processing.opengl.*;
import codeanticode.glgraphics.*;

GLModel cube;
GLModel plane;
int numvertex= 24;
float rotx = PI/4;
float roty = PI/4;
float lightX, lightY, lightZ;

void setup()
{
size(640, 480, GLConstants.GLGRAPHICS);
translate(width/2,height/2, -250);
background(255);
frameRate( 55 );
cube = new GLModel(this, numvertex, QUADS, GLModel.STREAM);
plane = new GLModel(this, 4, QUADS, GLModel.STREAM);

cube.initColors();

cube.beginUpdateVertices();
// Front face
// cube.setLineWidth(108);
cube.updateVertex(0, -100, -100, +100);
cube.updateVertex(1, +100, -100, +100);
cube.updateVertex(2, +100, +100, +100);
cube.updateVertex(3, -100, +100, +100);
// Back face
cube.updateVertex(4, -100, -100, -100);
cube.updateVertex(5, +100, -100, -100);
cube.updateVertex(6, +100, +100, -100);
cube.updateVertex(7, -100, +100, -100);
// Rigth face
cube.updateVertex(8, +100, -100, +100);
cube.updateVertex(9, +100, -100, -100);
cube.updateVertex(10, +100, +100, -100);
cube.updateVertex(11, +100, +100, +100);
// Left face
cube.updateVertex(12, -100, -100, +100);
cube.updateVertex(13, -100, -100, -100);
cube.updateVertex(14, -100, +100, -100);
cube.updateVertex(15, -100, +100, +100);
// Top face
cube.updateVertex(16, +100, +100, +100);
cube.updateVertex(17, +100, +100, -100);
cube.updateVertex(18, -100, +100, -100);
cube.updateVertex(19, -100, +100, +100);
// Bottom face
cube.updateVertex(20, +100, -100, +100);
cube.updateVertex(21, +100, -100, -100);
cube.updateVertex(22, -100, -100, -100);
cube.updateVertex(23, -100, -100, +100);

cube.endUpdateVertices();

cube.beginUpdateColors();
for (int i = 0; i < numvertex; i++) {
    cube.updateColor(i, 211,203,203, 300);
}
cube.endUpdateColors();
cube.setTint(255);

plane.initColors();

plane.beginUpdateVertices();
// Front face
// plane.setLineWidth(108);
plane.updateVertex(0, -800, -800, +800);
plane.updateVertex(1, +800, -800, +800);
plane.updateVertex(2, +800, +800, +800);
plane.updateVertex(3, -800, +800, +800);
plane.endUpdateVertices();

plane.beginUpdateColors();
for (int i = 0; i < 4; i++) {
    plane.updateColor(i, 211,203,203, 300);
}
plane.endUpdateColors();
plane.setTint(255);
}

void draw()
{
lightX = mouseX;
lightY = mouseY;
lightZ = -10.5;
background(255);

GLGraphics renderer = (GLGraphics)g;

renderer.beginGL();

pushMatrix();
translate(width/2,height/2, 0.1);
float dirX = width/2 - lightX;
float dirY = height/2 - lightY;
float dirZ = 0 - lightZ;
float n = sqrt(dirX * dirX + dirY * dirY + dirZ * dirZ);
dirX /= n;
dirY /= n;
dirZ /= n;
spotLight(255, 255, 255, lightX, lightY, lightZ, dirX, dirY, dirZ, PI/2, 0.1);
popMatrix();

pushMatrix();
translate(width/2,height/2, -1800);
renderer.model(plane);
popMatrix();

pushMatrix();
translate(width/2,height/2, -500);
rotateX(rotx);
rotateY(roty);
renderer.model(cube);
popMatrix();

renderer.endGL();

roty+=0.0058;
rotx+=0.0059;
}

______________________
www.systemarray.com

andres

Re: GLGraphics extention warnings

2 years ago

Hi, you forgot to specify the model's normals, which are needed by OpenGL to compute the lighting. GLGraphics doesn't compute normals automatically, so you need to set them explicitly, see the code below:

import processing.opengl.*;
import codeanticode.glgraphics.*;
GLModel cube;
GLModel plane;
int numvertex= 24;
float rotx = PI/4;
float roty = PI/4;
float lightX, lightY, lightZ;
void setup()
{
size(640, 480, GLConstants.GLGRAPHICS);
translate(width/2,height/2, -250);
background(255);
frameRate( 55 );
cube = new GLModel(this, numvertex, QUADS, GLModel.STREAM);
plane = new GLModel(this, 4, QUADS, GLModel.STREAM);
cube.initColors();
cube.initNormals();
cube.beginUpdateVertices();
// Front face
// cube.setLineWidth(108);
cube.updateVertex(0, -100, -100, +100);
cube.updateVertex(1, +100, -100, +100);
cube.updateVertex(2, +100, +100, +100);
cube.updateVertex(3, -100, +100, +100);
// Back face
cube.updateVertex(4, -100, -100, -100);
cube.updateVertex(5, +100, -100, -100);
cube.updateVertex(6, +100, +100, -100);
cube.updateVertex(7, -100, +100, -100);
// Rigth face
cube.updateVertex(8, +100, -100, +100);
cube.updateVertex(9, +100, -100, -100);
cube.updateVertex(10, +100, +100, -100);
cube.updateVertex(11, +100, +100, +100);
// Left face
cube.updateVertex(12, -100, -100, +100);
cube.updateVertex(13, -100, -100, -100);
cube.updateVertex(14, -100, +100, -100);
cube.updateVertex(15, -100, +100, +100);
// Top face
cube.updateVertex(16, +100, +100, +100);
cube.updateVertex(17, +100, +100, -100);
cube.updateVertex(18, -100, +100, -100);
cube.updateVertex(19, -100, +100, +100);
// Bottom face
cube.updateVertex(20, +100, -100, +100);
cube.updateVertex(21, +100, -100, -100);
cube.updateVertex(22, -100, -100, -100);
cube.updateVertex(23, -100, -100, +100);
cube.endUpdateVertices();
cube.beginUpdateNormals();
// Front face
cube.updateNormal(0, 0, 0, +1);
cube.updateNormal(1, 0, 0, +1);
cube.updateNormal(2, 0, 0, +1);
cube.updateNormal(3, 0, 0, +1);
// Back face
cube.updateNormal(4, 0, 0, -1);
cube.updateNormal(5, 0, 0, -1);
cube.updateNormal(6, 0, 0, -1);
cube.updateNormal(7, 0, 0, -1);
// Rigth face
cube.updateNormal(8, +1, 0, 0);
cube.updateNormal(9, +1, 0, 0);
cube.updateNormal(10, +1, 0, 0);
cube.updateNormal(11, +1, 0, 0);
// Left face
cube.updateNormal(12, -1, 0, 0);
cube.updateNormal(13, -1, 0, 0);
cube.updateNormal(14, -1, 0, 0);
cube.updateNormal(15, -1, 0, 0);
// Top face
cube.updateNormal(16, 0, +1, 0);
cube.updateNormal(17, 0, +1, 0);
cube.updateNormal(18, 0, +1, 0);
cube.updateNormal(19, 0, +1, 0);
// Bottom face
cube.updateNormal(20, 0, -1, 0);
cube.updateNormal(21, 0, -1, 0);
cube.updateNormal(22, 0, -1, 0);
cube.updateNormal(23, 0, -1, 0);
cube.endUpdateNormals();
cube.beginUpdateColors();
for (int i = 0; i < numvertex; i++) {
cube.updateColor(i, 211,203,203, 300);
}
cube.endUpdateColors();
cube.setTint(255);
plane.initColors();
plane.beginUpdateVertices();
// Front face
// plane.setLineWidth(108);
plane.updateVertex(0, -800, -800, +800);
plane.updateVertex(1, +800, -800, +800);
plane.updateVertex(2, +800, +800, +800);
plane.updateVertex(3, -800, +800, +800);
plane.endUpdateVertices();
plane.beginUpdateColors();
for (int i = 0; i < 4; i++) {
plane.updateColor(i, 211,203,203, 300);
}
plane.endUpdateColors();
plane.setTint(255);
}
void draw()
{
lightX = mouseX;
lightY = mouseY;
lightZ = -10.5;
background(255);
GLGraphics renderer = (GLGraphics)g;
renderer.beginGL();
pushMatrix();
translate(width/2,height/2, 0.1);
float dirX = width/2 - lightX;
float dirY = height/2 - lightY;
float dirZ = 0 - lightZ;
float n = sqrt(dirX * dirX + dirY * dirY + dirZ * dirZ);
dirX /= n;
dirY /= n;
dirZ /= n;
spotLight(255, 255, 255, lightX, lightY, lightZ, dirX, dirY, dirZ, PI/2, 0.1);
popMatrix();
pushMatrix();
translate(width/2,height/2, -1800);
renderer.model(plane);
popMatrix();
pushMatrix();
translate(width/2,height/2, -500);
rotateX(rotx);
rotateY(roty);
renderer.model(cube);
popMatrix();
renderer.endGL();
roty+=0.0058;
rotx+=0.0059;
}

ventai

Re: GLGraphics extention warnings

2 years ago

That seems to have done the trick! Thanks very much andres :) Will investigate into normals a little more. .

One final quick point: do you know of any way to ray trace using GLGraphics?
I've tried the Joons Renderer ( http://code.google.com/p/joons-renderer/), but there seems to be an issue when it tries to render out.
If nothing at the moment; will the OPENGL2 renderer have some way to do this?

Thanks again, you've been a great help

______________________
www.systemarray.com

andres

Re: GLGraphics extention warnings

2 years ago

Hi, the getting started example from Joons works fine with GLGraphics, so I guess the problems happens when you try to use advanced functionality such as GLModels.

I guess the reason is that the drawing of GLModel objects doesn't take place through the standard Processing API, so the Joons library cannot pick it up.

This should be solved with OPENGL2, where all the functionality is properly integrated into the core.

ventai

Re: GLGraphics extention warnings

2 years ago

Right, as it used the P5 renderer in setup; it seemed like a good contender for compatibility.

That's great news about the upcoming release; as I see ray tracing as the final pass in polishing many pieces, and will be an excellent addition to the functionality.

All the best. .

Cheers

______________________
www.systemarray.com

ventai

Re: GLGraphics extention warnings

2 years ago

(just a quick update)

Using the 'Getting Started' Joons ray trace example, http://code.google.com/p/joons-renderer/wiki/GettingStarted - I tried running this with the standard P5 OPENGL renderer, and it failed in the same way as using a GLModel.

So it appears that there could be issues with new the OPENGL2 renderer in this respect, if its compatibility is to be based upon the original core library. .

______________________
www.systemarray.com

ventai

Re: GLGraphics extention warnings

2 years ago

Hi andres,

Another update :); not sure if you've seen the thread over at http://forum.processing.org/topic/coding-opengl-sunflow#25080000000713322 - where we've been discussing a working implementation with OpenGL, Toxiclibs, and Sunflow.

______________________
www.systemarray.com