Get Spherical Coordinate Angles

Programming Questions

asimes

Get Spherical Coordinate Angles

in Programming Questions • 1 year ago

I have a code that can position a point relative to point(0, 0, 0) using Spherical Coordinates. I'm not sure how to reverse the process to get the angle information based on an arbitrary point. For example, if a point in space is at:

x = 0.25

y = -0.5

z = 1

Then I know that the radius is sqrt(sq(x)+sq(y)+sq(z)) or about 1.145. The elevation and azimuth are a little trickier for me to figure out. The code below positions a sphere (the red one) around another sphere (the stroke only one) at a fixed radius. I would like to make a code that tests every point in a bounding box and I'll need to know the angle relative to the center of the box. (If the box goes from -2 to 2 in the x, y, and z directions then I'll test every point inside of it assuming the box is centered on (0, 0, 0). In other words the box has a length of 4 in each direction.)

NOTE: In the code below I named elevation theta and azimuth phi based on this link: http://en.wikipedia.org/wiki/Spherical_coordinate_system

float rad = 200;
float theta = HALF_PI;
float phi = 0;
void setup() {
size(800, 600, P3D);
}
void draw() {
//theta += TWO_PI/1000;
phi += TWO_PI/100;
float x = cos(phi)*sin(theta)*(rad);
float y = cos(theta)*(rad);
float z = sin(phi)*sin(theta)*(rad);
background(255);
translate(width/2, height/2);
noFill();
sphere(rad);
translate(x, y, z);
fill(255, 0, 0);
sphere(20);
}

Replies(9)

allonestr..

Re: Get Spherical Coordinate Angles

1 year ago

If I understand you correctly, you'd like to find the angle of elevation of a point from a plane, and the azimuth angle of that point from an axis. Here I've done it all from the origin (0, 0, 0), say if you'd like help extending this to be from any other point (px, py, pz).

azimuth - here from the z-axis in the xz plane

Yyou know the distances of the point along the x and z axes, so you can use inverse tan to find the azimuth:

azimuth = atan2(x distance, z distance);

so if the point has co-ordinates (i, j, k), then this is

azimuth = atan2(i, k);

elevation from xz plane

You need a little more information - that is, the distance from the origin to the end point of the azimuth (the little blob in my diagram).

azimuthLength = sqrt(i*i + k*k);

More trig them gives you the elevation:

elevation = atan2(j, azimuthLength);

asimes

Re: Get Spherical Coordinate Angles

1 year ago

Thank you, that was a good explanation. I didn't think about using a different origin point yet (I don't think I'll need it for what I'm making), but if I had to guess on how to do it it would be like this:

rad = sqrt(sq(x1-x2)+sq(y1-y2)+sq(z1-z2));

azimuth = atan2(x1-x2, z1-z2);

azimuthLength = sqrt(sq(x1-x2)+sq(z1-z2));

elevation = atan2(y1-y2, azimthLength);

This is not tested, just trying to see if I can extend what I understand from looking at your explanation

Chrisir

Re: Get Spherical Coordinate Angles

1 year ago

Hello all,

I used this mighty sketch from asimes and made a Turtle program like in LOGO but as 3D.

Imagine a turtle that draws with a pen. When you tell it to go forward, it heads forward and paints a line.
When you tell it to turn right 90° and then go forward, you got an right angle painted. Repeat that four times a you have rect.
Now imagine you got a water turtle and can tell it to turn upwards and downwards with its nose as well and thus paint 3D or paint lines that go in an angle upward or downward from the classical 2D canvas of the Turtle.

I tried to draw a cube by first paint a rect (that works) (points abcda), then I am at point "a" again. Then go forward once to point "b". Then turn downward (that's the 3D part) 90° and paint again a rect. Now you would have to rects in a 90° angle.
That four times should give you a cube made of four rects (doesn't work).

Anyway, I failed utterly, probabaly due to a permanent lack of intelligence I encounter regularly.

Maybe the problem lies there that when I calculate the new line to draw (the new turtle pos) I assume to start from the 0,0,0 which is true only at the start.

Maybe someone can track down my bug.

Here's what I got so far:

// Turtle from LOGO but in 3D
// approach:
// reset canvas and all values at beginning from draw, paint a rect and then a cube.
//
// issue:
// works only 2D, not 3D
//
// to do:
// use another approach and push to an arrayList and paint this instead
// make Turtle a real class
//
float theta = 0; // degree / 2D angle of Turtle (left / right)
float phi = 0; // degree / 3D angle of Turtle (up / down)
boolean penUp = false; // turtle pulls a pen; when the pen moved up, it's not drawing (pen not on the canvas then)
//
int numMoves=0; // just to debug and show, where turtle was going
//
PVector posTurtle = new PVector ();
//
void setup() {
size(1444, 1000, P3D);
posTurtle.set( width/2, height/2, 0 );
}
//
void draw() {
// Init
background(255);
theta = 22;
phi = 0;
numMoves=0;
posTurtle.set( width/2, height/2, 0 );
//
quadRight() ;
forward (130);
noseDown(90);
quadRight() ;
}
// --------------------------------------------------------------------------
void quadRight() {
showTurtle ();
for (int i = 0 ; i<4; i++) {
forward (130);
RI (90);
//
} // for
} // func
void quadLeft() {
showTurtle ();
for (int i = 0 ; i<4; i++) {
forward (130);
LE (90);
//
} // for
} // func
// ==========================================================================
// the Turtle tools - make that a class some times
void RI (int angle1) {
// turn RIGHT
theta-=angle1;
}
//
void LE (int angle1) {
// turn left
theta+=angle1;
}
//
void noseDown (int angle1) {
phi-=angle1;
}
//
void nosUp (int angle1) {
phi+=angle1;
}
//
void forward (int rad) {
// that's drawing with line
float x = cos(radians(phi))*sin(radians(theta))*(rad);
float y = cos(radians(theta))*(rad);
float z = sin(radians(phi))*sin(radians(theta))*(rad);
if (penUp==false) {
line (posTurtle.x, posTurtle.y, posTurtle.z,
posTurtle.x+x, posTurtle.y+y, posTurtle.z+z );
}
posTurtle.x = posTurtle.x+x ;
posTurtle.y = posTurtle.y+y ;
posTurtle.z = posTurtle.z+z ;
numMoves++;
showTurtle () ;
}
void showTurtle () {
// small sphere
pushMatrix();
translate ( posTurtle.x, posTurtle.y, posTurtle.z );
fill(255, 0, 0);
sphere(11);
text( numMoves, 20, 0 );
popMatrix();
}

Thank you all very much!

Greetings, Chrisir

allonestr..

Re: Get Spherical Coordinate Angles

1 year ago

@asimes - That looks right. The only thing I'd add is a suggestion to use meaningful variable names.

If the point you're measuring from is the centre of the sphere, then call it (cx, cy, cz), and if the other point is on the surface, then call it (sx, sy, sz). These are harder to muddle up than (x1, y1, z1) and (x2, y2, z2).

asimes

Re: Get Spherical Coordinate Angles

1 year ago

I tried to track the red sphere's angles with the method above and place another green sphere which is supposed to match it. Something seems to have gone wrong, I don't know what to be honest. If you could help me figure out what I'd really appreciate it. I want to have a good grasp of this before I try the bounding box sketch.

float rad = 200;
float theta = HALF_PI;
float phi = 0;
void setup() {
size(800, 600, P3D);
}
void draw() {
theta += TWO_PI/1000;
phi += TWO_PI/100;
float x = cos(phi)*sin(theta)*(rad);
float y = cos(theta)*(rad);
float z = sin(phi)*sin(theta)*(rad);
float rad2 = sqrt(x*x+y*y+z*z);
float azimuth = atan2(x, z);
float azimuthLength = sqrt(x*x+z*z);
float elevation = atan2(y, azimuthLength);
float x2 = cos(azimuth)*sin(elevation)*(rad2);
float y2 = cos(elevation)*(rad2);
float z2 = sin(azimuth)*sin(elevation)*(rad2);
background(255);
translate(width/2, height/2);
noFill();
sphere(rad);
translate(x, y, z);
fill(255, 0, 0);
sphere(20);
translate(-x+x2, -y+y2, -z+z2);
fill(0, 255, 0);
sphere(20);
}

allonestr..

Re: Get Spherical Coordinate Angles

1 year ago

You've got your translations muddled up. Here I've split the translations for the large sphere and the two smaller ones into three different matrices so that you can see what's going on.

background(255);
pushMatrix();
translate(width/2, height/2);
noFill();
sphere(rad);
popMatrix();

pushMatrix();
translate(width/2, height/2);
translate(x, y, z);
fill(255, 0, 0);
sphere(20);
popMatrix();

pushMatrix();
translate(width/2, height/2);
translate(-x, -y, -z);
fill(0, 255, 0);
sphere(20);
popMatrix();

Here is the same without the matrices, with the third translation corrected

background(255);
translate(width/2, height/2);
noFill();
sphere(rad);
translate(x, y, z);
fill(255, 0, 0);
sphere(20);

translate(-2 * x, -2 * y, -2 * z);
fill(0, 255, 0);
sphere(20);

Say if you'd like this explaining.

asimes

Re: Get Spherical Coordinate Angles

1 year ago

I should have explained better instead of saying match. What I meant was for the green sphere to be placed in exactly the same place the red sphere is but using the new variables x2, y2, z2 (ideally it would cover the red sphere). In my code I wrote:

translate(width/2, height/2); // Translate to put the origin in the center of the screen
noFill();
sphere(rad); // Big sphere
translate(x, y, z); // Translate to where the red sphere should go
fill(255, 0, 0);
sphere(20); // Red sphere
translate(-x+x2, -y+y2, -z+z2); // Undo red translation, apply what should be green sphere translation
fill(0, 255, 0);
sphere(20); // Green sphere

In other words I want to translate using x2, y2, and z2 to place the green sphere. I think that the problem is in my azimuth and elevation code. If those angles were equal to theta and phi then x, y, z would be equal to x2, y2, z2

allonestr..

Re: Get Spherical Coordinate Angles

1 year ago

Ah, I/you/we have the variables in the atan2 brackets the wrong way round!

For my sanity, I've replaced your (x, y, z) with (redx, redy, redz) and your (x2, y2, z2) with (greenx, greeny, greenz). I've also reintroduced the matrices so that the translations don't accumulate too much (= I find this clearer).

void draw()
{
theta += TWO_PI/1000;
phi += TWO_PI/100;
float redx = cos(phi)*sin(theta)*(rad);
float redy = cos(theta)*(rad);
float redz = sin(phi)*sin(theta)*(rad);
float rad2 = sqrt(redx*redx + redy*redy + redz*redz);
float azimuth = atan2(redz, redx);
float azimuthLength = sqrt(redx*redx + redz*redz);
float elevation = atan2(azimuthLength, redy);
float xgreen = cos(azimuth)*sin(elevation)*(rad2);
float ygreen = cos(elevation)*(rad2);
float zgreen = sin(azimuth)*sin(elevation)*(rad2);
background(255);
pushMatrix();
translate(width/2, height/2);
noFill();
sphere(rad);
popMatrix();

pushMatrix();
translate(width/2, height/2);
translate(redx, redy, redz);
fill(255, 0, 0);
sphere(20);
popMatrix();
pushMatrix();
translate(width/2, height/2);
translate(xgreen, ygreen, zgreen);
fill(0, 255, 0);
sphere(20);
popMatrix();
}

asimes

Re: Get Spherical Coordinate Angles

1 year ago

Ha ha ha, I can't believe it was just the atan2 backwards. It works now, thanks for all the help

Top Reply