Duration timeline OSC

Contributed Library Questions

4ndrea

in Contributed Library Questions • 7 months ago

Hi,

I'm a beginner in processing via OSC. I looked oscP5.

I'd like to use the new timeline Duration with Processing, but I don't understand how to do.

With oscP5, after select the port, I receive messages:

### received an osc message with addrpattern /colors and typetag iii

-OscMessage----------

received from /127.0.0.1:59445

addrpattern /colors

typetag iii

[0] 249

[1] 59

[2] 0

what is the name of the variable?

This is the link of Duration:

http://www.duration.cc

Replies(5)

datamosh

Re: Duration timeline OSC

7 months ago

I don't understand your question: " what is the name of the variable?"

you can assign the value you retrieved from the message to a variable defined by you.

see the sketch below.

create new Duration project and add a color track, two curve and a switch, you'll find the names for these tracks in the sketch.

/* a sketch to test Duration (duration.cc) with Processing
enjoy
*/
import oscP5.*;
import netP5.*;
OscP5 oscP5;
void setup() {
oscP5 = new OscP5(this, 12345);
smooth();
}
float x = 0;
float y = 0;
color thecol, backcol;
void draw() {
noStroke();
fill(backcol);
rect(-1, -1, width+1, height+1);
fill(thecol);
ellipse(x, y, 20, 20);
}
void oscEvent(OscMessage mex) {
println(mex.typetag());
if (mex.addrPattern().equals("/curves")) {
x = mex.get(0).floatValue();
//println(mex.get(0).floatValue());
}
if (mex.addrPattern().equals("/switches")) {
if (mex.get(0).intValue() == 0) {
thecol = color(255, 30, 50);
}
else {
thecol = color(50, 10, 200);
}
}
if (mex.addrPattern().equals("/sine")) {
y = mex.get(0).floatValue();
}
if (mex.addrPattern().equals("/colors")) {
backcol = color(mex.get(0).intValue(), mex.get(1).intValue(), mex.get(2).intValue(), 10);
}
}

4ndrea

Re: Re: Duration timeline OSC

7 months ago

thank you very much!

4ndrea

Re: Duration timeline OSC

7 months ago

and for the audio?how to use FFT values??

andreas.s..

Re: Duration timeline OSC

7 months ago

Hi, had to gives this a shot, here is what I came up with

/* receive audio data from Duration */
import oscP5.*;
OscP5 oscP5;
void setup() {
size(400, 400);
oscP5 = new OscP5(this, 12345);
}
float[] audio = new float[0];
void draw() {
background(0);
stroke(255);
translate(0, height/2);
for (float f:audio) {
translate(2, 0);
line(0, 0, 0, -f * 100);
}
}
void oscEvent(OscMessage m) {
// check if the address pattern is a match for audio data sent from Duration
String address = "/audio"; // must match the name of the track in Duration
if ( m.addrPattern( ).equals( address ) ) {
audio = new float[ m.typetag().length() ];
for (int i = 0 ; i < m.typetag( ).length( ); i++) {
audio[ i ] = m.get( i ).floatValue( );
}
normalize( audio ); // map the highest value of array audio to 1, match others accordingly
}
}
void normalize(float[] src) {
float high = 0;
for ( float f:src ) {
if ( f > high ) {
high = f;
}
}
for (int i = 0 ; i< src.length; i++) {
src[i] = map(src[i], 0, high, 0, 1);
}
}

4ndrea

Re: Re: Duration timeline OSC

7 months ago

thank you guys!

Top Reply

Statistics

5 Replies
668 Views
0 Followers

Actions

Permalink