Paint your whole scene on a PGraphics instead of directly on the sketch. Then apply your effect and display the result.

That makes sense, but how does that affect moving "people" and particle effects in the scene?

As I wrote, you have to do all your drawing offline.
Now, that's a bit annoying to prefix all your drawing orders with a PGraphics reference...
So I resurrected an old trick I haven't used in ages (somebody else invented it, can't remember who).
We can temporarily replace the default PGraphics in which Processing do all its drawings with our own. Thus, rect(), ellipse(), etc. go there...
I took an old, simple sketch and applied this technique to illustrate (and test!) it. I even wrapped the substitution trick in a couple of functions to reuse it conveniently to make the mask...
Note that I make the mask once here, as it doesn't change in my case. If you have a moving spotlight, for example, you have to recreate the mask in draw(), instead.
Here is my code:

1. int[] distribution = { 2, 3, 5, 7, 5, 3, 2 };
2. int[] stats = new int[distribution.length];
3. int max;
4. PGraphics og; // Offline graphics
5. PImage maskI;
6.  
7. void setup()
8. {
9.   size(500, 200);
10.   randomSeed(System.nanoTime());
11.   for (int i = 0; i < distribution.length; i++)
12.   {
13.     max += distribution[i];
14.   }
15.  
16.   // Mask works only with P2D
17.   og = createGraphics(width, height, P2D);
18.   makeMask();
19. }
20.  
21. void draw()
22. {
23.   int rnd = 1 + int(random(max));
24.   int total = 0;
25.   int pos = -1;
26.   for (int i = 0; i < distribution.length; i++)
27.   {
28.     total += distribution[i];
29.     if (rnd <= total)
30.     {
31.       pos = i;
32.       break;
33.     }
34.   }
35.   assert pos >= 0;
36.   stats[pos]++;
37.  
38.   // Draw on standard g
39.   background(#EEFFEE);
40.   // Start drawing on offline graphics
41.   beginDrawOn(og);
42.  
43.   // Further drawing go offline
44.   background(255);
45.   int xpos = 20;
46.   for (int i = 0; i < stats.length; i++)
47.   {
48.     fill(100, 255 - i * 20, 128 + i * 20);
49.     rect(xpos, height - stats[i], 50, stats[i]);
50.     xpos += 70;
51.   }
52.  
53.   // Restore normal drawing
54.   endDrawOn();
55.   // Apply the mask on the offline graphics
56.   og.mask(maskI);
57.   // And display it
58.   image(og, 0, 0);
59. }
60.  
61. void makeMask()
62. {
63.   // Mask must be of same size as target image
64.   PGraphics maskG = createGraphics(width, height, JAVA2D);
65.   // Let's reuse my method!
66.   beginDrawOn(maskG);
67.   smooth();
68.   noStroke();
69. //  background(0); // Transparent background
70.   background(20); // Semi-transparent background
71.   fill(255); // Masking drawing
72.   ellipseMode(CENTER);
73.   ellipse(width / 2, height / 2, width - 40, height - 40);
74.   endDrawOn();
75.   // We can mask only with a PImage
76.   maskI = maskG.get(0, 0, width, height);
77. }
78.  
79. PGraphics oldG;
80. void beginDrawOn(PGraphics offlineG)
81. {
82.   oldG = g; // Preserve original
83.   g = offlineG; // Replace it with our graphics
84.   g.beginDraw(); // Still needed in this case
85. }
86. void endDrawOn()
87. {
88.   g.endDraw();
89.   g = oldG; // Restore default
90. }

I put in italics my original code, the one you can replace with your own. I didn't had to change it to make this effect.

The code is at http://bazaar.launchpad.net/~philho/+junk/Processing/files/head:/_QuickExperiments/DistributedRandom/ you can see the history of the sketch to see how I changed it.

Wow that is very clever. I'm slightly stuck though. I'm able to partially make my drawings show up but they are all black and randomly flash their correct colors. Also when I right click to enable the scoped view, the black becomes transparent and some shapes are still visible while others aren't.

I initially used this part to test how it was working and it did work, but I removed it and replaced it with my own drawings and now they aren't being displayed properly.

1. smooth();
2.   noStroke();
3. //  background(0); // Transparent background
4.   background(20); // Semi-transparent background
5.   fill(255); // Masking drawing
6.   ellipseMode(CENTER);
7.   ellipse(width / 2, height / 2, width - 40, height - 40);

I have currently resorted back to making everything in the background offline with the prefix because it is working better. Is it at all possible to make a function for the offline graphics that I am making so I can organize my code a little bit better and not need to to prefix everything with my "createGraphics" name. Also, will it work to have moving things within my offline drawing? Any help is appreciated, thanks!

" Is it at all possible to make a function for the offline graphics that I am making [...] not need to to prefix everything with my "createGraphics" name."
If that's a question, I just shown you how to do this. Works fine for me. I don't know if you fully understood how it works, though, as you wrote you replaced the code you show (which is doing the mask) with your own drawings (a circle?).

" will it work to have moving things within my offline drawing"
Moving things in Processing are just static things changing place between two frames. Again, my sketch shows how moving things are handle with this method.