Extract circle texture from background with alpha channel

Programming Questions

potter3366

Extract circle texture from background with alpha channel

in Programming Questions • 1 year ago

With this code I get on the edge black ring and all black pixels inside the circle are coverted to transparent..

Help me improve this code..

PGraphics pgTexture, pgMask, pgShape, savearea;
color pix;
int i;

void setup()
{
size(800, 500);
PImage img = loadImage("800x500.jpg");

pgMask = createGraphics(width, height, JAVA2D);
pgShape = createGraphics(width, height, P2D);
savearea = createGraphics(100, 100, JAVA2D);
pgTexture = createGraphics(width, height, JAVA2D);
pgTexture.beginDraw();
pgTexture.image(img, 0, 0);
pgTexture.endDraw();
}

void draw()
{
background(0);
DrawTextured();
}

void DrawTextured()
{
pgMask.background(0);
pgMask.fill(255);
pgMask.noStroke();
DrawCircle(pgMask);
PImage piMask = pgMask.get(0, 0, width, height);

pgShape.image(pgTexture, 0, 0);
pgShape.mask(piMask);

image(pgShape, 0, 0);

println(frameRate);

}

void DrawCircle(PGraphics g)
{
g.beginDraw();
g.smooth();
g.noStroke();
g.ellipse(mouseX, mouseY, 100, 100);
g.endDraw();
}

void mousePressed() {
savearea.set(0, 0, get(mouseX-50, mouseY-50, 100, 100));

savearea.loadPixels();
for (int x=0; x < 100; x++) {
    for (int y=0; y < 100; y++) {
      i = ((y * 100) + x);
      pix = savearea.pixels[i];
      if(pix == color(0, 0, 0)) savearea.pixels[i] = color(0, 0, 0, 0);
    }
}
savearea.updatePixels();

savearea.save("data/circleHole.png");
}

Replies(8)

PhiLho

Re: Extract circle texture from background with alpha channel

1 year ago

You describe what you have, but not what you want to have. What is your problem, exactly?

potter3366

Re: Extract circle texture from background with alpha channel

1 year ago

...find a better solution..What I need is 100x100 circle texture with transparent pixels outside the circle. .

Mouse position is center of texture.

potter3366

Re: Extract circle texture from background with alpha channel

1 year ago

background image

amnon.owed

Re: Extract circle texture from background with alpha channel

1 year ago

How about this?

The radius sets the dimensions of the circle & capture area. The feather smooths out the circle edges.

Code Example

PImage img = loadImage("http://3.bp.blogspot.com/_h-VQUQIOpeY/THnFlItz5PI/AAAAAAAAAEA/t9Fer-NN588/s1600/ocean-wallpaper-4.jpg");
PImage saveArea;
int radius = 50; // radius of the ellipse
int feather = 2; // smooth transition between opaque & transparent
void setup() {
size(img.width, img.height);
smooth();
stroke(255);
noFill();
}
void draw() {
background(0);
image(img, 0, 0);
saveEllipse(radius, feather);
image(saveArea, 10, 10);
ellipse(mouseX, mouseY, radius*2, radius*2);
}
void mousePressed() {
saveArea.save("data/circle.png");
}
void saveEllipse(int radius, int feather) {
int getX = constrain(mouseX, radius, width-radius);
int getY = constrain(mouseY, radius, height-radius);
PImage temp = img.get(getX-radius, getY-radius, radius*2, radius*2);
saveArea = createImage(temp.width, temp.height, ARGB);
for (int y=0; y<saveArea.height; y++) {
for (int x=0; x<saveArea.width; x++) {
int index = y + x * saveArea.width;
float d = dist(x, y, radius, radius);
if (d > radius) {
saveArea.pixels[index] = 0;
} else if (d >= radius-feather) {
color c = temp.pixels[index];
int r = (c >> 16)&0xff;
int g = (c >> 8)&0xff;
int b = (c)&0xff;
c = color(r, g, b, map(d, radius-feather, radius, 255, 0));
saveArea.pixels[index] = c;
} else {
saveArea.pixels[index] = temp.pixels[index];
}
}
}
saveArea.updatePixels();
}

potter3366

Re: Extract circle texture from background with alpha channel

1 year ago

Perfect! Thanks!

potter3366

Re: Extract circle texture from background with alpha channel

1 year ago

Amnon, how to rotate texture around its center immediately in your code??

I have tried but getting jagged edge texture..

PGraphics pg;
PImage img;

void setup()
{
size(100,100);
pg = createGraphics(100, 100, JAVA2D);
img=loadImage("circle.png");
}

void draw()
{
pg.imageMode(CENTER);
pg.beginDraw();
pg.background(255, 0);
pg.translate(50, 50);
pg.rotate(PI/3);
pg.image(img, 0, 0);
pg.endDraw();
}

void mousePressed() {
pg.save("data/circle1.png");
}

amnon.owed

Re: Extract circle texture from background with alpha channel

1 year ago

The quick-and-easy route would be to draw the rotated image to a PGraphics.

See the following example. The last parameter in the saveEllipse() function is the rotation in degrees (0-360).

Code Example

PImage img = loadImage("http://3.bp.blogspot.com/_h-VQUQIOpeY/THnFlItz5PI/AAAAAAAAAEA/t9Fer-NN588/s1600/ocean-wallpaper-4.jpg");
PImage saveArea;
int radius = 50; // radius of the ellipse
int feather = 2; // smooth transition between opaque & transparent
void setup() {
size(img.width, img.height);
smooth();
stroke(255);
noFill();
}
void draw() {
background(0);
image(img, 0, 0);
saveEllipse(radius, feather, frameCount);
image(saveArea, 10, 10);
ellipse(mouseX, mouseY, radius*2, radius*2);
}
void mousePressed() {
saveArea.save("data/circle.png");
}
void saveEllipse(int radius, int feather, int deg) {
int getX = constrain(mouseX, radius, width-radius);
int getY = constrain(mouseY, radius, height-radius);
PImage getImage = img.get(getX-radius, getY-radius, radius*2, radius*2);
PGraphics temp = createGraphics(getImage.width, getImage.height, JAVA2D);
temp.beginDraw();
temp.smooth();
temp.translate(temp.width/2, temp.height/2);
temp.imageMode(CENTER);
temp.rotate(radians(deg)); // degrees to radians
temp.image(getImage, 0, 0);
temp.endDraw();
saveArea = createImage(temp.width, temp.height, ARGB);
for (int y=0; y<saveArea.height; y++) {
for (int x=0; x<saveArea.width; x++) {
int index = y + x * saveArea.width;
float d = dist(x, y, radius, radius);
if (d > radius) {
saveArea.pixels[index] = 0;
} else if (d >= radius-feather) {
color c = temp.pixels[index];
int r = (c >> 16)&0xff;
int g = (c >> 8)&0xff;
int b = (c)&0xff;
c = color(r, g, b, map(d, radius-feather, radius, 255, 0));
saveArea.pixels[index] = c;
} else {
saveArea.pixels[index] = temp.pixels[index];
}
}
}
saveArea.updatePixels();
}

potter3366

Re: Extract circle texture from background with alpha channel

1 year ago

Excellent !!!