Fractal Conway's Game of Life

General Discussion Other

asimes

Fractal Conway's Game of Life

in General Discussion • Other • 1 year ago

I have been on Fractal Forums quite a bit lately and someone there, Tglad, gave permission to show an idea he's been working on. It is a multilayer Conway's Game of Life with grids of increasing resolution and he's been successful in making fractal-like images with it as well as traveling automaton.

It is still in-the-works as far as rule creation goes. I noticed that Conway's Game of Life sketches appear fairly often on this forum and thought people might be interested in experimenting with the variation, it has shown to make some nice images.

- Information on how to implement it: http://tglad.blogspot.com.au/2012/03/implementing-fractal-automata.html

- The topic I mentioned from their forum: http://www.fractalforums.com/new-theories-and-research/fractal-fire-and-other-fractal-life/

I'm currently working on it myself (getting the parent / child neighbor counting to work is a roadblock at the moment) and will show whatever I can make with it when I'm done.

Replies(5)

asimes

Re: Fractal Conway's Game of Life

1 year ago

I finished writing it if anyone wants to experiment. Please note, I am not 100% sure my parent and child neighbor testing is correct (it is difficult to test).

float livingChance = 0.10;
int depth = 10;
int frame = 1;
boolean[] alive;
int[] cellIndex = new int[depth];
void setup() {
size(1<<depth-1, 1<<depth-1, P2D);
int aliveNum = 0;
for (int i = 0; i < depth; i++) {
aliveNum += (1<<i)*(1<<i);
cellIndex[i] = aliveNum-(1<<i)*(1<<i);
}
alive = new boolean[aliveNum];
initialize();
}
void draw() {
String binFrame = binary(frame);
int position = binFrame.length()-binFrame.lastIndexOf('1')-1;
int layerToUpdate = depth-1-position;
if (layerToUpdate < 0) {
frame = 1;
layerToUpdate = depth-1;
}
updateLayer(layerToUpdate);
display();
frame++;
}
void mousePressed() {
initialize();
}
void initialize() {
for (int i = 0; i < alive.length; i++) alive[i] = random(1) < livingChance;
}
void updateLayer(int layer) {
int numCells = 1<<layer;
boolean[] lives = new boolean[numCells*numCells];
for (int i = 0; i < numCells*numCells; i++) {
int neighbors = 0;
int x = i%numCells;
int y = i/numCells;
// Parent
if (layer > 0 && alive[cellIndex[layer-1]+x/2+y/2*(1<<layer-1)]) neighbors++;
// Siblings
if (y > 0) {
if (x > 0 && alive[cellIndex[layer]+i-numCells-1]) neighbors++;
if (alive[cellIndex[layer]+i-numCells]) neighbors++;
if (x < numCells-1 && alive[cellIndex[layer]+i-numCells+1]) neighbors++;
}
if (x > 0 && alive[cellIndex[layer]+i-1]) neighbors++;
if (alive[cellIndex[layer]+i]) neighbors++; // Self
if (x < numCells-1 && alive[cellIndex[layer]+i+1]) neighbors++;
if (y < numCells-1) {
if (x > 0 && alive[cellIndex[layer]+i+numCells-1]) neighbors++;
if (alive[cellIndex[layer]+i+numCells]) neighbors++;
if (x < numCells-1 && alive[cellIndex[layer]+i+numCells+1]) neighbors++;
}
// Children
if (layer < depth-1) {
if (alive[cellIndex[layer+1]+x*2+y*2*(1<<layer+1)]) neighbors++;
if (alive[cellIndex[layer+1]+x*2+y*2*(1<<layer+1)+1]) neighbors++;
if (alive[cellIndex[layer+1]+x*2+y*2*(1<<layer+1)+(1<<layer+1)]) neighbors++;
if (alive[cellIndex[layer+1]+x*2+y*2*(1<<layer+1)+1+(1<<layer+1)]) neighbors++;
}
// Rules
if (alive[cellIndex[layer]+i]) lives[i] = neighbors == 2 || neighbors == 4;
else lives[i] = neighbors == 3;
}
for (int i = 0; i < numCells*numCells; i++) alive[cellIndex[layer]+i] = lives[i];
}
void display() {
loadPixels();
for (int i = 0; i < width*height; i++) {
if (alive[cellIndex[depth-1]+i]) pixels[i] = 0xff0000;
else pixels[i] = 0;
}
updatePixels();
}

Another stable ruleset:

// Rules
if (alive[cellIndex[layer]+i]) lives[i] = neighbors > 3 && neighbors < 7;
else lives[i] = neighbors == 4;

asimes

Re: Fractal Conway's Game of Life

1 year ago

A test so far:

quarks

Re: Fractal Conway's Game of Life

1 year ago

Thanks for this it's great fun!

Got a nice result with this rule set
    if (alive[cellIndex[layer]+i])
      lives[i] = neighbors > 5 && neighbors < 7 ;
    else
      lives[i] = neighbors == 3 || neighbors == 4;

I have not been able to reproduce tglad's results - do you know what rule set(s) he used?

asimes

Re: Fractal Conway's Game of Life

1 year ago

Not exactly, but one big difference is that he likes to use four parents instead of one. I left one parent in the code above but with my own testing I multiply that only parent by 4. I actually am not exactly sure how to correctly code his method of using four parents (the diagram on his website shows the other three not included in my code). The logic behind multiplying mine by 4 was to make the weight of the parent the same as the children.

asimes

Re: Fractal Conway's Game of Life

1 year ago

Some results: http://alexsimes.com/FractalAutomata/

Also I asked Tglad how he made the fractal like images and he said that is for static images and that it would not work for dynamic ones. His explanation is in the linked topic at the top

Top Reply