Elliptical Orbit

Programming Questions

atezun

in Programming Questions • 1 year ago

I'm trying to make a small solar system. I've made some planets and moons that are on a circular rotational orbit using translate() and rotate(). I'm looking to add a small comet that moves along an ellipitical orbit. I know that rotate won't work for this, but I'm not sure where to go from there.

float SunDiam = 80;
float VenusDiam = 24;
float VenusOrbitRadius = 120;
float VenusAngle = 0;
float EarthDiam = 30;
float EarthOrbitRadius = 200;
float EarthAngle = 0;
float MoonDiam = 6;
float MoonOrbitRadius = 26;
float MoonAngle = 0;
void setup() {
size(1024,768);
frameRate(30);
}
void draw() {
background(0,0,0); // inky blackness of space
translate(width/2,height/2); // move origin to the center of the screen
noStroke();
fill(255,200,64); // yellow-orange
ellipse(0,0,SunDiam,SunDiam); // the mighty Sun
// save the solar system
pushMatrix();
// rotate Venus around the sun
rotate(VenusAngle);
// move out to Venus orbit
translate(VenusOrbitRadius,0);
fill(155,135,95);
ellipse(0,0,VenusDiam,VenusDiam);
// return to the sun
popMatrix();
// rotate around the sun
rotate(EarthAngle);
// move out to Earth orbit
translate(EarthOrbitRadius, 0);
fill(64,64,255); // blue-ish
ellipse(0,0,EarthDiam,EarthDiam); // the noble Earth
// rotate around the Earth
rotate(MoonAngle);
// hove out to Moon orbit
translate(MoonOrbitRadius,0);
fill(192,192,180); //grayish
ellipse(0,0,MoonDiam,MoonDiam); // the friendly Moon
VenusAngle += 0.008;
EarthAngle += 0.005;
MoonAngle += 0.02;
}

Replies(5)

nardove

Re: Elliptical Orbit

1 year ago

Here is a simple example of elliptical orbit:

float poX, posY;
float radiusX, radiusY;
float theta;
void setup() {
size( 200, 200 );
posX = posY = 0;
radiusX = 50;
radiusY = 100;
theta = 0;
}
void draw() {
background( 0 );
theta += 0.01;
posX = radiusX * cos( theta );
posY = radiusY * sin( theta );
translate( width / 2, height / 2 );
fill( 255 );
ellipse( posX, posY, 5, 5 );
}

Check out the Circles In The Sand, Round And Round… section in this article for a brief explanation of how that works.

Hope that helps

epochapex

Re: Elliptical Orbit

10 months ago

Now how would you actually use the atan2 function to rotate the shapes so they face the centre of the orbit?

Here's my code with the rotation code commented out because it's not working:

PShape bot1;
int plots = 30;
float increase = PI*2/plots;
float angle = 0;
float[] xCoord;
float[] yCoord;
float[] rot;
void setup() {
size(640, 480);
bot1 = loadShape("icons-1.svg");
xCoord = new float[plots];
yCoord = new float[plots];
// loop for plotting
for (int i = 0; i < plots; i++) {
double tempX = 100 * Math.cos( angle ) + width/2;
double tempY = 100 * Math.sin( angle ) + height/2;
xCoord[i] = (float)tempX;
yCoord[i] = (float)tempY;
angle += increase;
}
noLoop();
}
void draw() {
for(int i = 0; i < plots; i++) {
//double tempRot = Math.atan2(yCoord[i]-height/2,xCoord[i]-width/2);
//translate(width/2+15, height/2+15);
//rotate((float)tempRot);
shape(bot1, xCoord[i], yCoord[i], 30, 30);
}
save("Orbital.png");
}

I tried it with the matrix functions too and it didn't work.

epochapex

Re: Elliptical Orbit

10 months ago

Is there a way to rotate the shapes along their centre point after they have been translated into the circle?

PhiLho

Re: Elliptical Orbit

10 months ago

PShape bot1;
int plots = 30;
float increase = PI*2/plots;
float angle = 0;
float[] xCoord;
float[] yCoord;
float[] rot;
void setup() {
size(640, 480);
bot1 = loadShape("H:/PhiLhoSoft/Processing/ImprovingSVG/data/Chess_klt45.svg");
noLoop();
}
void draw() {
for (int i = 0; i < plots; i++) {
float x = 200 * cos( angle );
float y = 200 * sin( angle );
angle += increase;
pushMatrix();
translate(width / 2 + x, height / 2 + y);
rotate(angle);
shape(bot1, 0, 0, 30, 30);
popMatrix();
}
// save("Orbital.png");
}

epochapex

Re: Elliptical Orbit

10 months ago

Thanks for your help.

I see you got rid of the redundant loop in the setup function, cleaned up some of the math and made the rotation based on the angle.

It looks like the main problem was the structure of the math.

Edit: for anyone parachuting into this, here's a good article that explains basic trig for processing:
http://processing.org/learning/trig/

Top Reply