Gestures...

Android Processing

algo_macc..

in Android Processing • 2 years ago

Another question ...
Sorry for being very curious, but I explore processing-android from the south to the north.
I have to do a kind of workshop next week about interactivity with android and processing, that's why I'm looking into different way of developping applications, use sensor...
So, my next question is about gestures recognition.
I've built GESTURE_BUILDER on my spica, and it's all right.
But now I want to create an application to recognize gestures.

the problem it's that all the recognition activity take effect with the GestureOverlayView class, that is a kind of layout at the top of the other layout.
Unfortunately I believe Processing is only 1 layout, and so I can't use GestureOverlayView and any other layout.
Do you think there is a way to implement gesture in processing without rebuild all the recognition system ?

Thanks

Replies(5)

interstar

Re: Gestures...

2 years ago

Not sure about Android, so this may be irrelevant to you. But I've found ezGesture quite handy : http://www.silentlycrashing.net/ezgestures/

algo_macc..

Re: Gestures...

2 years ago

Hi interstar,

Thanks for the tips but ezGestures uses java.awt.Rectangle that is not implemented into Android so return me this error:

java.lang.NoClassDefFoundError: java.awt.Rectangle

No way, I don't want to re-write the ezgestures :)

But For now, I'm using the GestureDetector for the Android classic gestures like onScroll, onDoubleTap ...

Jesse Sco..

Re: Gestures...

2 years ago

That would be great if you can share some sample code that shows how to access the GestureDetector... ??

algo_macc..

Re: Gestures...

2 years ago

My pleasure :)

(There is probably some improvement to do )

first :

import android.view.GestureDetector;
import android.view.GestureDetector.SimpleOnGestureListener;
import android.os.Bundle;
GestureDetector mGestureDetector;
ArrayList<Foo> foo;
//Foo foo;
void setup() {
size(screenWidth, screenHeight, A2D);
// Fix the orientation so the sketch won't reset when rotated.
orientation(PORTRAIT);
noStroke();
smooth();
foo = new ArrayList();
}
void draw() {
background(255);
for (int i=0; i<foo.size(); i++) {
Foo f = (Foo) foo.get(i);
f.moveOn();
f.display();
}
}
void birth(float _x, float _y) {
foo.add(new Foo(_x, _y));
}
public void onCreate(Bundle savedInstanceState) {
super.onCreate(savedInstanceState);
mGestureDetector = new GestureDetector(this, new LearnGestureListener());
}
public boolean surfaceTouchEvent(MotionEvent me) {
if (mGestureDetector.onTouchEvent(me))
{
//return true;
return super.surfaceTouchEvent(me);
}
else
{
return false;
}
}

class Foo:

import android.view.animation.Interpolator;
import android.view.animation.OvershootInterpolator;
class Foo {
float x, y, taille, easing = 0.05, targetX, targetY, X, Y;
float totalAnimDx, totalAnimDy;
long startTime, endTime;
Interpolator animateInterpolator;
color couleur;
Foo(float _x, float _y) {
x = _x;
y = _y;
taille = 70;
animateInterpolator = new OvershootInterpolator();
couleur = color(123, 123, 123, 50);
}
void update(float _x, float _y) {
x += _x;
y += _y;
}
void moveOn() {
// x += _x;
// y += _y;
x = constrain(x, 0+taille/2, screenWidth-taille/2);
y = constrain(y, 0+taille/2, screenHeight-taille/2);
targetX = x;
targetY = y;
float dx = targetX - X;
float dy = targetY - Y;
if (abs(dx) > 1) X += dx * easing;
if (abs(dy) > 1) Y += dy * easing;
}
void quickly(float dx, float dy, long duration) {
startTime = System.currentTimeMillis();
endTime = startTime + duration;
totalAnimDx = dx;
totalAnimDy = dy;
long curTime =System.currentTimeMillis();
float percentTime = (float) (curTime - startTime) / (float) (endTime - startTime);
float percentDistance = animateInterpolator.getInterpolation(percentTime);
float curDx = percentDistance * totalAnimDx;
float curDy = percentDistance * totalAnimDy;
update(curDx, curDy);
}
void changeColor() {
couleur = color(random(255), random(255), random(255), 50);
}
void grow() {
if (taille<300) {
taille+=10;
println(taille);
}
else {
taille = 70;
}
}
void display() {
fill(couleur);
ellipse(X, Y, taille, taille);
}
}

class learGestureListener:

class LearnGestureListener extends GestureDetector.SimpleOnGestureListener {
@Override
public boolean onSingleTapUp(MotionEvent ev) {
println("onSingleTapUp");
birth(ev.getX(), ev.getY());
return true;
}
@Override
public boolean onDoubleTap(MotionEvent ev) {
println("onDoubleTap");
for (int i=0; i<foo.size(); i++) {
Foo f = (Foo) foo.get(i);
f.changeColor();
}
return true;
}
@Override
public void onShowPress(MotionEvent ev) {
println("onShowPress");
}
@Override
public void onLongPress(MotionEvent ev) {
for (int i=0; i<foo.size(); i++) {
Foo f = (Foo) foo.get(i);
f.grow();
}
println("onLongPress");
}
@Override
public boolean onScroll(MotionEvent e1, MotionEvent e2, float distanceX, float distanceY) {
println("onScroll");
for (int i=0; i<foo.size(); i++) {
Foo f = (Foo) foo.get(i);
f.update(distanceX, distanceY);
}
return true;
}
@Override
public boolean onDown(MotionEvent ev) {
println("onDown");
return true;
}
@Override
public boolean onFling(MotionEvent e1, MotionEvent e2, float velocityX, float velocityY) {
println("onFling");
final float distanceTimeFactor = 0.4f;
final float totalDx = (distanceTimeFactor * velocityX / 2);
final float totalDy = (distanceTimeFactor * velocityY / 2);
for (int i=0; i<foo.size(); i++) {
Foo f = (Foo) foo.get(i);
f.quickly(totalDx, totalDy, (long) (1000 * distanceTimeFactor));
}
return true;
}
}

Thank to Almond Mendoza for sharing some code on his blog.

+++

Jesse Sco..

Re: Gestures...

1 year ago

Thanks Algo...

Quick question... I guess more of a Java one than an Android...

I've got this to run fine, it prints and returns the proper values in this example...

However, I'm a bit unfamiliar with using return statements and extended classes, so how would I get this to return and test against a particular gesture elsewhere in my sketch?

My problem is that with mousePressed(), I see, to get multiple executions when I press my screen, so it's unreliable to use as a state change device... I want to use double tap or fling... but can't seem to figure out how to access it through surfaceTouchEvent()

Thanks in advance...

Top Reply

Gestures...

Replies(5)

Re: Gestures...

Re: Gestures...

Re: Gestures...

Re: Gestures...

Re: Gestures...

Statistics

Tags

Actions