import org.gicentre.utils.multisketch.*;
import java.awt.GridLayout; 

// The master sketch controlling all others.

EmbeddedSketch[] sketches;  // Array of sketches to be shown.

void setup()
{
  size(400,400);
  setLayout(new GridLayout(1,1));    // Space for one sketch at a time.
  frameRate(1);  // Can set a slow frame rate for master 
                 // since it only changes sketches occasionally.
  
  sketches = new EmbeddedSketch[3];    // Number of sketches in slideshow.
  sketches[0] = new ASketch();
  sketches[1] = new AnotherSketch();
  sketches[2] = new YetAnotherSketch();
  
  // Start with the first sketch and add it to the master sketch.
  sketches[0].setIsActive(true);
  add(new SketchPanel(this,sketches[0]));
}

void draw()
{
  // Change sketches randomly but around every 10 seconds.  
  if (random(10) < 1)
  {    
    // Ensure non-visible sketches are 'resting'
    for (EmbeddedSketch sketch : sketches)
    {
      sketch.setIsActive(false);
    }
    
    // Replace old sketch with new randomly selected one and activate it.
    int randSketchNum = int(random(sketches.length));    
    sketches[randSketchNum].setIsActive(true);
    removeAll();
    add(new SketchPanel(this,sketches[randSketchNum]));
    validate();
  }
}

// This is one of the sketches to be shown in the slideshow
class ASketch extends EmbeddedSketch
{
  void setup()
  {
    size(400,400);
  }
  
  void draw()
  {
    super.draw();
    background(255,200,200);
    textAlign(CENTER,CENTER);
    fill(50);
    text("A sketch", width/2,height/2);
  } 
}

// This is another one of the sketches to be shown in the slideshow
class AnotherSketch extends EmbeddedSketch
{
  void setup()
  {
    size(400,400);
  }
  
  void draw()
  {
    super.draw();
    background(200,255,200);
    textAlign(CENTER,CENTER);
    fill(50);
    text("Another sketch", width/2,height/2);
  } 
}

// And another of the sketches to be shown in the slideshow
class YetAnotherSketch extends EmbeddedSketch
{
  void setup()
  {
    size(400,400);
  }
  
  void draw()
  {
    super.draw();
    background(200,200,255);
    textAlign(CENTER,CENTER);
    fill(50);
    text("Yet another sketch", width/2,height/2);
  } 
}