Getting serial port data in to draw() function

Core Library Questions

ofeyrpf

Getting serial port data in to draw() function

in Core Library Questions • 1 year ago

Hi,

I'm trying to control a variable inside draw() with data from the serial port. The serial port is connected to an Arduino with a simple potentiometer circuit.

I can read in from the serial port to a variable called inByte. But then how do I work with that inside draw()? The code is below.

Any help would be greatly appreciated.

Thanks,

Shane

import processing.serial.*;

Serial myPort; // The serial port

void setup () {
size(400, 300);
println(Serial.list());
myPort = new Serial(this, Serial.list()[0], 9600);
myPort.bufferUntil('\n');
}
void draw () {
    fill(0, 12);
    line(inByte, 0, width, height);
}

void serialEvent (Serial myPort) {
String inString = myPort.readStringUntil('\n');

if (inString != null) {
    inString = trim(inString);
    float inByte = float(inString);
    inByte = map(inByte, 0, 1023, 0, 255);

}
}

Replies(8)

jbum

Re: Getting serial port data in to draw() function

1 year ago

When you declare float inByte inside of serialEvent, the variable is local to that function, and can't be accessed outside of the function. This is why your use of inByte inside the draw function is likely generating an error message.

The section of code where you can legally access the variable is called the 'scope' of the variable, and we say that variables declared inside functions have 'local scope' -- they are local to the function.

What you want is a variable with 'global scope' - meaning it can be accessed everywhere. To do this, you declare the variable outside the function. You can still use it inside the serialEvent function, but you can use it in other places, like the draw function as well.

As a general rule, try to use locally scoped variables most of the time. Use global scope only when you need it, as in this particular case. This will help you avoid accidentally reusing global vars, which can cause hard-to-debug problems.

import processing.serial.*;
Serial myPort; // The serial port
int inByte; // <-- moved this here, used a more appropriate data type
void setup () {
size(400, 300);
println(Serial.list());
myPort = new Serial(this, Serial.list()[0], 9600);
myPort.bufferUntil('\n');
}
void draw () {
fill(0, 12);
line(inByte, 0, width, height);
}
void serialEvent (Serial myPort) {
String inString = myPort.readStringUntil('\n');
if (inString != null) {
inByte = map(int(trim(inString)), 0, 1023, 0, 255);
}
}

ofeyrpf

Re: Getting serial port data in to draw() function

1 year ago

jbum,

Thanks for your reply. I understand what you mean.

When I run it I get an error,

"cannot convert from float to int"

Thanks,

Shane

jbum

Re: Getting serial port data in to draw() function

1 year ago

Whoops:

Add a type cast in this line, as shown:

inByte = (int) map(int(trim("2.3")), 0, 1023, 0, 255);

OR change the data type of inByte back to a float....

float inByte;

ofeyrpf

Re: Getting serial port data in to draw() function

1 year ago

jbum,

You've been very helpful thanks,

inByte within draw() doesn't seem to update. I thought it would. The idea was that I'd like to turn the pot and this would move a coordinate of the line. (But I'm sure that's obvious from the code.)

Is that possible here or do I need a completely different approach?

Thanks,

Shane

ofeyrpf

Re: Getting serial port data in to draw() function

1 year ago

I can see that inByte stays at 0.

void draw () {
    fill(0, 12);
    line(inByte, 0, width, height);
    println(inByte);
}

I wonder how to get this to update? I did try putting the code to read the serial port inside the draw function but it wasn't happy having the serialEvent function inside draw().

Thanks

jbum

Re: Getting serial port data in to draw() function

1 year ago

Leave your serial function as it was (as a function outside of draw).

Inside of draw, add these three lines to call it, when data is available.

if ( myPort.available() > 0) { // If data is available,

serialEvent(myPort);

}

Also, to debug that it's being called, you can add a println inside serialEvent.

void serialEvent (Serial myPort) {
String inString = myPort.readStringUntil('\n');
if (inString != null) {
inByte = (int) map(int(trim(inString)), 0, 1023, 0, 255);
println(inString);
}
}

ofeyrpf

Re: Getting serial port data in to draw() function

1 year ago

It's working pretty well now. Just one small problem, when the line lines the previous lines remain.

//Works with SerialLine Arduino code
//Circuit diagram http://www.arduino.cc/en/Tutorial/Graph
import processing.serial.*;
Serial myPort;        // The serial port
int inByte;           // <-- moved this here, used a more appropriate data type

void setup () {
size(400, 300);
println(Serial.list());
myPort = new Serial(this, Serial.list()[0], 9600);
myPort.bufferUntil('\n');
background(0);
}

void draw () {
stroke(127, 34, 255);
line(0, 0, inByte, height);
print("inByte = ");
println(inByte);
if ( myPort.available() > 0) { // If data is available,
    serialEvent(myPort);
}
}

void serialEvent (Serial myPort) {
String inString = myPort.readStringUntil('\n');

if (inString != null) {
    inByte = (int) map(int(trim(inString)), 0, 1023, 0, width);
    print("inString = ");
    println(inString);
}
}

Thanks for all your help,

Shane

ofeyrpf

Re: Getting serial port data in to draw() function

1 year ago

This is fantastic! I can now get a small ellipse to move up and down controlled by the pot.

Here's the code if anyone is interested.

//Works with SerialLine Arduino code
//Circuit diagram http://www.arduino.cc/en/Tutorial/Graph
import processing.serial.*;
Serial myPort;        // The serial port
int inByte;           // <-- moved this here, used a more appropriate data type

void setup () {
size(100, 100);
smooth();
noStroke();
ellipseMode(RADIUS);
println(Serial.list());
myPort = new Serial(this, Serial.list()[0], 9600);
myPort.bufferUntil('\n');
}

void draw () {
fill(0, 12);
rect(0, 0, width, height);
fill(255);
ellipse(width/2, inByte, 5, 5);
print("inByte = ");
println(inByte);
if ( myPort.available() > 0) { // If data is available,
    serialEvent(myPort);
}
}

void serialEvent (Serial myPort) {
String inString = myPort.readStringUntil('\n');

if (inString != null) {
    inByte = (int) map(int(trim(inString)), 0, 1023, 0, height);
    print("inString = ");
    println(inString);
}
}

Thanks,

Shane

Top Reply