for loop question

Programming Questions

chuchuchu

in Programming Questions • 11 months ago

Hello All!

New to programming and Processing so thanks for your patience/help.

Trying to generate 15 squares oscillating with simple harmonic motion but with different periods, each is essentially a pendulum. Here is an example that works by entering the periods of each oscillator manually:

void setup() {
size(800,340);
}

color c = color(255);
float x = 400;

void draw()

{
background(0);
noStroke();
int l = millis();
fill(c);
rectMode(CENTER);
rect( x +( sin((cos((2*(PI*(millis())))/4013))))*300,20,20,20);
/* generates a rect that moves along x axis under simple harmonic motion with period 4013 etc*/
rect( x +( sin((cos((2*(PI*(millis())))/3822))))*300,40,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/3648))))*300,60,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/3489))))*300,80,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/3344))))*300,100,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/3210))))*300,120,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/3086))))*300,140,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/2973))))*300,160,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/2866))))*300,180,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/2768))))*300,200,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/2675))))*300,220,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/2589))))*300,240,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/2508))))*300,260,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/2432))))*300,280,20,20);
rect( x +( sin((cos((2*(PI*(millis())))/2361))))*300,300,20,20);
}

I am trying to do this with a for loop but am only getting the first oscillator:

void setup() {
size(800,340);
}

color c = color(255);

void draw() {
background (0);
noStroke();
fill(c);
for( int i = 0 ; i <= 14 ; i = i + 1 ) {
      float l_1 = 4;
      float x = 350;
      int m = millis();
      float l = l_1 * ( pow ( ( 20 / ( 20 + i )) , 2 ) );
      float t = TWO_PI * sqrt( ( l / 9.80665));
      float tn = t * 1000; // period of ith oscillator in milliseconds
      float p = sin ( ( cos ( ( 2 * ( PI * m ) ) / tn ) ) ); // x position of ith oscillator at millis() with values between +-1
      float pn = x + (p * 300); // centers each oscillator on screen and moves according to p through +-300
      rectMode(CENTER);
      rect( pn , (i + 1) * 20 , 20 , 20 );
}
}

Any ideas? In my head this for loop generates each oscillator with initial coordinates (x = 350, y = (i +1) * 20), where am i going wrong?

Many thanks, processing is Great!

Replies(4)

asimes

Re: for loop question

11 months ago

float x = 400;
int[] harmonicVals = {
4013, 3822, 3648, 3489, 3344, 3210, 3086, 2973, 2866, 2768, 2675, 2589, 2508, 2432, 2361
};
void setup() {
size(800, 340);
noStroke();
rectMode(CENTER);
fill(255);
}
void draw() {
background(0);
/* generates a rect that moves along x axis under simple harmonic motion with period 4013 etc*/
for (int i = 0; i < 15; i++) {
rect( x +( sin((cos((2*(PI*(millis())))/harmonicVals[i]))))*300, i*20+20, 20, 20);
}
}

Edit: I moved some things to setup() as they only need to be called once

GoToLoop

Re: for loop question

11 months ago

Hey! I've found the culprit in the original source!
There is an integer division @ float l = l_1 * ( pow ( ( 20 / ( 20 + i ) ) , 2 ) );
Both operands -> 20 & (20 + i) are integers! So the result is truncated!
Solution is just suffix one of the 20 number literals w/ an F -> float l = l_1 * ( pow ( ( 20f / ( 20 + i ) ) , 2 ) );
This way, we have a floating-point division!

While I was trying to understand your program, I've removed lotsa fat. Check it out:

void setup() {
    size(800, 340);
    rectMode(CENTER);
    noStroke();
    fill(255);
}

void draw() {

    background(0);

    float l, t, p;

    for ( int i=0, x=350, ll=4; i<16; ) {

        l = ll * sq( 20f / (20 + i) );
        t = TWO_PI * sqrt(l / 9.80665f) * 1000;
        p = x + sin( cos(TWO_PI * millis() / t) ) * 300;

        rect( p, ++i*20, 20, 20 );

        println( "i: "+(i-1)+"\t l: "+l+" \t t: "+t+"\t p: "+p );
    }
}

GoToLoop

Re: for loop question

11 months ago

Here's a version which scales up to canvas' dimensions. Also got sp & sz variables to set speed & size respectively:

/*
 Harmonic Oscillating Squares (v1.8)
 by chuchuchu (2012/Nov)
 
 http://forum.processing.org/topic/for-loop-question-18-11-2012
 
 http://studio.processingtogether.com/sp/pad/export/ro.9W9u$FePd6P0W/latest
 */

void setup() {
    
    size(800, 600);
    rectMode(CENTER);
    noStroke();
    fill(255);
    frameRate(50);
}

void draw() {

    background(0);

    float l, t, p;
    byte  sp=4, sz=1;
    int   w=width>>1, h=height/sz, m=millis();

    while (--h > 0) {

        l = sp * sq( sz / float(sz+h) ) / 10;
        t = TWO_PI * sqrt(l) * 1000;
        p = w + sin( cos(TWO_PI * m / t) ) * w;

        rect( p, h*sz, sz, sz );
    }
}

chuchuchu

Re: for loop question

11 months ago

Thanks for your responses!

asimes,

I really wanted to calculate:

int[] harmonicVals = {
4013, 3822, 3648, 3489, 3344, 3210, 3086, 2973, 2866, 2768, 2675, 2589, 2508, 2432, 236
};

inside my for loop, thanks though.

GoToLoop,

Wicked thanks. Think I get the use of float in the first example. But does ++i here:

rect( p, ++i*20, 20, 20 );

Return i+1 and also increase value i for next oscillator/for loop iteration? I don't see i ++ in your for loop definition?

Liking what you've made in the second example, will fiddle around to try understand byte/while and generally what you've come up with. Brilliant!

If you are interested this is all based on an installation we created:

http://youtu.be/FBPEAIjLt38
http://youtu.be/Dye3Mf93T_0

Which is based on 'the pendulum wave experiment'.

Top Reply