fisica: FConstantVolumeJoint change volume

ejmoli

fisica: FConstantVolumeJoint change volume

in Contributed Library Questions • 8 months ago

I'm trying to get the volume conserved by FConstantVolumeJoint to change. For example in this openProcessing sketch, the volume is constant. I have been unable to change the volume with any of the built in methods (frequency, damping) or by adding circles to the joint.

Does anybody know how I can:

(a) change the volume at creation?

(b) change the volume interactively (after creation)?

Cheers,

-Evan

Replies(5)

ricardmp

Re: fisica: FConstantVolumeJoint change volume

8 months ago

There is a method for the underlying JBox2D ConstantVolumeJoint named inflate() that allows you to grow or shrink the volume.

As an alternative you can also remove and recreate the volumejoint with the edge bodies "push out" from the center. I post the code here (press keys 'a' and 'b'):

import fisica.*;
import org.jbox2d.dynamics.joints.*;
FWorld world;
FBox caja;
boolean growNow = false;
FConstantVolumeJoint j;
ArrayList<FCircle> edges;
ArrayList<FCircle> circles;
float x, y;
int N = 50;
void setup() {
size(400, 400);
smooth();
Fisica.init(this);
world = new FWorld();
world.setGravity(0, 0);
world.setEdges();
j = new FConstantVolumeJoint();
edges = new ArrayList();
for (int i = 0; i<N; i++) {
FCircle circle = new FCircle(10);
circle.setFill(255, 100, 100);
circle.setPosition(width/2+100*cos(radians(i*360/N)), height/2+100*sin(radians(i*360/N)));
circle.setNoFill();
circle.setNoStroke();
j.addBody(circle);
edges.add(circle);
world.add(circle);
}
j.setNoFill();
j.setStrokeWeight(5);
j.setStroke(255, 0, 50);
world.add(j);
circles = new ArrayList();
for (int i = 0; i<50; i++) {
FCircle c = new FCircle(random(15, 30));
c.setPosition(width/2+random(-50, 50), height/2+random(-50, 50));
c.setFill(100+random(155), 150, random(255));
c.setNoStroke();
circles.add(c);
world.add(c);
}
background(255);
}
void draw() {
background(255);
for (int i = 0; i<circles.size(); i++) {
FCircle c = (FCircle)circles.get(i);
c.addForce(random(-200, 200), random(-200, 200));
}
if (growNow) {
growBlob();
growNow = false;
}
world.step();
world.draw(this);
}
void growBlob() {
PVector c = j.getCentroid();
world.removeJoint(j);
j = new FConstantVolumeJoint();
for (FCircle ci: edges) {
float x = ci.getX();
float y = ci.getY();
ci.setPosition(x + (x-c.x)*0.1, y + (y-c.y)*0.1);
j.addBody(ci);
}
j.setNoFill();
j.setStrokeWeight(5);
j.setStroke(255, 0, 50);
world.addJoint(j);
}
void keyPressed() {
if (key == 'a') {
((ConstantVolumeJoint)j.getBox2dJoint()).inflate(0.9);
} else if(key == 'b') {
((ConstantVolumeJoint)j.getBox2dJoint()).inflate(1.1);
}
else {
try {
saveFrame("screenshot.png");
}
catch (Exception e) {
}
}
}

ejmoli

Re: fisica: FConstantVolumeJoint change volume

7 months ago

Thanks for the reply. I couldn't get the posted code to work because I get an error that reads "j.getCentroid() does not exist".

Any suggestions?

ejmoli

Re: fisica: FConstantVolumeJoint change volume

7 months ago

.... however, the inflate() function on the ConstantVolumeJoint object DOES work. Thanks for that!

Cheers,

-evan

ejmoli

Re: fisica: FConstantVolumeJoint change volume

7 months ago

Sorry to clutter with more questions. In regards to the inflate() function, I can only get this working inside the context of the keyPressed() method. I cannot use the same trick to automatically inflate the ConstantVolumeJoint at, say, the first frame of the sketch without requiring a key prompt. Explicitly...

*********** THIS WORKS**********************

import fisica.*
import org.jbox2d.dynamics.joints.*;
Fworld world;
FConstantVolumeJoint j;
void setup(){
size(300,300);
Fisica.init(this);
world = new FWorld();
j = new FConstantVolumeJoint();
world.add(j);
}
void draw(){
//do stuff
world.step();
world.draw(this);
}
void keyPressed() {
((ConstantVolumeJoint)j.getBox2dJoint()).inflate(1.5);
}

************* THE FOLLOWING DOES NOT WORK ********************

import fisica.*
import org.jbox2d.dynamics.joints.*;
Fworld world;
FConstantVolumeJoint j;
void setup(){
size(300,300);
Fisica.init(this);
world = new FWorld();
j = new FConstantVolumeJoint();
world.add(j);
}
void draw(){
//do stuff
if (frameCount==1){
myInflate(2.0);
}
world.step();
world.draw(this);
}
void myInflate(float ratio) {
((ConstantVolumeJoint)j.getBox2dJoint()).inflate(ratio);
}

The above gives me a nullPointerException.

------

I want to inflate the joint at the first draw, instead of perturbing the joint throughout the sketch. Is there any way of doing this without having to press a key? Why does the same operation work only inside the keyPressed method?

ricardmp

Re: fisica: FConstantVolumeJoint change volume

7 months ago

Yes, that's because myWorld.add(myBody) doesn't add the body immediately, it does so at the next call to step() or draw(). This is done in this way to allow the user to add bodies during events such as contacts etc...

It is easy to work around:

simply change line 10 to

world.addJoint(j);

However keep in mind that you are adding a joint without any bodies, I don't know if this is what you really want to do.

As a sidenote I may change the API of Fisica in the future, so that we have

world.add(myBody); // add the body/joint immediately

and:

world.addLater(myBody); // adds the body/joint at the next step/draw call

Still haven't decided.

Top Reply