GLGraphics and strange problems with matrix transformations

rafe.cope..

GLGraphics and strange problems with matrix transformations

in Contributed Library Questions • 1 year ago

Hi,

I'm sure there's a simple solution to this, but I have a series of shapes involving a bunch of matrix transformations (translate, rotateX, rotateY and rotateZ, pushMatrix and popMatrix) which draw fine outside of the beginGL() / endGL() block, and I then draw a GLModel on top of that which is inside beginGL() / endGL(). But if I put beginGL() / endGL() around everything in the draw function then suddenly everything goes c-rrazy.... though you'll notice the red dots (the GLModel) are in the same spot

I tried changing everything to renderer.translate(), renderer.rotateX(), renderer.pushMatrix() etc, but no help.

Here are two screenshots.

Any ideas?

Replies(4)

andres

Re: GLGraphics and strange problems with matrix transformations

1 year ago

Hello, it is difficult to say without looking at the code.

If you apply a different set of transformations for the GLModel and for the rest of the geometry you draw with regular Processing functions, then you should isolate the transformations before beginGL and endGL using pushMatrix()/popMatrix(), otherwise those will affect the GLModel too:

import processing.opengl.*;
import codeanticode.glgraphics.*;
GLModel obj;
void setup() {
size(400, 400, GLConstants.GLGRAPHICS);
obj = new GLModel(this, 4, QUADS, GLModel.STATIC);
obj.beginUpdateVertices();
obj.updateVertex(0, -100, -100, 0);
obj.updateVertex(1, 100, -100, 0);
obj.updateVertex(2, 100, 100, 0);
obj.updateVertex(3, -100, 100, 0);
obj.endUpdateVertices();
obj.initColors();
obj.beginUpdateColors();
obj.updateColor(0, 255, 0, 0);
obj.updateColor(1, 0, 255, 0);
obj.updateColor(2, 0, 0, 255);
obj.updateColor(3, 255, 255, 0);
obj.endUpdateColors();
}
void draw() {
background(0);
pushMatrix();
translate(width/2, height/2);
rotateY(frameCount * 0.01);
fill(255);
beginShape(QUADS);
vertex(-100, -100, 1);
vertex(-80, -100, 1);
vertex(-80, -80, 1);
vertex(-100, -80, 1);
vertex(80, 80, -1);
vertex(100, 80, -1);
vertex(100, 100, -1);
vertex(80, 100, -1);
endShape();
popMatrix();
GLGraphics renderer = (GLGraphics)g;
renderer.beginGL();
translate(width/2, height/2, 0);
rotateY(frameCount * 0.01);
renderer.model(obj);
renderer.endGL();
}

rafe.cope..

Re: GLGraphics and strange problems with matrix transformations

1 year ago

Hi Andres,

Thanks, I'll try that.

But to clarify, when I draw something using ellipse(), for example, inside the beginGL / endGL, is it being rendered with GLGraphics? Basically I'm just wondering why I couldn't in your example above, do:

void draw() {
GLGraphics renderer = (GLGraphics)g;
renderer.beginGL();
background(0);
translate(width/2,height/2);
rotateY(frameCount * 0.01);
fill(255);
beginShape(QUADS);
vertex(-100, -100, 1);
vertex(-80, -100, 1);
vertex(-80, -80, 1);
vertex(-100, -80, 1);
vertex(80, 80, -1);
vertex(100, 80, -1);
vertex(100, 100, -1);
vertex(80, 100, -1);
endShape();
renderer.model(obj);
renderer.endGL();
}

Do all non-GLGraphics functions have to be outside of the beginGL / endGL block?

Also, the code I am using can be found here

Thanks!

andres

Re: GLGraphics and strange problems with matrix transformations

1 year ago

Everything is drawn by the GLGraphics renderer, but it does it differently whether you are putting the calls inside or outside the beginGL/endGL block (basically, the geometric transformations are stored in the gl modelview matrix when inside beginGL/endGL, while the gl modelview is set to identity in normal Processing operation because all the transformations are applied to the vertices on the CPU side).

So, this means that all non-GLGraphics functions have to be outside of the beginGL/endGL block. If you try your modified draw() method, you will see that the white rectangle drawn with beginShape/endShape is misplaced.

rafe.cope..

Re: GLGraphics and strange problems with matrix transformations

1 year ago

Thanks Andres, that explains it all! Problem solved

Top Reply