Getting Average Pixel Color Value from a PImage that is constantly changing.

olimason

Getting Average Pixel Color Value from a PImage that is constantly changing.

in Contributed Library Questions • 3 months ago

Hi Everyone,

I have a sketch that focuses a of a small section of what someone is wearing.

I have loaded this into a PImage and have successfully displayed it in the corner of my sketch, now I want to take the data from the PImage and get a running average of the color data.

I could do with a little help!

Regards,

Oli

import hypermedia.video.*;

import java.awt.Rectangle;

OpenCV opencv;

// contrast/brightness values

int contrast_value = 0;

int brightness_value = 0;

int adv = 0;

PImage c;

int average;

int total = 0;

void setup() {

size( 320, 240 );

opencv = new OpenCV( this );

opencv.capture( width, height ); // open video stream

opencv.cascade( OpenCV.CASCADE_FRONTALFACE_ALT ); // load detection description, here-> front face detection : "haarcascade_frontalface_alt.xml"

}

public void stop() {

opencv.stop();

super.stop();

}

void draw() {

// grab a new frame

opencv.read();

opencv.contrast( contrast_value );

opencv.brightness( brightness_value );

// proceed detection

Rectangle[] faces = opencv.detect( 1.2, 2, OpenCV.HAAR_DO_CANNY_PRUNING, 40, 40 );

// display the image

image( opencv.image(), 0, 0 );

// draw face area(s)

noFill();

stroke(255, 0, 0);

for ( int i=0; i<faces.length; i++ ) {

c = get(faces[i].x, faces[i].y+100, faces[i].width-20, faces[i].height-20 );

image(c, 0, 0);

}

Replies(4)

amnon.owed

Re: Getting Average Pixel Color Value from a PImage that is constantly changing.

3 months ago

Moved to contributed library quesions because your code requires a contributed library to run.

Go over all the pixels of the PImage. Calculate the average r, g, b. Then you have the average color.

This can be done with a custom method of a few lines, so it's very suitable as a beginner project. Give it a try.

color getAverageColor(PImage img) {
// code
return avgColor;
}

For more tips see: http://processing.org/tutorials/pixels/

olimason

Re: Getting Average Pixel Color Value from a PImage that is constantly changing.

3 months ago

Thanks for they reply Amnon,

I have updated the code a little, but when I try to print either r g b to see what value they are returning I get no result, so Im guessing there is a problem somewhere?

Regards,

Oli

import hypermedia.video.*;

import java.awt.Rectangle;

OpenCV opencv;

// contrast/brightness values

int contrast_value = 0;

int brightness_value = 0;

int adv = 0;

PImage c;

int AvgColor;

void setup() {

size( 320, 240 );

opencv = new OpenCV( this );

opencv.capture( width, height ); // open video stream

opencv.cascade( OpenCV.CASCADE_FRONTALFACE_ALT ); // load detection description, here-> front face detection : "haarcascade_frontalface_alt.xml"

}

public void stop() {

opencv.stop();

super.stop();

}

void draw() {

// grab a new frame

opencv.read();

opencv.contrast( contrast_value );

opencv.brightness( brightness_value );

// proceed detection

Rectangle[] faces = opencv.detect( 1.2, 2, OpenCV.HAAR_DO_CANNY_PRUNING, 40, 40 );

// display the image

image( opencv.image(), 0, 0 );

// draw face area(s)

noFill();

stroke(255, 0, 0);

for ( int i=0; i<faces.length; i++ ) {

c = get(faces[i].x, faces[i].y+100, faces[i].width-20, faces[i].height-20 );

image(c, 0, 0);

}

color getAdverageColor(PImage c ) {

loadPixels();

c.loadPixels();

//load all pixels into array

for (int y = 0; y < c.height; y++) {

for (int x = 0; x < c.width; x++) {

int loc = x + y*width;

//reads all rgb vlaues from every pixel

float r = red(c.pixels[loc]);

float g = green(c.pixels[loc]);

float b = blue(c.pixels[loc]);

}

updatePixels();

return AvgColor;

}

amnon.owed

Re: Getting Average Pixel Color Value from a PImage that is constantly changing.

3 months ago

Credit for trying. But at the moment you don't call the method anywhere in your main sketch, nor do you have println's, nor do you have any calculations in it. So I don't know what you were expecting from this method.

Some suggestions:

You don't need to load and update the pixels of the main canvas.
You don't need the xy. Loop through the pixels. Then you don't need to calculate the index.
You can use faster methods to retrieve the rgb values (see the reference).
The returned variable should be locally calculated on each method call (not some global variable).

I have made the proposed changes to the custom method. Put in an image and get out it's average color.

Adapted Code

color getAverageColor(PImage img) {
img.loadPixels();
int r = 0, g = 0, b = 0;
for (int i=0; i<img.pixels.length; i++) {
color c = img.pixels[i];
r += c>>16&0xFF;
g += c>>8&0xFF;
b += c&0xFF;
}
r /= img.pixels.length;
g /= img.pixels.length;
b /= img.pixels.length;
return color(r, g, b);
}

Sidenote: In general you should consider posting code examples related to the actual problem. For example with your current code example people can't run your code if they don't have the library.

olimason

Re: Getting Average Pixel Color Value from a PImage that is constantly changing.

3 months ago

Thank you so much,

Mine was a pretty poor effort to be fair!, still trying to get to grips with processing coming from Max/Msp.

But the great people on the forum such as yourself are helping a lot.

This is like the fifth time you have helped me btw, I do appreciate it.

Regards,

Top Reply