Find max of array input from text file?

Programming Questions

list1234

Find max of array input from text file?

in Programming Questions • 1 years ago

Hi I'm very new to processing and for a project in college I need to write a program to plot 'x' and 'y' values inputted from a text file. The values are located in two columns in the text file separated by a tab.This I have achieved but I would like if the plot would automatically adjust its size depending on the max value in the array but i'm having trouble finding the max value in the array. Tried setting up a 2D array and using the max function but did not work. Any help would be greatly appreciated. My code is a s follows.

int i = 0;
int a = 0;
String[] lines;
int index = 0;
void setup()
{
size(1000, 600);
//sets background white
background(255, 255, 255);
frameRate(150);
lines = loadStrings("sinewave.txt");
// writes text to display
fill(0, 0, 0);
textSize(14);
String s = "TIME / (seconds)";
text(s, 500, 510, 150, 50);
String s_1 = "VOLTAGE / (volts)";
text(s_1, 15, 250, 100, 50);
}
void draw()
{
if (index+1 < lines.length)
{
String[] pieces = split(lines[index], '\t');
String[] pieces_1 = split(lines[index+1], '\t');
if (pieces.length == 2)
{
int x = int(pieces[0]);
int y = int(pieces[1]);
int a = int(pieces_1[0]);
int b = int(pieces_1[1]);
stroke(255, 0, 0);
line(x+120, 500-y, a+120, 500-b);
stroke(0, 0, 255);
ellipse(x+120, 500-y, 5, 5);
stroke(0, 0, 0);
String[][] s = (lines);
int q = max(s);
strokeWeight(1);
beginShape(POINTS);
// Horizontal gridlines dark
for (i = 120; i<x+140; i+=2)
for ( a = 80; a<500; a+=40)
{
strokeWeight(2);
vertex(i, 20+a);
strokeWeight(1);
}
// Vertical gridlines dark
for (i = 100; i<500; i+=2)
for ( a = 100; a<520-y; a+=40)
{
strokeWeight(2);
vertex(20+a, i);
strokeWeight(1);
}
stroke(204, 204, 204);
// Horizontal gridlines
for (i = 120; i<x+140; i+=2)
for (a = 80; a<480; a+=20)
{
vertex(i, 20+a);
}
// Vertical gridlines
for (i = 100; i<500; i+=2)
for ( a = 120; a<500-y; a+=20)
{
vertex(20+a, i);
}
stroke(0, 0, 0);
endShape();
//sets thickness of lines
strokeWeight(5);
line(120, 100, 120, 500);
line(120, 500, 520-y, 500);
strokeWeight(1);
}
// Go to the next line for the next run through draw()
index = index + 1;
}
}

Replies(5)

jbum

Re: Find max of array input from text file?

1 years ago

Could you send a link to (or insert a sample of) your sinewaves.txt file?

list1234

Re: Find max of array input from text file?

1 years ago

The end goal is for sine wave values but as a start any values of a line is great. So started with values of a linear line e.g.

0 0

10 10

20 20

30 30

40 40

50 50

60 60

70 70

80 80

90 90

100 100

110 110

120 120

130 130

140 140

150 150

160 160

170 170

180 180

190 190

200 200

jbum

Re: Find max of array input from text file?

1 years ago

This will get you closer.

1) Added some globals to represent graph dimensions.

2) Added dedicated function for drawing dotted lines.

3) Computing min/max values for both axes.

4) Moved axis drawing code to setup() since it only needs to happen once, the way your code is currently

structured.

5) Your code has an artifact which is that the line quickly animates as it draws. If you don't care about that, the resulting code would be a bit simpler (you can move most of the code to draw, and clear the background, and use a loop to draw the data).

To compute a data point's coordinates, use:

float px = map(x, xMin, xMax, leftMargin, rightMargin);

float py = map(y, yMin, yMax, botMargin, topMargin);

String[] lines;
// Added these variables for controling size of graph
int leftMargin = 120;
int topMargin = 100;
int botMargin;
int rightMargin;
int graphWidth;
int graphHeight;
float yMin, yMax, xMin, xMax;
int xMajorGrid = 50; // expressed in graph units (not pixels)
int xMinorGrid = 25;
int yMajorGrid = 50;
int yMinorGrid = 25;
int lastX, lastY;
int index = 0;
void setup()
{
size(1000, 600);
graphWidth = width-leftMargin*2;
graphHeight = height-topMargin*2;
botMargin = height-topMargin;
rightMargin = width-leftMargin;
//sets background white
background(255, 255, 255);
frameRate(150);
lines = loadStrings("sinewave.txt");
// writes text to display
fill(0, 0, 0);
textSize(14);
String s = "TIME / (seconds)";
text(s, 500, 510, 150, 50);
String s_1 = "VOLTAGE / (volts)";
text(s_1, 15, 250, 100, 50);
// Compute maximum and minimum
yMax = 0;
yMin = 1000000;
xMax = 0;
xMin = 1000000;
for (int i =0 ; i < lines.length; ++i) {
String[] pieces = split(lines[i], '\t');
xMax = max(xMax, int(pieces[0]));
xMin = min(xMin, int(pieces[0]));
yMax = max(yMax, int(pieces[1]));
yMin = min(yMin, int(pieces[1]));
}
// optional - add a little breathing room
yMax *= 1.1;
xMax *= 1.1;
println("X = " + xMin + " --> " + xMax);
println("Y = " + yMin + " --> " + yMax);
// Note: The gridline code will currently be misaligned if you have negative values in your data...
// It assumes yMin/xMin are zero.
// Draw minor grid lines here...
stroke(204, 204, 204);
for (float i = yMin; i < yMax; i += yMinorGrid) { // i is in graph units, not pixels
float px1 = leftMargin;
float px2 = rightMargin;
float py = map(i,yMin,yMax,botMargin,topMargin);
dottedLine(px1,py, px2,py);
}
for (float i = xMin; i < xMax; i += xMinorGrid) { // i is in graph units, not pixels
float py1 = topMargin;
float py2 = botMargin;
float px = map(i,xMin,xMax,leftMargin,rightMargin);
dottedLine(px,py1, px,py2);
}
// Major grid lines
strokeWeight(2);
for (float i = yMin; i < yMax; i += yMajorGrid) { // i is in graph units, not pixels
float px1 = leftMargin;
float px2 = rightMargin;
float py = map(i,yMin,yMax,botMargin,topMargin);
line(px1,py, px2,py);
}
for (float i = xMin; i < xMax; i += xMajorGrid) { // i is in graph units, not pixels
float py1 = topMargin;
float py2 = botMargin;
float px = map(i,xMin,xMax,leftMargin,rightMargin);
line(px,py1, px,py2);
}
// Major Axes
stroke(0);
strokeWeight(5);
float px = map(0,xMin,xMax,leftMargin,rightMargin);
float py = map(0,yMin,yMax,botMargin,topMargin);
line(px, py, px+graphWidth, py);
line(px, py, px, py-graphHeight);
strokeWeight(1);
}
void dottedLine(float x1, float y1, float x2, float y2)
{
float dst = sqrt(sq(x2-x1)+sq(y2-y1));
float ang = atan2(y2-y1,x2-x1);
int dotDist = 5;
int nbrDots = round(dst / dotDist);
float dx = cos(ang)*dotDist;
float dy = sin(ang)*dotDist;
strokeWeight(2);
for (int i = 0; i < nbrDots; ++i) {
float px = x1 +dx*i;
float py = y1 +dy*i;
point(px,py);
}
strokeWeight(1);
}
void draw()
{
if (index < lines.length)
{
String[] pieces = split(lines[index], '\t');
if (pieces.length == 2)
{
int x = int(pieces[0]);
int y = int(pieces[1]);
// Convert to pixels
float px = map(x, xMin, xMax, leftMargin, rightMargin);
float py = map(y, yMin, yMax, botMargin, topMargin);
float px2 = map(lastX, xMin, xMax, leftMargin, rightMargin);
float py2 = map(lastY, yMin, yMax, botMargin, topMargin);
if (index > 0) {
stroke(255, 0, 0);
line(px, py, px2, py2);
}
lastX = x;
lastY = y;
stroke(0, 0, 255);
ellipse(px, py, 5, 5);
}
// Go to the next line for the next run through draw()
index = index + 1;
}
}

list1234

Re: Find max of array input from text file?

1 years ago

Thanks for all your help and your very quick response that was a great help.

As I said I'm very new to processing so just trying to fully understand all the functions now. Also yes I would prefer if the line didn't animate itself when the program runs. Are you saying to achieve this I just all I need to do is move the relevant code to draw? Sorry I'm not sure what exactly you mean.

Again thanks for all the help hopefully be able to achieve my goal of drawing a sinewave now and adding dimensions to the plot.

jbum

Re: Find max of array input from text file?

1 years ago

I meant that instead of using a global 'index' variable, which counts up during each frame of the animation, you put a loop in your draw method that draws each point. Here's what it looks like.

String[] lines;
// Added these variables for controling size of graph
int leftMargin = 120;
int topMargin = 100;
int botMargin;
int rightMargin;
int graphWidth;
int graphHeight;
float yMin, yMax, xMin, xMax;
int xMajorGrid = 50; // expressed in graph units (not pixels)
int xMinorGrid = 25;
int yMajorGrid = 50;
int yMinorGrid = 25;
void setup()
{
size(1000, 600);
graphWidth = width-leftMargin*2;
graphHeight = height-topMargin*2;
botMargin = height-topMargin;
rightMargin = width-leftMargin;
//sets background white
background(255, 255, 255);
frameRate(150);
lines = loadStrings("sinewave.txt");
// writes text to display
fill(0, 0, 0);
textSize(14);
String s = "TIME / (seconds)";
text(s, 500, 510, 150, 50);
String s_1 = "VOLTAGE / (volts)";
text(s_1, 15, 250, 100, 50);
// Compute maximum and minimum
yMax = 0;
yMin = 1000000;
xMax = 0;
xMin = 1000000;
for (int i =0 ; i < lines.length; ++i) {
String[] pieces = split(lines[i], '\t');
xMax = max(xMax, int(pieces[0]));
xMin = min(xMin, int(pieces[0]));
yMax = max(yMax, int(pieces[1]));
yMin = min(yMin, int(pieces[1]));
}
// optional - add a little breathing room
yMax *= 1.1;
xMax *= 1.1;
println("X = " + xMin + " --> " + xMax);
println("Y = " + yMin + " --> " + yMax);
noLoop(); // turned off looping since this doesn't animate
}
void dottedLine(float x1, float y1, float x2, float y2)
{
float dst = sqrt(sq(x2-x1)+sq(y2-y1));
float ang = atan2(y2-y1,x2-x1);
int dotDist = 5;
int nbrDots = round(dst / dotDist);
float dx = cos(ang)*dotDist;
float dy = sin(ang)*dotDist;
strokeWeight(2);
for (int i = 0; i < nbrDots; ++i) {
float px = x1 +dx*i;
float py = y1 +dy*i;
point(px,py);
}
strokeWeight(1);
}
void draw()
{
// Draw minor grid lines here...
stroke(204, 204, 204);
for (float i = yMin; i < yMax; i += yMinorGrid) { // i is in graph units, not pixels
float px1 = leftMargin;
float px2 = rightMargin;
float py = map(i,yMin,yMax,botMargin,topMargin);
dottedLine(px1,py, px2,py);
}
for (float i = xMin; i < xMax; i += xMinorGrid) { // i is in graph units, not pixels
float py1 = topMargin;
float py2 = botMargin;
float px = map(i,xMin,xMax,leftMargin,rightMargin);
dottedLine(px,py1, px,py2);
}
// Major grid lines
strokeWeight(2);
for (float i = yMin; i < yMax; i += yMajorGrid) { // i is in graph units, not pixels
float px1 = leftMargin;
float px2 = rightMargin;
float py = map(i,yMin,yMax,botMargin,topMargin);
line(px1,py, px2,py);
}
for (float i = xMin; i < xMax; i += xMajorGrid) { // i is in graph units, not pixels
float py1 = topMargin;
float py2 = botMargin;
float px = map(i,xMin,xMax,leftMargin,rightMargin);
line(px,py1, px,py2);
}
// Major Axes
{
stroke(0);
strokeWeight(5);
float px = map(0,xMin,xMax,leftMargin,rightMargin);
float py = map(0,yMin,yMax,botMargin,topMargin);
line(px, py, px+graphWidth, py);
line(px, py, px, py-graphHeight);
strokeWeight(1);
}
int lastX = -1;
int lastY = -1;
for (int i = 0; i < lines.length; ++i) {
String[] pieces = split(lines[i], '\t');
if (pieces.length == 2)
{
int x = int(pieces[0]);
int y = int(pieces[1]);
// Convert to pixels
float px = map(x, xMin, xMax, leftMargin, rightMargin);
float py = map(y, yMin, yMax, botMargin, topMargin);
float px2 = map(lastX, xMin, xMax, leftMargin, rightMargin);
float py2 = map(lastY, yMin, yMax, botMargin, topMargin);
lastX = x;
lastY = y;
if (i > 0) {
stroke(255, 0, 0);
line(px, py, px2, py2);
}
stroke(0, 0, 255);
ellipse(px, py, 5, 5);
}
// Go to the next line for the next run through draw()
}
}

Top Reply