Finding Variable in Previous Frame

Programming Questions

Shlosh

Finding Variable in Previous Frame

in Programming Questions • 1 year ago

Hello all.
Just a quick question.
How do you find the value of a variable in the previous frame. Is there any command?
For example :

int a, b;

void setup() {
int a = 0;
}

void draw() {
a += 5;
b = (value of a in previous frame)
}

How would you find b?
If your just using mouse commands you can use pmouse() but how do you do this for created variables?

Replies(5)

amnon.owed

Re: Finding Variable in Previous Frame

1 year ago

You need a variable to store the previous value. You can store the current value for "a" at the end of the frame in another variable (call it b or pa or whatever). Then in the next frame, BEFORE you store the new value, it's still the previous value. If you want to store the 10 last values you could use an array or an arraylist.

Adapted Code

int a, b;
void setup() {
}
void draw() {
a += 5;
// here you have a new a
// but b still holds the previous a value
b = a; // at the end set the current a to be stored in b
}

Shlosh

Re: Finding Variable in Previous Frame

1 year ago

I tired a quick example of this and it didn't work. Slow frame rate shows more detail.

Code

int a, b;
void setup () {
size(600, 600);
a = 0;
b = 0;
frameRate(1);
}
void draw() {
rectMode(CENTER);
noStroke();
a += 100;
if(a > 250) {
a = 0;
}
fill(a);
rect(200, 300, 100, 100);
b = a;
fill(b);
rect(400, 300, 100, 100);
}

**EDIT - You had it in the wrong order.

Fixed Code

int a, b;
void setup () {
size(600, 600);
a = 0;
b = 0;
frameRate(1);
}
void draw() {
rectMode(CENTER);
noStroke();
b = a;
fill(b);
rect(400, 300, 100, 100);
a += 100;
if(a > 250) {
a = 0;
}
fill(a);
rect(200, 300, 100, 100);
}

Thanks for helping.

Shlosh

Re: Finding Variable in Previous Frame

1 year ago

Now if I wanted to get a variable say 10 frames in the past could I do the same thing but make a loop and a Boolean that turned on for one frame every 10 frames?

PhiLho

Re: Finding Variable in Previous Frame

1 year ago

You can use an array, shifting the values when you need to add a new one.
An alternative is to use a specialized collection, I have an old sketch I made to show this feature:

int queueSize = -1;
ArrayDeque lines;
void setup()
{
size(700, 700);
frameRate(40);
lines = new ArrayDeque();
noFill();
ellipseMode(CENTER);
noLoop();
PFont f = createFont("Verdana", 16);
textFont(f);
}
void draw()
{
background(128, 128, 255);
if (queueSize < 0)
{
text("Type a number between 1 and 9", 10, 20);
return;
}
if (mouseX != pmouseX || mouseY != pmouseY)
{
PVector p = new PVector(mouseX, mouseY);
lines.addFirst(p);
}
if (lines.size() > queueSize)
{
lines.removeLast();
}
Iterator it = lines.iterator();
PVector pp = null;
while (it.hasNext())
{
PVector cp = (PVector) it.next();
if (pp != null)
{
stroke(14, 7, 42);
strokeWeight(1);
line(pp.x, pp.y, cp.x, cp.y);
stroke(214, 7, 142);
strokeWeight(5);
ellipse(cp.x, cp.y, 21, 21);
}
pp = cp;
}
}
void keyReleased()
{
int number = key - '0';
if (number > 0)
{
println(number);
queueSize = 10 * number;
loop();
}
}

amnon.owed

Re: Finding Variable in Previous Frame

1 year ago

@ Shlosh: Please read my post again.

In your first code example, you change b to early. You have to store it at the end.

First code

int a, b;
void setup () {
size(600, 600);
frameRate(1);
}
void draw() {
rectMode(CENTER);
noStroke();
a += 100;
if(a > 250) {
a = 0;
}
fill(a);
rect(200, 300, 100, 100);
fill(b);
rect(400, 300, 100, 100);
// this should be at the end
// before this point b is the a from the previous frame
b = a;
}

In your second code example, your fix basically skips b altogether. If you don't need b this is fine, however your question was about storing values from a previous frame.

Second Code

int a;
void setup () {
size(600, 600);
frameRate(1);
}
void draw() {
rectMode(CENTER);
noStroke();
// this is what your second code basically does
// use the a value
fill(a);
rect(400, 300, 100, 100);
a += 100; // change the a value
if(a > 250) {
a = 0;
}
// use the changed a value
fill(a);
rect(200, 300, 100, 100);
}

As mentioned before, you can use an array or arraylist to store multiple previous points. Also see PhiLho's example above.

Code Example

ArrayList <PVector> points = new ArrayList <PVector> ();
void setup() {
size(500, 500);
noStroke();
smooth();
}
void draw() {
background(0);
points.add(new PVector(mouseX, mouseY));
while (points.size () > 100) {
points.remove(0);
}
for (int i=0; i<points.size(); i++) {
PVector p = points.get(i);
fill(255-i*2);
ellipse(p.x, p.y, 5+i/2, 5+i/2);
}
}

Top Reply