fisica question: shapes infinitely created in class FContact

Nokjao

fisica question: shapes infinitely created in class FContact

in Contributed Library Questions • 1 year ago

I used the function contactStarted() to add FCircle objects at the point where a glyph "touch" the world's edge or one another. When it does, the FCircle objects keep being created until it crashes, sending message:

AssertionError: Too many pairs (16384 shape AABB overlaps) - this usually means you have too many bodies, or you need to increase Settings.maxPairs.

Here is my code, adapted from Ricard Marxer's Letters and also using the geomerative library to create the fonts. (a .ttf font file is needed in a data folder for it to work and change the name in red according to the font's name.)

I tried to reset the frameCount and hence setting the FCircle objects' lifetime and remove them after but it didn't work.

import fisica.*;
import geomerative.*;
FWorld world;
FChar chr;
FCircle ball;
float posX = 0;
RFont font;
char[] characters;
void setup() {
size(400, 400, JAVA2D);
smooth();
frameRate(60);
Fisica.init(this);
Fisica.setScale(4);
RG.init(this);
RG.setPolygonizer(RG.ADAPTATIVE);
world = new FWorld();
world.setGravity(0, 500);
world.setEdges(this, color(255));
world.remove(world.top);
font = RG.loadFont("LiberationSerif-Bold.ttf");
}
void draw() {
background(255);
fill(0);
stroke(0);
world.draw(this);
world.step();
chr = new FChar(key);
ball = new FCircle(random(2, 20));
ball.setNoStroke();
ball.setFill(random(255), random(255), random(255));
}
void keyPressed() {
if (chr.bodyCreated()) {
world.setEdges(this, color(255));
world.add(chr);
}
if (key == ' ') {
world.clear();
// world.setEdges(this, color(255));
// world.remove(world.top);
posX = 0;
}
}
void contactStarted(FContact contact) {
ball.setPosition(contact.getX(), contact.getY());
if (contact.getBody1() == world.getBody(contact.getX(), contact.getY())) {
world.add(ball);
frameCount = 0;
if (frameCount == 30) {
world.remove(ball);
}
}
}

Replies(6)

ricardmp

Re: fisica question: shapes infinitely created in class FContact

1 year ago

Hi there,

The problem is that every time you create one of those circles it also touches the edge and will then create new circles. This happens recursively.

To avoid this, you may set a group index for the circles and another one for the glyphs. Then check in the contactStarted method that one of the bodies is the edge and that the other body has a group different from the circle's group index.

Your friends are the methods:

FBody.setGroupIndex(int i)

FBody.getGroupIndex()

Nokjao

Re: fisica question: shapes infinitely created in class FContact

1 year ago

Thank you, it's an honor to have you answered my question. By the way, now that you are here. Please bear with me as I shot another question:

What are the differences between the functions contactStarted(), contactPersisted() and contactEnded() and when should one be used?
In class FContactResult, when getNormalImpulse() and getTangentImpulse() are used, what is exactly the unit of the returned float values (or any metric/scale relationship to anything, say, the setScale method)? For instance, if a collision returns a float value of 40.0, how do we make sense of that scale of magnitude?

Thanks in advance,

ricardmp

Re: fisica question: shapes infinitely created in class FContact

1 year ago

What are the differences between the functions contactStarted(), contactPersisted() and contactEnded() and when should one be used?

The contactStarted() gets called at the step when the bodies start a collision.

The contactPersisted() gets called at each step the bodies continue in contact.

The contactEnded() gets called at the step the bodies lose contact.

Well, the when should they be used depends on the task. But for example if you want to launch a sound when two bodies collide, you would do that in contactStarted().

In class FContactResult, when getNormalImpulse() and getTangentImpulse() are used, what is exactly the unit of the returned float values (or any metric/scale relationship to anything, say, the setScale method)? For instance, if a collision returns a float value of 40.0, how do we make sense of that scale of magnitude?

I have updated the documentation in the git repository of fisica.

http://gitorious.org/fisica/fisica/blobs/master/src/fisica/FContactResult.java

Basically the units are those of an impulse (units of a force multiplied by time). Since in Fisica the length units are in pixels, this should be (kg * pixels / s) however I am not sure. I'm simply wrapping around jBox2d here and haven't tested it.

But you must keep in mind that Fisica wraps the old jbox2d and many things have changed in this area since. The branch of Fisica for the new jbox2d is not yet finished and this is one of the things that remain to be done.

Nokjao

Re: fisica question: shapes infinitely created in class FContact

1 year ago

Hi Ricard,

I have come back with another problem! Here I've used groupIndexes and it worked just fine, except that the Fcircle objects were generated only once in contactStarted() and never made it to draw(), so the any other contacts after the first one did not generate any Fcircle objects.

/**
* Falling letters
*
* by Ricard Marxer
*
* This example shows how the use <a href="http://www.ricardmarxer.com/geomerative">Geomerative</a> to access
* the contours of letters and create them as physical objects.
*
* Click on the applet and type!
*/
import fisica.*;
import geomerative.*;
import org.apache.batik.svggen.font.table.*;
import org.apache.batik.svggen.font.*;
FWorld world; // Declare the FWorld object
RFont font; // Declare the Rfont object
float posX = 0; // Declare a variable for the starting position
void setup() {
size(800, 400);
smooth();
frameRate(60);
Fisica.init(this); // The method to start (call) Fisica library
Fisica.setScale(4); // Set scale of the force in Fisica
RG.init(this); // Method to start (call) Geomerative library
RG.setPolygonizer(RG.ADAPTATIVE); // Method to start (call) the Polygonizer
// Setting up the world of Fisica
world = new FWorld(); // Instantiate an FWorld object
world.setGravity(0, 500); // Call setGravity method
world.setEdges(this, color(255)); // Call setEdges method
world.remove(world.top); // Call remove(top edge) method
font = RG.loadFont("LiberationSerif-Bold.ttf"); // Method to "geomeratively" load a true-type font
}
void draw() {
background(255);
fill(0);
stroke(0);
world.draw(this); // Draw the world of Fisica
world.step(); // Advance the world simulation at 1/60th second (very much like frameRate)
}
void keyPressed() {
FChar chr = new FChar(key); // Instantiate a new FChar object (see class FChar)
chr.setGroupIndex(0); // Set the group index to every FChar objects
if (chr.bodyCreated()) {
world.setEdges(this, color(255));
world.add(chr);
}
if (key == ' ') {
world.clear();
world.setEdges(this, color(255));
world.remove(world.top);
posX = 0;
}
if (keyCode == LEFT) {
world.setGravity(-500, 50);
}
else if (keyCode == RIGHT) {
world.setGravity(500, 50);
}
else if (keyCode == UP) {
world.setGravity(0, -500);
}
else if (keyCode == DOWN) {
world.setGravity(0, 500);
}
else {
world.setGravity(0, 500);
}
}
void contactStarted(FContact contact) {
// if ((contact.getBody1().getGroupIndex() == 0) || (contact.getBody1().getGroupIndex() == 1)) {
FCircle ball = new FCircle(random(5, 15)); // Instantiate a new FCircle object
ball.setGroupIndex(1); // Group Index for ball objects
ball.setNoStroke();
ball.setFill(225, 10, 10);
ball.setPosition(contact.getX(), contact.getY());
ball.setVelocity(random(-400, 400), random(-400, 400));
if ((world.getBody(contact.getX(), contact.getY()).getGroupIndex() != 1) ||
((contact.getBody1().getGroupIndex() == 0) && (contact.getBody2().getGroupIndex() == 0))) {
world.add(ball);
}
}

ricardmp

Re: fisica question: shapes infinitely created in class FContact

1 year ago

Several things...

The scale of the Falling letters example is not very usual, make sure it is correct for your current scenario. (Fisica.setScale(4) means that 4pixels = 1meter). I should probably change that in the example.

This means that even for low restitution values the letters will be bouncing continuously and therefore continuously starting contacts with the ground.

If you set the restitution of the two colliding bodies (world.bottom and the FChar) to 0, then you won't get multiple contactStarted() calls, but then the letters won't bounce.

The other part to take into account is that the group indices will only give you a limited amount of control over the collisions.

To have more control, you can use CategoryBits and FilterBits. However this may be a bit more complex to understand. It consists of binary masks encoded in the form of a byte. I added the use of those as a small illustrative example.

In this case the FChars will collide with everything except the balls. And the balls will collide with everything except the FChars.

/**
* Falling letters
*
* by Ricard Marxer
*
* This example shows how the use <a href="http://www.ricardmarxer.com/geomerative">Geomerative</a> to access
* the contours of letters and create them as physical objects.
*
* Click on the applet and type!
*/
import fisica.*;
import geomerative.*;
import org.apache.batik.svggen.font.table.*;
import org.apache.batik.svggen.font.*;
FWorld world; // Declare the FWorld object
RFont font; // Declare the Rfont object
float posX = 0; // Declare a variable for the starting position
void setup() {
size(800, 400);
smooth();
frameRate(60);
Fisica.init(this); // The method to start (call) Fisica library
//Fisica.setScale(4); // Set scale of the force in Fisica
RG.init(this); // Method to start (call) Geomerative library
RG.setPolygonizer(RG.ADAPTATIVE); // Method to start (call) the Polygonizer
// Setting up the world of Fisica
world = new FWorld(); // Instantiate an FWorld object
world.setGravity(0, 500); // Call setGravity method
world.setEdges(this, color(255)); // Call setEdges method
world.remove(world.top); // Call remove(top edge) method
world.bottom.setGroupIndex(2);
world.bottom.setCategoryBits(Integer.parseInt("10000000",2));
world.bottom.setFilterBits(Integer.parseInt("11111111",2));
world.bottom.setRestitution(0.4);
font = RG.loadFont("LiberationSerif-Bold.ttf"); // Method to "geomeratively" load a true-type font
}
void draw() {
background(255);
fill(0);
stroke(0);
world.draw(this); // Draw the world of Fisica
world.step(); // Advance the world simulation at 1/60th second (very much like frameRate)
}
void keyPressed() {
FChar chr = new FChar(key); // Instantiate a new FChar object (see class FChar)
chr.setGroupIndex(0); // Set the group index to every FChar objects
chr.setCategoryBits(Integer.parseInt("01000000",2));
chr.setFilterBits(Integer.parseInt("11011111",2));
chr.setRestitution(0);
if (chr.bodyCreated()) {
world.setEdges(this, color(255));
world.add(chr);
}
if (key == ' ') {
world.clear();
world.setEdges(this, color(255));
world.remove(world.top);
posX = 0;
}
if (keyCode == LEFT) {
world.setGravity(-500, 50);
}
else if (keyCode == RIGHT) {
world.setGravity(500, 50);
}
else if (keyCode == UP) {
world.setGravity(0, -500);
}
else if (keyCode == DOWN) {
world.setGravity(0, 500);
}
else {
world.setGravity(0, 500);
}
}
void contactStarted(FContact contact) {
if (contact.getBody1().getGroupIndex() == 1 || contact.getBody2().getGroupIndex() == 1) {
return;
}
if (contact.getBody1().getGroupIndex() != 2 && contact.getBody2().getGroupIndex() != 2) {
return;
}
// if ((contact.getBody1().getGroupIndex() == 0) || (contact.getBody1().getGroupIndex() == 1)) {
FCircle ball = new FCircle(random(5, 15)); // Instantiate a new FCircle object
ball.setGroupIndex(1); // Group Index for ball objects
ball.setCategoryBits(Integer.parseInt("00100000",2));
ball.setFilterBits(Integer.parseInt("10111111",2));
ball.setNoStroke();
ball.setFill(225, 10, 10);
ball.setPosition(contact.getX(), contact.getY());
ball.setVelocity(random(-400, 400), random(-400, 400));
world.add(ball);
}

Nokjao

Re: fisica question: shapes infinitely created in class FContact

1 year ago

Dear Ricard,

It is kinda cool (though I understand very little about CategoryBits), the way the FCircles stay independent of the FChars. However, I want the letters to produce the FCircle Objects once collided too.

And a side question: I have been having problems with Processing programs I wrote because they use up too much memory and soon start to stagger. In this program of yours, after a few typings, everything slowed down and finally came to crash with the same warning as before:

AssertionError: Too many pairs (16384 shapes AABB overlaps) - this usually means you have too many bodies, or you need to increase Settings.maxPairs.

Could you explain the Settings.maxPairs? Or if I should post it on a different room then please tell me so.

Thanks as always

Top Reply