dynamic oscP5 messages

woolgathe..

in Contributed Library Questions • 1 month ago

Hi everyone,

I'm pretty new to processing but I can't seem to get enough of it! Anyway, I'm stuck on something I feel should have a solution...

I'm using OscP5 in my program and want to have several variables coming in simultaneously; however, I also want to avoid having to rewrite the entire oscEvent function over and over again for a different variable. What I'm wondering is how to dynamically create an Osc function that accepts arguments so I can just write, for instance:

myOscEvent(someString, someChar, printMe?);

such that:

float oscEvent(OscMessage theOscMessage) {
if (theOscMessage.checkAddrPattern(someString)==true) {
if (theOscMessage.checkTypetag(someChar)) {
float firstValue = theOscMessage.get(0).floatValue();
if(printMe?==true) {
println(" values: "+firstValue);
}
return firstValue;
}
}
}

I also suppose I don't understand how to pass arguments to oscEvent if (oscMessage theOscMessage) are there... And how do I pass strings as arguments in the first place?? Thanks for letting me be a noob...

Replies(1)

andreas.s..

Re: dynamic oscP5 messages

1 month ago

Hi, I have included 2 sample sketches that show you how to use oscP5's plug method to route an incoming message to a function inside your sketch and the second sketch uses a HashMap - a routing table - to route incoming messages to registered OscEventListeners. I have included comments into the sketches.

1. plug method

import oscP5.*;
import netP5.*;
OscP5 osc;
NetAddress remote;
void setup() {
size( 400, 400 );
/* start oscP5, and listen on port 12000 */
osc = new OscP5( this, 12000 );
/* our remote address here will point to 'osc' of this sketch */
remote = new NetAddress( "127.0.0.1", 12000 );
/* plug a function of your sketch to an address-pattern and typetag of
* an OscMessage you are expecting, the arguments will then be forwarded to
* the corresponding function inside your sketch.
* 1. argument: an object, here a reference to this sketch
* 2. argument: a String, the name of a function
* 3. argument: an address-pattern
* 4. argument: a typetag
*/
osc.plug(this, "test", "/test" , "ii");
}
void test(int a, int b ) {
println("hello "+ a + ", " + b );
}
void draw() {
}
/* send some test message on keyPressed */
void keyPressed() {
OscMessage m = new OscMessage("/test");
m.add(1);
m.add(2);
osc.send( m , remote );
}

2. routing table

import oscP5.*;
import netP5.*;
import java.util.*;
OscP5 osc;
NetAddress remote;
final Map<String , OscEventListener> routes = new HashMap<String , OscEventListener>();;
void setup() {
size( 400, 400 );
/* start oscP5, and listen on port 12000 */
osc = new OscP5( this, 12000 );
/* our remote address here will point to 'osc' of this sketch*/
remote = new NetAddress( "127.0.0.1", 12000 );
/* add an OscEventListener to our routing table (a HashMap, see processing or
* java api for more details). the Key here refers to the address-pattern followed by
* a space and the typetag of an OscMessage the Value is of type OscEventListener
* and expects an OscMessage which you can then work with.
*/
routes.put( "/test ii" , new OscEventListener() {
public void oscEvent(OscMessage m) {
println("hello");
}
});
routes.put( "/test iii" , new OscEventListener() {
public void oscEvent(OscMessage m) {
println("received /test iii");
}
});
/* add an OscEventListener to osc so that any message received can be
* evaluated against the keys inside our routing table.
*/
osc.addListener( new OscEventListener() {
public void oscEvent(OscMessage m) {
String key = m.addrPattern() +" "+ m.typetag( );
if( routes.containsKey( key ) ) {
routes.get( key ).oscEvent( m );
}
}
});
}
void draw() {
}
/* send some test message on keyPressed */
void keyPressed() {
OscMessage m;
switch(key) {
case('1'): // /test ii
m = new OscMessage("/test");
m.add(1);
m.add(2);
osc.send( m , remote );
break;
case('2'): // /test iii
m = new OscMessage("/test");
m.add(1);
m.add(2);
m.add(3);
osc.send( m , remote );
break;
}
}

andreas schlegel, http://www.sojamo.de

Top Reply