Flob with GSVideo?

stralen

in Contributed Library Questions • 2 years ago

Hi,

Im currently working on a system with Ubuntu 10.04 and want to use the flob library to detect gestures. I read up on the forum to find a way to capture video from the webcam (since quicktime dosent run on linux) and found a few links talking of the GSVideo library.

So i installed the lib and made a few changes to the hello_flob example..(changed Capture to GSCapture), but the sketch compiles with an "ArrayIndexOutOfBounds" error for the line

blobs = flob.calc(flob.binarize(video));

The capture window then gives a very garbled output.

Is it an error in the code or flob isnt meant to work with GSVideo? Im very new to Processing so please pardon the ignorance.

Thanks,
Chirag

Replies(1)

andres

Re: Flob with GSVideo?

2 years ago

The main problem was that the resolution in the flob example (128x128) was not supported by GSCapture. The following code worked fine for me (using 320x240 for capture):

import processing.opengl.*;
import codeanticode.gsvideo.*;
import s373.flob.*;

GSCapture video;
Flob flob;
ArrayList blobs;

int tresh = 20;
int fade = 25;
int om = 1;
int videoresw=320;
int videoresh=240;

String info="";
PFont font;
float fps = 60;
int videotex = 3;

void setup() {
size(640, 480, OPENGL);
frameRate(fps);
rectMode(CENTER);
video = new GSCapture(this, videoresw, videoresh, (int)fps);
flob = new Flob(videoresw, videoresh, width, height);

flob.setTresh(tresh);
flob.setSrcImage(videotex);
flob.setImage(videotex);
flob.setBackground(video);
flob.setBlur(0);
flob.setMirror(true,false);
flob.setOm(0);

font = createFont("monaco",9);
textFont(font);
blobs = new ArrayList();
}

void draw() {
if(video.available()) {
     video.read();
     blobs = flob.calc(flob.binarize(video));
}
image(flob.getSrcImage(), 0, 0, width, height);

int numblobs = blobs.size();
for(int i = 0; i < numblobs; i++) {
    ABlob ab = (ABlob)flob.getABlob(i);
    fill(0,0,255,100);
    rect(ab.cx,ab.cy,ab.dimx,ab.dimy);
    fill(0,255,0,200);
    rect(ab.cx,ab.cy, 5, 5);
    info = ""+ab.id+" "+ab.cx+" "+ab.cy;
    text(info,ab.cx,ab.cy+20);
}

fill(255,152,255);
rectMode(CORNER);
rect(5,5,flob.getPresencef()*width,10);
String stats = ""+frameRate+"\nflob.numblobs: "+numblobs+"\nflob.thresh:"+tresh+
    " <t/T>"+"\nflob.fade:"+fade+"   <f/F>"+"\nflob.om:"+flob.getOm()+
    "\nflob.image:"+videotex+"\nflob.presence:"+flob.getPresencef();
fill(0,255,0);
text(stats,5,25);
}