Getting started with GLGraphics. - Processing Forum

Loading...

Processing Forum

Contributed Library Questions

jimthree

jimthree

Getting started with GLGraphics.

in Contributed Library Questions • 2 years ago

Hi.

I've got a processing app which loads in XYZ coordinates from a text file and renders them as points (or cubes, or spheres with minimal detail) in a 3D scene that can be navigated with peasycam.

Once I get over a few tens of thousand points, the framerate drops quickly and navigation becomes unusable.

I expected this, but now want to start utilising the GPU to open the door to much more performance. Some of the datasets I have contain millions of points, and it would be great to be able to render these in realtime (I have some fairly good hardware for this, 2x nVvidia GFX470's running in SLI mode)

I like the look of the GLGraphics lib, I've installed it and the examples all run fine. The problem is that I don't know where to start with integrating it. Ideally, I'd start with an app that rendered points (or minimal detail primitives) at random locations within a volume. I'd then add in PeasyCam (if that works with GLGraphics) and see how many points I can render before my GPUs melt.

Looking at the SimpleGPUParticleSytem example it seems that the particles are being rendered to a texture? is that right? I don't really understand the terminology being used here. Is the texture in this case just a screen buffer? This example doesn't really render geometry does it, it's moving sprites around. How do you render a simple primitive or a point?

I guess what I'm really looking for is the simplest possible implementation of a cube on the screen rendered on the GPU via GLGraphics. I can then build what I need on top of that.

Thanks for the help

Jim

1

Replies(36)

jimthree

jimthree

Re: Getting started with GLGraphics.

2 years ago

Perhaps this is getting a bit off topic, but I thought I'd post my progress so far. I was scared to try to start with, but starting small builds confidence to try new things.

Rather than diving straight in with the GLGraphics Lib, it seemed best to try and learn more about OpenGL and taming it inside Processing. I started here: http://wiki.processing.org/w/Advanced_OpenGL and managed to get a sphere on the screen fairly quickly. Next, I ported my 'grid' drawing routine over, which again wasn't too tricky.

I then found the GL_POINTS primitive and was able to get points plotted in the space. During this process I learnt that a lot of the slow down I was seeing in the original (non-pure/standard openGL) version of the sketch was due to the way I adding colour, using three map() calls to scale the colour values before drawing each point was a very daft thing to do.

I removed all the colour and stuck with grey for now. I was surprised (although I'm not sure why I should be) that PeasyCam went in straight away, nothing difficult there either.

I now have what I asked for in my original post. A sketch that renders a volume of random points using the GPU, with simple mouse based navigation.

The results are good. I can render 15 million points, but it does take the framerate down below 5fps. I can render 200,000 at 60fps.

My next step is to look at Vertex lists and try and work those out.

I am left with a couple of questions i'm trying to work out.

1) how do I efficiently colour all the points differently?

2) my sketch seems to be locked to 60fps, even rendering nothing other than the grid It won't get higher than 60, rendering the grid and 200,000 points still gives me 60fps. with more points it drops to 30fps and remains there, adding a million points slows it down below 12fps, (on the nVidia 8800GT I'm running this on atm). there seems to be a ceiling of 60fps and a plateau at 30fps (eg, I've never seen 45fps).

In case anyone wants a look, (and I'd welcome any comments on optimisation) here is my code.

import processing.opengl.*;
import javax.media.opengl.*;
import javax.media.opengl.glu.*;
import peasy.*;
PeasyCam cam;
GL gl;
GLU glu;
//Declare the Arrays for storing co-ords.
float[] coords_x = new float[1];
float[] coords_y = new float[1];
float[] coords_z = new float[1];
int data_rows = 1;
int max_points = 200000;
int rand = 1000;
void setup()
{
// Not quite fullScreen
size(screen.width-40, screen.height-100, OPENGL);
//SetUp PeasyCam
cam = new PeasyCam(this, 1000);
cam.setWheelScale(10);
cam.setResetOnDoubleClick(false);
cam.lookAt(width/2, height/2, (rand/2));
float fov = PI/3.0;
float cameraZ = (height/2.0) / tan(fov/2.0);
perspective(fov, float(width)/float(height),cameraZ/200.0, cameraZ*1000.0);
//SetUp the GL thingys
gl=((PGraphicsOpenGL)g).gl;
glu=((PGraphicsOpenGL)g).glu;
//Load the point data into the arrays
load_data();
}
void draw ()
{
//note the framerate
frame.setTitle(str(round(frameRate))+"fps");
//set BG colour and wipe new frame
background(0);
//More GL stuff I don't really understand yet.
PGraphicsOpenGL pgl = (PGraphicsOpenGL) g;
//All GL drawing commands are wrapped in a beginGL()/endGL() loop
GL gl = pgl.beginGL();
//Move everything we draw into the middle of the screen (or could just move the camera)
gl.glTranslatef(width/2, height/2, 0);
//Draw a grid
drawgrid(10,101,0.1);
//Draw the points
draw_points();
pgl.endGL();
}
void drawgrid(float spacing, int gridsize, float gridStroke)
{
for (int i = 0; i < gridsize; i++)
{
gl.glLineWidth(1);
//change the apparent size of the lines (via alpha) for Min and Max grid highlights
gl.glColor4f(1, 1, 1, gridStroke);
if (i%5 == 0) gl.glColor4f(1, 1, 1, gridStroke+0.05);
if (i == 0) gl.glColor4f(1, 1, 1, gridStroke+0.1);
//draw the lines using a GL Line primitive.
gl.glBegin(gl.GL_LINES);
gl.glVertex3f(-(gridsize*(spacing/2)), (i*spacing)-((gridsize/2)*spacing), 0);
gl.glVertex3f((gridsize*(spacing/2)), (i*spacing)-((gridsize/2)*spacing), 0);
gl.glEnd();
gl.glBegin(gl.GL_LINES);
gl.glVertex3f((i*spacing)-((gridsize/2)*spacing),-(gridsize*(spacing/2)), 0);
gl.glVertex3f((i*spacing)-((gridsize/2)*spacing),(gridsize*(spacing/2)), 0);
gl.glEnd();
}
}
void load_data()
{
// originaly this function loaded data from a database or file, where the number of
// rows was unknown. It would have been easier to do this with an array list, but
// also it would have been a bit slower for some uses.
//expand arrays to fit.
coords_x = expand (coords_x,max_points);
coords_y = expand (coords_y,max_points);
coords_z = expand (coords_z,max_points);
// fill the arrays with random points.
for (int i=0; i < max_points; i++)
{
coords_x[i] = random(rand);
coords_y[i] = random(rand);
coords_z[i] = random(rand);
}
}
void draw_points()
{
// set the size of the points to draw
gl.glPointSize(1);
//BeginGL to draw points
gl.glBegin(gl.GL_POINTS);
for (int i=0; i<max_points; i++)
{
// Not using this colour function anymore as the map() function is was _WAY_ too slow.
// gl.glColor4f(map(coords_x[i],0,max(coords_x),0,1),map(coords_y[i],0,max(coords_y),0,1),map(coords_z[i],0,max(coords_z),0,1), 1);
gl.glVertex3f(coords_x[i]-(rand/2), coords_y[i]-(rand/2), coords_z[i]);
}
gl.glEnd();
}

andres

andres

Re: Getting started with GLGraphics.

2 years ago

Using glBegin/glEnd with large geometries as it is your case is really inefficient. You should switch to vertex arrays, or even better Vertex Buffer Objects (VBOs). There are several threads in this forum about this technique, like this one.

With GLGraphics, you can use the GLModel class, that internally encapsulates the VBO functionality. Take a look at the SwarmingPoints and SwarmingSprites examples that come with the library to get an idea of how to use GLModel.

guess

guess

Re: Getting started with GLGraphics.

2 years ago

I'm trying to do a similar thing with a large number of moving points using GLModel. I have a simple question. Can you instantiate more than one GLModel in a program? Thanks!

guess

guess

Re: Getting started with GLGraphics.

2 years ago

I just figured it out, you can indeed!

jimthree

jimthree

Re: Getting started with GLGraphics.

2 years ago

I'm having great fun with this, Thanks to the direction from Andres above, I've now got my sketch rendering a 10 million points dataset into a VBO using the GLModel class in GLGraphics. Even on my old nvidia 8800GT, I can get 30FPS with 10 million points. Awesome stuff.

While I've come really far, I still feel like I'm missing some basics. Within the context of GLGraphics, how do I draw basic primitives such as lines (or later i'll be needing cubes)?

it used to be:

gl.glBegin(gl.GL_LINES);
gl.glVertex3f(x,y,z);
gl.glVertex3f((x,y,z);
gl.glEnd();

But now I don't know, does it need to be a new model object?

cheers

Jim

andres

andres

Re: Getting started with GLGraphics.

2 years ago

You set the rendering mode (POINTS, LINES, QUADS, etc.) when you create the model:

model = new GLModel(this, numPoints, LINES, GLModel.DYNAMIC);

A single GLModel object can have only one rendering mode at the time. So if you need to create a 3D shape with outlines, you have to use two models, one with the quads defining the faces, and the second containing the lines.

jimthree

jimthree

Re: Getting started with GLGraphics.

2 years ago

Brilliant, Thanks Andres.

What is the most efficient way of rendering hundreds of thousands of cubes? Can that be done within the scope of a GLModel?

Jim

andres

andres

Re: Getting started with GLGraphics.

2 years ago

I would say that putting all the cubes inside a single GLModel (and the outlines in a second GLModel, if you need to). Take a look at the Bilboards example included with the library, where one GLModel object is used to store many rectangles.

guess

guess

Re: Getting started with GLGraphics.

2 years ago

Thanks for such a great library Andres!

I'm also trying to make a GLModel full of cubes as well. But I just can't get my mind around how to go from the Billboards example to six faces of a cube. I was trying to figure out a way to define each face in relation to one another based on this Ira Greenberg example ( http://processing.org/learning/3d/pushpopcubes.html). But he is just using vertices, whereas with GLModel placement is done with coordinates (if I understand it right). Is a good strategy to make the for loop

for (int n = 0; n < numSprites; n + 6) {

and then repeat each coords, objcorn, tcoords 6 times adding one in each succeeding [] and positioning the faces (with an additional a z value)? If this is the right track how can I get them to face in the right direction.

Any help would be greatly appreciated!

andres

andres

Re: Getting started with GLGraphics.

2 years ago

Hi, the following code generates a GLModel holding an axis-aligned cube of width = height = depth = 200 and centered at (0, 0, 0):

cube = new GLModel(this, 24, QUADS, GLModel.STATIC);
cube.beginUpdateVertices();
// Front face
cube.updateVertex(0, -100, -100, +100);
cube.updateVertex(1, +100, -100, +100);
cube.updateVertex(2, +100, +100, +100);
cube.updateVertex(3, -100, +100, +100);
// Back face
cube.updateVertex(4, -100, -100, -100);
cube.updateVertex(5, +100, -100, -100);
cube.updateVertex(6, +100, +100, -100);
cube.updateVertex(7, -100, +100, -100);
// Rigth face
cube.updateVertex(8, +100, -100, +100);
cube.updateVertex(9, +100, -100, -100);
cube.updateVertex(10, +100, +100, -100);
cube.updateVertex(11, +100, +100, +100);
// Left face
cube.updateVertex(12, -100, -100, +100);
cube.updateVertex(13, -100, -100, -100);
cube.updateVertex(14, -100, +100, -100);
cube.updateVertex(15, -100, +100, +100);
// Top face
cube.updateVertex(16, +100, +100, +100);
cube.updateVertex(17, +100, +100, -100);
cube.updateVertex(18, -100, +100, -100);
cube.updateVertex(19, -100, +100, +100);
// Bottom face
cube.updateVertex(20, +100, -100, +100);
cube.updateVertex(21, +100, -100, -100);
cube.updateVertex(22, -100, -100, -100);
cube.updateVertex(23, -100, -100, +100);
cube.endUpdateVertices();

You can add more vertices with shifted coordinates to store more cubes inside the same GLModel.

guess

guess

Re: Getting started with GLGraphics.

2 years ago

Thanks a lot Andres!!!

Is it possible to reduce the iterations per cube from 24 vertices to somehow just describing the 8 vertices, thus eliminating redundancy?

Using the shifted coordinates and a lot of cubes, there is a big performance hit.

And in general is it quicker to use the following syntax?

coords = new float[4 * 4 * numSprites];

coords[16 * n + 8 + 0] = x0;

etc..

model.updateVertices(coords);

than successive cube.updateVertex() calls ?

Thanks again!

Jeff

andres

andres

Re: Getting started with GLGraphics.

2 years ago

There are some ways to reduce the geometry redundancy but they are currently unsupported in the GLModel class.

However, even with 24 vertices per cube, I'm surprised you experience a performance hit. GLModel objects usually can can have thousands of points and render fine. How many are you setting in your model?

As for updating the coordinates using a float array, yes, it should be faster than updating each vertex separately with the updateVertex() method.

guess

guess

Re: Getting started with GLGraphics.

2 years ago

Thanks for your response Andres!

When I use

thisModel = new GLModel(p, total, POINTS, GLModel.STREAM);

I can make 500,000 moving (updateVertex) points at 30 fps

STREAM really seems to accelerate things.

When I use

thisModel = new GLModel(this, 24 * total, QUADS, GLModel.STREAM);

I can make 20,000 moving cubes (displaceVertex) at around 38 fps

which I think is roughly equivalent 20,000 x 24 vertices = 480,000 points

I'd really like to make more moving cubes leading me to try reducing the vertex redundancy.

Do you think there is any way to do this or have I reached a limit?

Thanks again, your library is so excellent!

andres

andres

Re: Getting started with GLGraphics.

2 years ago

Yes, there is a way of reducing redundancy, which consists in first specifying the vertices without duplicates, and then passing an array of vertex indices to opengl, which can contain duplicated references. The problem is that in order to make this work I need to do some modifications in the source code of GLModel. I think is worth it, but it will probably take a couple of weeks to have it done.

About the meaning of the usage modes in GLModel:

STATIC: the vertices won't change at all

DYNAMIC: the vertices will change frequently but not every frame

STREAM: the vertices will be modified at every frame.

guess

guess

Re: Getting started with GLGraphics.

2 years ago

Okay that would be excellent!
But certainly don't go out of your way, unless it's important for you too!

It's strange because of the three STATIC, DYNAMIC and STREAM, the later is by far the quickest and all the while constantly modifying position.

Thanks again.
Jeff

andres

andres

Re: Re: Getting started with GLGraphics.

2 years ago

There is a new release of GLGraphics that incorporates vertex indexing. See details here.

andres

andres

Re: Getting started with GLGraphics.

2 years ago

I'd say that STREAM mode being the quickest when constantly (i.e.: every frame) modifying the coords of the model should be the expected outcome. The GLModel is just a wrapper of Vertex Buffer Objects (VBOs) in OpenGL, you can read this online article for the more technical details.

guess

guess

Re: Getting started with GLGraphics.

2 years ago

GLGraphics 0.9.9.1 Excellent! Thanks a lot!
Jeff

guess

guess

Re: Getting started with GLGraphics.

2 years ago

Strangely using MillionCubes, indexed mode is twice as slow as the non indexed mode...

Am I missing something?

250,000 static cubes at 29 fps (non-indexed mode) 14 fps (indexed mode).

However, updating the coordinates using a float array is considerably faster.

And moving the cubes with updateVertices(coords) is three times faster in indexed mode (8 iterations instead of 24) which is great!

andres

andres

Re: Getting started with GLGraphics.

2 years ago

Thanks for testing.

Yes, I also noticed similar inconsistencies when running the MillionCubes example on Windows. My initial testings on OSX gave the expected result: indexed mode faster that non-indexed (from 2fps to 10fps with 1,000,000 static cubes, NVidia Geforce 320M).

But on Windows I got the reverse behavior as you did, although I don't have the fps values on top of my head. So I guess this feature needs further debugging.

Maybe I'm doing something completely wrong at the level of the OpenGL function calls and buffers, but the fact that it works fine at least on one platform, makes difficult to point out the problem right away.

guess

guess

Re: Getting started with GLGraphics.

2 years ago

Well actually I'm using a Mac, so I guess it is not system dependent.

And I'm using a GeForce 8600M GT.

I didn't totally understand the part that starts with -

int indices[] = new int[36 * cubeCount];

I thought maybe it had something to do with that. Why is 36 used? I tried changing it to 32 and my computer went haywire. So I guess it is right.

jimthree

jimthree

Re: Getting started with GLGraphics.

2 years ago

Hi Andres,

I've just had a chance to look over the million cubes example in the library, I've noted down some data for you for various numbers of cubes.

My system is a Quad core i7 3.4Ghz, 8GB Ram and running Windows 7x64. I've got 2 nVidia GTX470 running in SLI mode.

                    FPS           %Util
      cubes	    norm   idx	  CPU	GPU
      ---------------------------------------------
      500,000	    60	   60	  >2%	94%
      750,000	    42.8   42.8	  25%	99%
      1,000,000     32.2   32.2	  25%	99%
      1,500,000     5.4	   21.6	  25%	99%
      2,000,000     4	   6	  25%	99%

I think there is something interesting here. The only time I see any difference in FPS between the two modes (non-indexed and indexed) is when I'm pushing the limits of what my system can do. The indexed mode performs better where there is a difference.

When the GPU maxs out in % utilisation, it seems to fall back to the CPU. The CPU total never rises above 25% although this appears to be one of the 4 cores maxed out, it never spreads the load between cores, although it does swap cores every few seconds. It's difficult to say what SLI is bringing to this party. I plan to disable it and run some more tests to see if the GPU maxs out earlier if the cards aren't pared. If the results are the same then it would suggest that it's not taking advantage of SLI, or my system isn't configured properly.

Does anyone know why my framerate seems to be capped at 60fps? I've seen this before in all the 3D work I've done in processing, regardless of how little geometry I render.

cheers

Jim

andres

andres

Re: Re: Getting started with GLGraphics.

2 years ago

Thanks for the detailed benchmark. It seems to indicate that the "indexed" mode doesn't have much effect, except in more extreme situations with very large geometries. Good to know.

motscousus

Re: Getting started with GLGraphics.

2 years ago

quick question, that might sound silly. how do you get the GPU usage ? :)

jimthree

jimthree

Re: Getting started with GLGraphics.

2 years ago

No, that's a very good question, I've spent ages trying to work out how to track GPU performance. In the end I used a small app called GPU-Z from here: http://www.techpowerup.com/downloads/1930/TechPowerUp GPU-Z v0.5.1.html

(I wanted to use RivaTuner, but it doesn't support newer Nvidia cards apparently). If anyone has any better solutions, let us know.

Jim

motscousus

Re: Getting started with GLGraphics.

2 years ago

ok thanks. unfortunalty it's windows only, but i'll find a windows machine to run some test.

thanks !

henri

guess

guess

Re: Getting started with GLGraphics.

2 years ago

Another question about GLModel.

Is there a way where you change the color of one POINT of the model, something like this (which doesn't work) ? :

      n = 50;   // where n is within the colors array

        colors[4 * n + 0] = 225.0f;
        colors[4 * n + 1] = 120.0f;
        colors[4 * n + 2] = 75.0f;
        colors[4 * n + 3] = 1.0f;

        theModel.updateColors(colors);

Or do you imperatively need to cycle through (for loop) the entire colors float list, telling all the other colors to stay the same?

Thanks!

UPDATE : Yes it works...

andres

andres

Re: Getting started with GLGraphics.

2 years ago

Yes, it is a valid operation. A little inefficient though, since updateColors(colors) will copy the entire array to the GPU, even though only one element changed.

guess

guess

Re: Getting started with GLGraphics.

2 years ago

Okay. Is this also true ( copying the entire array to the GPU) if I use :

theModel.beginUpdateColors();
theModel .updateColor(24 * loc, 0.55, 0.10, 0.90, 225.0);
theModel .endUpdateColors();

? Or does this method just update the color of one vertex?

Thanks again!

andres

andres

Re: Getting started with GLGraphics.

2 years ago

In fact, yes: when you do a bunch of updateColor() calls for single vertices, GLGraphics internally creates a temporary float array capable of holding all the vertices in the model, and then copies this temporary array to the GPU in the endUpdateColors() call. Which for modifying just a few vertices is not particularly efficient.

But another way of modifying the geometry is to directly access the float buffers that map to the GPU data: vertices, colors, normals, texCoords, attributes, and indices. All of these are of type FloatBuffer, with the exception of indices, which is an IntBuffer. So yo could do:

model.beginUpdateColors();
model.colors.position(vertIdx * 4); // Go to the position vertIdx * 4 in the buffer
model.colors.put( 0.55);
model.colors.put( 0.10);
model.colors.put( 0.90);
model.colors.put(1.00);
// You could also do model.colors.put(col) with float[] col = {0.55, 0.10, 0.90, 1.0}, etc.
model.endUpdateColors();

All of these should be properly documented. I will try to put some wiki up with an overview of these different APIs.

guess

guess

Re: Getting started with GLGraphics.

2 years ago

I have another question.

Can you make a GLModel :

model = new GLModel(this, 4 * numSprites, GLModel.QUADS, GLModel.DYNAMIC);

that has a different texture for each quad? or for example sets each texture from a choice of say 5 different textures?

Thanks

andres

andres

Re: Getting started with GLGraphics.

2 years ago

GLModel doesn't let you apply different textures to different groups of vertices in your geometry. This limitation was removed in the opengl2 renderer i'm currently implementing, but I don't think i can port this feature back to glgraphics, at least for the time being.

One workaround would be to define a "texture atlas": basically a large image containing all the textures, and by properly setting the texture coordinates of the vertices you would get the different faces of your model mapped with the right region of the atlas.

rbrauer

rbrauer

Re: Getting started with GLGraphics.

2 years ago

I'm trying to run MillionCubes on a factory overclocked GeForce GTX 560 Ti, Processing 194, GLGraphics .99, WinXPx64, 32bit Java. It will draw 430,080 cubes and not one more without complaining about memory.

"OpenGL error 1285 at top endDraw(): out of memory"

The card is supposed to have 1Gb of memory and GPU-Z shows it using 478Mb with load in the low 60s while running with 430,080 cubes. If I try many more than that, they are still drawn but sometimes have seemingly random per face or per vertex colors. Trying with even higher numbers causes a null pointer exception.

Exception in thread "Animation Thread" java.lang.NullPointerException
    at codeanticode.glgraphics.GLModel.beginUpdateVertices(Unknown Source)
    at MillionCubes.createCubes(MillionCubes.java:105)
    at MillionCubes.setup(MillionCubes.java:74)
    at processing.core.PApplet.handleDraw(Unknown Source)
    at processing.core.PApplet.run(Unknown Source)
    at java.lang.Thread.run(Unknown Source)

Anyone have any insight into this?

jimthree

jimthree

Re: Getting started with GLGraphics.

2 years ago

I would think about moving to 64bit java and JOGL libs, it could improve memory access. worth an expriment at least.

Jim

rbrauer

rbrauer

Re: Getting started with GLGraphics.

2 years ago

Thanks for the suggestion Jim. I installed the JDK and it ran okay at one million reporting 30.2FPS. By the way, I usually put frameRate(-1); if I want to try a sketch uncapped by the default 60FPS. I tried messing with JOGL a little, but didn't really know what I was doing. I think in 194 it ships with various dll versions and chooses the ones to use automatically.

I almost forgot to mention, this only put the GPU load in the high 60s to 71 or so acoording to GPU-Z which I thought was odd. [edit] I just noticed that if you add whatever java.exe Processing is using to NVidia control panel under "Manage 3D Settings" and put vertical sync on "Force off" your OpenGL frame rate wont be limited to 60.

quaghm

Re: Getting started with GLGraphics.

1 year ago

Time to bump this excellent thread! Learned a lot from this discussion.

Few questions though:

- how can I draw a sphere instead of the cube previously mentioned? I understand I cannot simply use sphere() (duh), but is there any faster way than drawing all vertices, lines, ... I wouldn't even know where to start.

- I want to link Toxiclibs' particle system to this method of drawing, I suppose that should be done with points.displaceVertex() or points.updateVertex() ? I've altered the SwarmingPoints example to run with 80,000 particles. The framerate drops tremendously. Any tips on how to achieve moving points with about 500,000? I'm happy with 30FPS.

Many thanks! Will be working on it anyway, but advice is always welcome :)

Top Reply