Emergent pattern A.K.A. how to spy on your neighbor

Programming Questions

sanspot

Emergent pattern A.K.A. how to spy on your neighbor

in Programming Questions • 2 years ago

Hi all!

I've been working on this project for a while now after I read a book called Emergence: The Connected Lives of Ants, Brains, Cities, and Software... Super cool text...
Without going too much in details I want to create a series of identical objects that behave following few simple rules, while interacting with each other...A sort of interconnected frame of objs that observe and react on each other...To make the idea more clear I made a small viz of the logic behind the code...check the png i posted here...
If you look at my coding you'll see that I:
1) created an array of objects called lampList
2) told to two of them to Display(): this means thy will simply see the dist() btw center & mouseX/Y and use that to determine the transparency.
3)assigned the third obj the doOpposite(): it will see what is the condition of the first obj and do the opposite!

The thing I can't seem to do is apply the same three behavior to ALL obj! All object should be able to:
1)read the distance to the mouseX/Y and behave consequently
2)see what is the closest obj doing, and do the opposite

I added some more comment to the coding to explain what I'm doing...

int lastMove;
float stealTransp;
float scaleRange = 255;
float diff;
ArrayList <Lamp> lampList;

void setup() {
  size(800, 600);
  smooth();

  //create the arrayList and create 3 Lamp OBJ...
  lampList = new ArrayList();
  lampList.add(new Lamp(200,150));
  lampList.add(new Lamp(500,300));
  lampList.add(new Lamp(300,350));
}

void draw() {
  background(0);
  //apply behaviours to each array obj
  for(int i=0;i<lampList.size();i++) {
   lampList.get(0).display();
   lampList.get(2).display();
   lampList.get(1).doOpposite();
  }

}

void mouseMoved() {
  lastMove = millis();
}

class Lamp {
  float x;
  float y;
  int ellipseWidth;
  float transp;
  color c;

  Lamp(float tempx, float tempy) {
   x = tempx;
   y = tempy;
   ellipseWidth = 50;
   c = color(random(255),random(255),random(255));
  }

  void display() {
   ellipseMode(CENTER);
   /* here is the trick! calculate the dist between center of the obj
   and mouse X & Y. costrain the values between 0 and 250 and send it to
   the fill() */
   transp = dist(x, y, mouseX, mouseY);
   transp = constrain(transp,0,255);
   fill (c,transp);
   ellipse(x, y, ellipseWidth, ellipseWidth);
  }

   void doOpposite() {
   /* here is the first probem which is that I managed to only follow a specific
   obj, and not the closest...So here I tell the second to check the first */
   stealTransp = lampList.get(0).transp;
   diff = scaleRange - stealTransp;
   ellipseMode(CENTER);
   fill (c, diff);
   ellipse(x, y, ellipseWidth, ellipseWidth);
   }

  }

Hopefully if all works, strange cool things should happen...

Replies(7)

quarks

Re: Emergent pattern A.K.A. how to spy on your neighbor

2 years ago

If I can just clarify the situtaion, the algorithm you want is

for each lamp calculate the distance from the mouse and use this to assign a value for the transparnecy
for each lamp calculate the nearest lamp - then get the transparency for that lamp and apply the opposite transparency
display each lamp (currently you are only displaying 2)

Is this correct?
Will the positions of the lamps change or are they fixed? (If fixed we only need to calculate the nearest lamp once and store the result in the lamp class, otherwise we need to calculate it every frame.)

Need to know the answers to create the appropriate algorithm.

sanspot

Re: Re: Emergent pattern A.K.A. how to spy on your neighbor

2 years ago

for each lamp calculate the distance from the mouse and use this to assign a value for the transparnecy

for each lamp calculate the nearest lamp - then get the transparency for that lamp and apply the opposite transparency

display each lamp (currently you are only displaying 2

yes that is the case.

and the position are now fixed for it's easy for me to understand where the neighbor is...Ideally each Lamp OBJ should be able to understand that on their own...

quarks

Re: Emergent pattern A.K.A. how to spy on your neighbor

2 years ago

Hope you don't mind I had a go at the problem myself and this is what I came up with.

int lastMove;
float stealTransp;
float scaleRange = 255;
float diff;
ArrayList <Lamp> lampList;
void setup() {
size(800, 600);
smooth();
//create the arrayList and create 3 Lamp OBJ...
lampList = new ArrayList();
lampList.add(new Lamp(200,150));
lampList.add(new Lamp(500,300));
lampList.add(new Lamp(300,350));
}
void draw() {
background(0);
//apply behaviours to each array obj
calculateNearest();
actOnNearest();
for(int i=0;i<lampList.size();i++) {
lampList.get(i).display();
}
}
void calculateNearest() {
Lamp a, b;
float d, minD;
for(int i = 0; i < lampList.size(); i++) {
a = lampList.get(i);
minD = Float.MAX_VALUE;
for(int j = 0; j < lampList.size(); j++) {
if(i != j) {
b = lampList.get(j);
d = dist(a.x, a.y, b.x, b.y);
if(d < minD){
d = minD;
a.nearest = j;
}
}
}
}
}
void actOnNearest(){
Lamp a;
for(int i = 0; i < lampList.size(); i++) {
a = lampList.get(i);
a.transp = 255 - lampList.get(a.nearest).transp;
}
}
void mouseMoved() {
lastMove = millis();
}
class Lamp {
float x;
float y;
int ellipseWidth;
float transp;
color c;
int nearest;
Lamp(float tempx, float tempy) {
x = tempx;
y = tempy;
ellipseWidth = 50;
c = color(random(255),random(255),random(255));
}
void display() {
ellipseMode(CENTER);
/* here is the trick! calculate the dist between center of the obj
and mouse X & Y. costrain the values between 0 and 250 and send it to
the fill() */
transp = dist(x, y, mouseX, mouseY);
transp = 250 - constrain(transp,0,250);
fill (c,transp);
ellipse(x, y, ellipseWidth, ellipseWidth);
}
}

Notes:
The method calculateNearest calculates the nearest lamp to lamp a and stores the result in lamp a
The second method actOnNearest then uses this to do the opposite.

I have removed the doOpposite method from Lamp because it is not good practice for class methods to directly access variables outside the class i.e. lampList

HTH

sanspot

Re: Re: Emergent pattern A.K.A. how to spy on your neighbor

2 years ago

it works fine and smoothly (also it look cleaner than my coding!)

Anyway I'd like to ask a thing or two about it....1st why isn't it good for classes to get data out of external variables?

Second question is about this:

if(i != j) {
b = lampList.get(j);
d = dist(a.x, a.y, b.x, b.y);
if(d < minD){
d = minD;
a.nearest = j

You crossed referenced the lamp objects using the for structure: it will find the first object (for(int i=0; i<lampList.size; i++) then with the same method find the second and the third and so on (for(int j=0; j<lampList.size; j++). So now it will compare the first object to the second and the third, the second with the first and the third and so on.... then calculating the distance between the x and y of both new OBJ A and B (which are the objects in the lampList)....

Finally you go into a if structure for which if the distance is minor of minD (which I don't get what it is, as you stated it before as a float but for what???) then you reset the d the MAX_value and then?????

Sorry to ask...

I grasp the logic more or less but the technicality are a bit hard to fully understand...My coding knowledge is not that developed...

I'll read it again and again until i get it 100%

Thanks again

quarks

Re: Emergent pattern A.K.A. how to spy on your neighbor

2 years ago

There is a mistake in my code line 37 should be
minD = d;
not the other way round.

To answer the second part of your last post it would be good to examine what is actaully happening in the calculateNearest method

void calculateNearest() {
Lamp a, b;
float d, minD;
for(int i = 0; i < lampList.size(); i++) { // loop through each lamp
a = lampList.get(i); // get lamp at position i
minD = Float.MAX_VALUE; // Maximise the value in minD
for(int j = 0; j < lampList.size(); j++) { // loop through each lamp
if(i != j) { // Ignore if they are the same
b = lampList.get(j); // get lamp at position j
d = dist(a.x, a.y, b.x, b.y); // calc the distance between them
if(d < minD){ // if smallest distance so far
minD = d; // remember smallest dist so far
a.nearest = j; // remember nearest lamp to a
}
}
}
}
}

I have added comments which should make it clearer.

minD is simply used to store the smallest distance found so far so we always initialise it to a very large number to ensure we find a smaller value, if we started with minD = 0 we would not find a nearer lamp.Then a.nearest is updated whenever we find find a nearer lamp. By the time the method is finished each lamp is aware of its nearest neighbour.

why isn't it good for classes to get data out of external variables?

You have probably heard the term object orietation, it is probably the most common programming paradigm in use since there are many OO languages e.g. Java, C++, C# etc.

The building block of OO is the class structure and the primary purposes of the class structure is to create reuseable/ autonomous objects. That means that the methods (functions) in a class should ONLY access fields/attributes defined in the class or any parameters passed to them. The class can then be reused in any other program that needs it because its code is independant of anything outside the class.

In your class you use the global variable lampList so the class could not be reused in another program.

Processing which is written using Java and has hundreds of classes. A realy useful one is PVector which is used to hold x/y/z coordinates. A very common requirement.

HTH

sanspot

Re: Re: Emergent pattern A.K.A. how to spy on your neighbor

2 years ago

First of all thanks for you patience in explaining me what you did exactly...I spend half an hour with pen and paper to understand how the coding was behaving...I literally translated the calculation taking in place on paper..A sort of Human Calculator!

Anyway I understand how it is proceeding now, though I have one small thing more to ask about the minD.

When you first declare it (minD=Float.MAX_VALUE;) what value does it starts from?...Logically it is not 0 and I never saw that syntax before (capital F for Float? what is the default Max_value?)...

thank you again so much...

quarks

Re: Emergent pattern A.K.A. how to spy on your neighbor

2 years ago

Float.MAX_VALUE is a constant declared by Java and is the largest positive value that can be stored in a variable of type float see here

Java provides classes that 'wrap' up the primitive data types

primitive      class
float                      Float
int -                   Integer
double -             Double
etc.

Top Reply