getting mousReleased() to move rect further

Programming Questions

inputhone

getting mousReleased() to move rect further

in Programming Questions • 5 months ago

hey folks,

i am quite new to processing and i am having a problem with my new code. i added only the part of the code that i want to get working. i want the rect() to move out of the screen by itself by using mouseReleased(), after it came in and stopped (there you canrotate it by mouseX).

But it will only move once at a time when you click on the screen. i assume the action is not done repeatedly afte the mouse is clicked.

int l;
int b;

//declare grid x-value
int transx1;

int g = 8;

void setup() {


    size(900, 600);



}

void draw() {

    background(175, 204, 231);
    noStroke();
    rectMode(CENTER);

    l = 500; //Höhe
    b = 90; //Breite
    float a = PI*mouseX / width*2;
    float c = PI*random(width/2 - 1, width/2 + 1) / width * 4;

//Black Stripe

    fill(0);
    //Moving In

    translate(transx1,height/2);

      //Stops at specific position
      if(transx1<width/2-b){
        transx1 = transx1 + g;


      }
    //Draw Rect and rotate by mouseX
    rotate(a);
    rect(0, 0, b, l);


}

void mouseReleased(){

transx1 = transx1 + g;

}

Any Ideas?

Replies(3)

v.k.

Re: getting mousReleased() to move rect further

5 months ago

mouseReleased(), as mousePressed() are called once each time the mouse is pressed or released. YOu can have a boolean to control the movement triggered by mouse released... Like this:

changes in bold:

int l;
int b;//declare grid x-value
int transx1;
int g = 8;
boolean go;
void setup() {
size(900, 600);
// just to make things nicer :)
smooth();
}
void draw() {
background(175, 204, 231);
noStroke();
rectMode(CENTER);
if(go)
transx1 = transx1 + g;
l = 500; //Höhe
b = 90; //Breite
float a = PI*mouseX / width*2;
float c = PI*random(width/2 - 1, width/2 + 1) / width * 4; //Black Stripe
fill(0);
//Moving In
translate(transx1, height/2);
//Stops at specific position
if (transx1<width/2-b) {
transx1 = transx1 + g;
} //Draw Rect and rotate by mouseX
rotate(a);
rect(0, 0, b, l);
}
void mouseReleased() {
go = true;
}

tfguy44

Re: getting mousReleased() to move rect further

5 months ago

Here I've used a couple of booleans to remember if the rectangle is moving in or out. Once it has moved in as far as it should, it stops moving in. Once the mouse is clicked after it has stopped moving in, it starts moving out.

int l;
int b;
int transx1;
int g = 8;
boolean movingIn = true;
boolean movingOut = false;
void setup() {
size(900, 600);
noStroke();
rectMode(CENTER);
}
void draw() {
background(175, 204, 231);
l = 500;
b = 90;
float a = PI*mouseX / width*2;
if (movingIn) {
transx1 = transx1 + g;
}
if ( transx1>=width/2-b) {
movingIn = false;
}
if (movingOut) {
transx1 = transx1 - g;
}
translate(transx1, height/2);
rotate(a);
fill(0);
rect(0, 0, b, l);
}
void mousePressed() {
if ( movingIn == false ) {
movingOut = true;
}
}

inputhone

Re: getting mousReleased() to move rect further

5 months ago

thanks folks this is great. i also solved it by restructuring to a current and a target position, but the boolean concept seems more beautiful..

here is my version, what you think about this? is it good like this?

int l;
int w;

int target_position_x1;

int current_position_x1;

float angle;
int speed = 10;

void setup() {

    size(900, 600);
    smooth();
    l = 500; // length
    w = 90; // width

    rectMode(CENTER); // all rectangles are drawn from center

    // first of all: move index stripes to bar to center
    target_position_x1 = width/2-w;

    // let them start from left or right
    current_position_x1 = 0;

    // rotation
    angle = 0;
}

void draw() {

    background(175, 204, 231); // redraw the background
    noStroke();

//Stripe One Black


    // First: Move to target_position_x
    if (current_position_x1 < target_position_x1) {
      current_position_x1 += speed; // Move to right
    }
    translate(current_position_x1, height/2); // Always verticle centered

    // Second (to respect translation!): Update rotation angle, if:
    if (current_position_x1 >= target_position_x1 && // we reached out target position
        current_position_x1 < width) { // and still on screen

        // Rotate our obj based on MousePosition
        angle = PI * mouseX / width * 2;
    }

    // Draw a stripe at the previous caluclated position and declare angle!
    rotate(angle);
    fill(0);
    rect(0, 0, w, l);

}

void mouseReleased(){
//if mouseReleased once update angle and shake to zero
angle=0;

//Move objects out again
target_position_x1 = width+w;

}

Top Reply