function with name of Class as parameter

Programming Questions

mloizix

function with name of Class as parameter

in Programming Questions • 1 month ago

Hi,

I'm searching to make a function who has 3 parameters : String, ArrayList, Class ;

the goal of it is to search inside the ArrayList if an instance has the name specified in String parameter.

I've got an error : the Class parameter don't replace the Class name inside the function.

thanks a lot.

IntDict isNAMEinsideCLASS(String name, ArrayList itemList, Class theClass) {
IntDict toReturn = new IntDict();
int nmbInequality = 0;
for (int i= 0; i<itemList.size(); i++) {
theClass item = itemList.get(i);
if (item.name.equals(name)) {
toReturn.set("true", i);
}
else {
nmbInequality+=1;
}
}
if(nmbInequality == itemList.size()){
toReturn.set("false", -1);
}
return toReturn;
}

Replies(10)

GoToLoop

Re: function with name of Class as parameter

1 month ago

Class objects? That is too much advanced for me. Anyways, some points I've spotted:

1)
To access anything from a List, like using get() method for example,
we gotta specify what we're getting at that moment.

So, if what's inside an ArrayList are Class objects, we either use a cast operator like (Class) or
declare a variable using Generics like:

IntDict isNAMEinsideCLASS(String name, ArrayList<Class> itemList, Class theClass) {

So the Java's compiler knows what's to expect from that List @ itemList.

2)
We can't use variable labels for data-type declarations as you do @ theClass item = itemList.get(i);
Only a class or interface label is valid for declarations. Besides the 8 primitive types of course.

PhiLho

Re: function with name of Class as parameter

1 month ago

As said, you cannot pass a type to a function and declare a variable of this type.
And if get(i) isn't of the type in theClass, then you would get an exception (ClassCastException).
This kind of "dynamic type" programming isn't canonical in Java.

Let's try to do it the Java way, although you don't give the motivation behind your function.
Ah, I have a description of your goal " the goal of it is to search inside the ArrayList if an instance has the name specified in String parameter."

Let's suppose your array list hold objects of various types, but all of them have a name field.
Then, you can declare an interface:

interface HasName
{
String getName();
}

Then, you can make all your classes to implement this interface:

class SomeStuff implements HasName
{
String name;
// Other declarations
// Other methods
// Method imposed by the interface:
public String getName()
{
return name;
}
}

Then, your array list can be declared as follows:

List<HasName> namedStuff = new ArrayList<HasName>();

And your function would look like:

IntDict isNAMEinsideCLASS(String name, ArrayList<HasName> itemList) {
IntDict toReturn = new IntDict();
int nmbInequality = 0;
for (int i= 0; i<itemList.size(); i++) {
HasName item = itemList.get(i);
if (item.getName().equals(name)) {
toReturn.set("true", i);
}
else {
nmbInequality+=1;
}
}
if(nmbInequality == itemList.size()){
toReturn.set("false", -1);
}
return toReturn;
}

Here, you made a super-type which works for all the objects you can put in the list, as long as they all implement the interface.
You can refine the concept by adding a type field, if you need.

PhiLho

Re: function with name of Class as parameter

1 month ago

A concrete illustration. Just for the proof of concept, I added detection of the class of the item to find.

interface HasName
{
String getName();
}
class SomeStuff implements HasName
{
String name;
// Other declarations
SomeStuff(String n) { name = n; }
// Other methods
// Method imposed by the interface:
public String getName()
{
return name;
}
public String toString() { return getClass().getName() + " " + name; }
}
class OtherStuff implements HasName
{
String name;
// Other declarations
OtherStuff(String n) { name = n; }
// Other methods
// Method imposed by the interface:
public String getName()
{
return name;
}
public String toString() { return getClass().getName() + " " + name; }
}
ArrayList<HasName> namedStuff = new ArrayList<HasName>();
int isNAMEinsideCLASS(String name, ArrayList<HasName> itemList, Class kind) {
for (int i = 0; i < itemList.size(); i++) {
HasName item = itemList.get(i);
if (item.getName().equals(name) && item.getClass().equals(kind)) {
return i;
}
}
return -1;
}
void setup()
{
namedStuff.add(new SomeStuff("foo"));
namedStuff.add(new OtherStuff("gah"));
namedStuff.add(new SomeStuff("bar"));
namedStuff.add(new OtherStuff("bu"));
namedStuff.add(new SomeStuff("bu"));
println(namedStuff);
println(isNAMEinsideCLASS("gah", namedStuff, SomeStuff.class));
println(isNAMEinsideCLASS("bu", namedStuff, SomeStuff.class));
println(isNAMEinsideCLASS("bu", namedStuff, OtherStuff.class));
exit();
}

mloizix

Re: function with name of Class as parameter

1 month ago

whow,

thanks a lot.

so I have to learn about interface

by the way :

yes, I've got three ArrayList who hold three different Class.

and I don't manage to answer the question "what's the type of my Class ?"

this is three subclass with their fields & methods, like this example :
http://processing.org/examples/inheritance.html
if you can enlighten me.

and yes, all my Class Object have a name field.

thank you

PhiLho

Re: function with name of Class as parameter

1 month ago

In the change global value with slider thread, I give another explanation about interfaces, if it can help.

I have not understood your last question.

GoToLoop

Re: function with name of Class as parameter

1 month ago

As already mentioned, if you make your classes to inherent from a common 1,
you can put every1 inside a composite, like an Array , ArrayList , HashMap , etc.

From your own link above, there are 3 classes. But 1 of them is the "parent". The other 2 are "children".
I've made some modifications there to better illustrate the technique. Check it out:

final static int NUM = 3;
final Spin[] spins = new Spin[NUM];

void setup() {
  size(600, 400);
  strokeWeight(1);

  // instantiating 1 SpinSpots object into Array
  spins[0] = new SpinSpots(width>>1, height>>1, -.03, 0200);

  // Instantiting 2 SpinArm objects into Array
  spins[1] = new SpinArm(width>>1, height>>1, .01);
  spins[2] = new SpinArm(width>>1, height>>1, -.05);
}

void draw() {
  background(0300);

  // both SpinSpots & SpinArm
  for (Spin spin: spins)  spin.script();
}

abstract class Spin {   // Abstract Parent
  float x, y, speed;
  float angle;

  Spin(float xpos, float ypos, float s) {
    x = xpos;
    y = ypos;
    speed = s;
  }

  void update() {
    angle += speed;
  }

  abstract void display();

  void script() {
    update();
    display();
  }
}

class SpinSpots extends Spin {   // Child A
  int dim;

  SpinSpots(float x, float y, float s, int d) {
    super(x, y, s);
    dim = d;
  }

  void display() {
    noStroke();

    translate(x, y);
    rotate(angle);

    ellipse(-dim>>1, 0, dim, dim);
    ellipse(dim>>1, 0, dim, dim);

    resetMatrix();
  }
}

class SpinArm extends Spin {   // Child B
  SpinArm(float x, float y, float s) {
    super(x, y, s);
  }

  void display() {
    stroke(0);

    translate(x, y);
    rotate(angle);

    line(0, 0, height>>1, 0);

    resetMatrix();
  }
}

mloizix

Re: function with name of Class as parameter

1 month ago

okay, thanks,

just to well understand, my question was :

what is the *type* of an object ?

dimkir

Re: function with name of Class as parameter

1 month ago

Here's example which shows how to extract type name from arbitrary objects. There're actually to ways to represent type as "CanonicalName" and as "SimpleName" (the last one is the one you're used to think of when you make your types, the former is how Java sees class names).

Here's code for the sketch:

void setup(){
// as the sketch is a class itself, let's print it's names.
printTheClassCanonicalName(this);
printTheClassSimpleName(this); // this is also way to figure out name of your sketch.
println();
// now let's make our own class and try to see it's names:
MyClass myClass = new MyClass();
printTheClassCanonicalName(myClass);
printTheClassSimpleName(myClass);
exit();
}
/**
* Just sample class, can be declard here or in
* the separate tab. (In the sep. tab NOT ending with ".java")
*/
class MyClass{
}
void printTheClassCanonicalName(Object obj){
println("Your class canoical name is: " + obj.getClass().getCanonicalName());
}
void printTheClassSimpleName(Object obj){
println("Your class SIMPLE name is: " + obj.getClass().getSimpleName());
}
void draw(){
}

ps. @mloizix, I was wondering if you're familiar with this syntax of Java:

width>>1

or is it the first time you see anything as fancy as << and >> ?

mloizix

Re: function with name of Class as parameter

1 month ago

okay,

yes it's the first time hat I see << or >> in processing code.

thanks

PhiLho

Re: function with name of Class as parameter

1 month ago

" what is the *type* of an object ?"
It is just the class of the object. The type of a string is String, the type of a Processing vector is PVector, of its images is PImage, and so on.

Top Reply