get other 3 corners

Programming Questions

clankill3r

in Programming Questions • 2 years ago

I have to get the corner coordinates of a rotated shape.

I did something simulair before but there the center of the rectangle was really the center.

Now i use a offset where it rotates around so getting the corners is a bit harder.

I managed to get 1 corner, but i can't manage to get the other 3 (or they get on the same place or the place don't make sense or they rotate in the other direction etc).

(p.s. how is the subjcect called about measuring triangles, it was something like triangology i believe but when i seatch for things like that i en up with art or food...).

float rectWidth = 10;
float rectHeight = 26;
float x = 100;
float y = 100;
float xCenterOffset = 0;
float yCenterOffset = 8;
float rotation = 0;
void setup() {
size(300, 300);
smooth();
rectMode(CENTER);
ellipseMode(CENTER);
}
void draw() {
background(104);
pushMatrix();
translate(x, y);
rotate(rotation);
// offset must be negative here
rect(-xCenterOffset, -yCenterOffset, rectWidth, rectHeight);
// no offset for the ellipse cause the purpose is to show the
// axis where it rotates around
ellipse(0, 0, 3, 3);
popMatrix();
// right bottom corner
float rectDiag = sqrt(( (rectWidth/2) - xCenterOffset) * ( (rectWidth/2) - xCenterOffset) + ( (rectHeight/2) - yCenterOffset) * ( (rectHeight/2) - yCenterOffset));
float rectAngle = atan2( (rectHeight/2) - yCenterOffset, (rectWidth/2) - xCenterOffset);
float cx1 = x + (rectDiag * cos(rectAngle + rotation));
float cy1 = y + (rectDiag * sin(rectAngle + rotation));
ellipse(cx1, cy1, 3, 3);
// others??
rotation += (radians(1));
}

Replies(5)

calsign

Re: get other 3 corners

2 years ago

Do you mean trigonometry?

kritzikra..

Re: Re: get other 3 corners

2 years ago

hey!

well, this is a little painful to do with basic geometry,

it becomes much much easier if you use (affine) matrices.

i'm assuming you don't know how this works, there's lots of info

on the web about it (e.g. wikipedia) but here's the basic ideas:

an affine matrix consists of 4 numbers (i believe 6 in processing's case

but let's ignore that for now). there are different kinds of matrices:

- translation matrix

- rotation matrix

- many more different types.

now you can multiply a vector and a matrix and the result will be a vector again,

so for instance

translation matrix * point will give you the translated point

rotation matrix * point will give you the point rotated around the center.

but it gets better, you can multiply two of those matrices and this will

give you a matrix again that does both things, so

translation matrix * rotation matrix will give _one_ matrix that first translates, then rotates,

rotation matrix * translation matrix will give one matrix that first rotates, then translates.

it still get's better. processing has built in matrix types, and you don't even need to understand

how they work exactly.

construct a new matrix by writing

PMatrix2D mat = new PMatrix2D();

this gives the so called identity matrix, if you apply it to a point nothing happens.

then you can do:

mat.rotate( PI/2 );

this will create a new matrix rotation matrix and apply it to your existing matrix.

then do a

mat.translate( 10, 10 );

this will create a new translation matrix and apply it to your rotation thingie.

and so on...

ultimately you have a bunch of methods to apply points to it as well (which is what you really want).

one way is:

float x = mat.multx( 50, 0 ); // where would the point 50,0 go after doing rotate(pi/2) and then translate(10,10)

float y = mat.multy( 50, 0 ); // according y coordinate

there's also another way to get x and y coordinates directly,

the code is below....

i hope this wasn't too much info for a single post :)

float rectWidth = 100;
float rectHeight = 260;
float x = 100;
float y = 100;
float xCenterOffset = 0;
float yCenterOffset = 8;
float rotation = 0;
void setup() {
size(300, 300);
smooth();
rectMode(CENTER);
ellipseMode(CENTER);
}
void draw() {
background(104);
pushMatrix();
translate(x, y);
rotate(rotation);
// offset must be negative here
rect(-xCenterOffset, -yCenterOffset, rectWidth, rectHeight);
// no offset for the ellipse cause the purpose is to show the
// axis where it rotates around
ellipse(0, 0, 3, 3);
popMatrix();
PMatrix2D mat = new PMatrix2D(); // create identity matrix
mat.translate( x, y ); // apply translation
mat.rotate( rotation ); // apply rotation
mat.translate( -xCenterOffset, -yCenterOffset ); // apply your offset
PVector res = new PVector(); // results will go here ...
mat.mult( new PVector( rectWidth/2, rectHeight/2 ), res ); // top right
ellipse( res.x, res.y, 3, 3 );
mat.mult( new PVector( -rectWidth/2, rectHeight/2 ), res ); // top left
ellipse( res.x, res.y, 3, 3 );
mat.mult( new PVector( rectWidth/2, -rectHeight/2 ), res ); // bottom right
ellipse( res.x, res.y, 3, 3 );
mat.mult( new PVector( -rectWidth/2, -rectHeight/2 ), res ); // bottom left
ellipse( res.x, res.y, 3, 3 );
rotation += (radians(1));
}

kritzikra..

Re: get other 3 corners

2 years ago

p.s. there's one more minor improvement.

you could, but definitely don't need to, fetch the matrix from

your current transformation stack.

this will save you the hastle of applying the same transforms twice.

the lines 36-49 from above would change to:

// offset must be negative here
translate( -xCenterOffset, -yCenterOffset );
rect(0, 0, rectWidth, rectHeight);
// no offset for the ellipse cause the purpose is to show the
// axis where it rotates around
ellipse(0, 0, 3, 3);
// let's save that matrix before we pop it!
// if you apply this matrix it will transform
// point exactly as your above rotate/translate/...
// commands say.
PMatrix2D mat = getMatrix((PMatrix2D) null);
popMatrix();
PVector res = new PVector(); // results will go here ...

btw --- if you understand these matrix transform then you can imagine

one of the fundamental tasks of a gpu: multiplying matrices crazy fast! :)

clankill3r

Re: get other 3 corners

2 years ago

thanks, i go look at it in detail somewhere this week but it looks good.
Is your method also fast?
Cause it's for a rts game and i must apllie the above for every unit.

.feda

Re: get other 3 corners

2 years ago

Can you link to your game if you have it hosted please?

Top Reply

Statistics

5 Replies
470 Views
0 Followers

Actions

Permalink