Drawing Glitches following 2012 Java Mac OS X Lion Updates

General Discussion Other

kitschpat..

Drawing Glitches following 2012 Java Mac OS X Lion Updates

in General Discussion • Other • 1 year ago

I'm getting some very nasty JAVA2D glitches after recent updates to Lion's Java JVM. Where you would expect smooth shape outlines, I'm getting variably jagged outlines. I've confirmed that these issues aren't present on 1.5 JVMs, or on any 1.6 JVM releases prior to Jan 2012 or so.

Here's a minimal test case:

float angle = 0;
void setup() {
size (600, 600, JAVA2D);
strokeWeight(10);
noFill();
stroke(255);
}
void draw() {
background (0);
beginShape();
for (float theta = 0; theta < angle % 360; theta += 0.1) {
float x = 200 * cos(radians(theta)) + 300;
float y = 200 * sin(radians(theta)) + 300;
vertex(x, y);
}
endShape();
angle++;
}

And here's the output I'm seeing on Lion. Same issue with either the 1.6.0_31 or 1.6.0_29 JVMs, and Processing 1.5.1 vs 2.0a5 doesn't make a difference either. This same code produces a perfect circle on earlier JVMs:

Any ideas? Looks like a JVM bug but I haven't been able to find a work-around.

This is a possibly related post from a few months ago:

http://forum.processing.org/topic/problems-with-java-update-1-6-0-29-mac-os-x-lion

Replies(7)

calsign

Re: Drawing Glitches following 2012 Java Mac OS X Lion Updates

1 year ago

I have Windows 7 64 bit with Java 1.6.026 and get similar drawing errors when running your code...
Adding a call to smooth() doesn't help, either.
I have not noticed anything similar before.

I think the problem has more to do with your code than a Java issue - changing the for loop increment from 0.1 to 1 fixed the problem for me. It likely has to do with internal rounding...

kitschpat..

Re: Drawing Glitches following 2012 Java Mac OS X Lion Updates

1 year ago

Hi Calsign, thanks for responding and testing the code. However, I already played around with smoothing, and tried different theta incrementation values... I get the same errors even (albeit to a lesser degree). Again the code I posted draws fine on Java 1.5, even with theta += 0.1.

For example, here's a version of the test code which only draws on whole-number increments and never places a vertex on the same pixel location twice...

float lastX, lastY, angle;
void setup() {
size (600, 600, JAVA2D);
strokeWeight(10);
noFill();
stroke(255);
}
void draw() {
background (0);
beginShape();
for (float theta = 0; theta < angle % 360; theta += 0.1) {
float x = 200 * cos(radians(theta)) + 300;
float y = 200 * sin(radians(theta)) + 300;
// Only draw vertex on whole increments,
// never draw twice in the same location
if ((lastX != int(x)) || (lastY != int(y))) {
lastX = int(x);
lastY = int(y);
vertex(lastX, lastY);
}
}
endShape();
angle++;
}

This creates similarly glitchy output:

The glitch can be isolated to the stroke drawing routines... filled shapes still draw cleanly. For example, if set noStroke() and draw with a fill instead, the same code (even with the 0.1 theta increment) draws just fine. Here's the slightly modified code:

float angle;
void setup() {
size (600, 600, JAVA2D);
fill(255);
noStroke();
}
void draw() {
background (0);
beginShape();
for (float theta = 0; theta < angle % 360; theta += 0.1) {
float x = 200 * cos(radians(theta)) + 300;
float y = 200 * sin(radians(theta)) + 300;
vertex(x, y);
}
endShape();
angle++;
}

And the output:

I'm really at a loss.

asimes

Re: Drawing Glitches following 2012 Java Mac OS X Lion Updates

1 year ago

This doesn't answer your question, but maybe you could place ellipses instead?

kitschpat..

Re: Drawing Glitches following 2012 Java Mac OS X Lion Updates

1 year ago

Thanks asimes, but this is just the simplest case required to reproduce the error — I'm running into the error in a more complicated context where there aren't clear work-arounds.

This is a core component of the drawing API's functionality that used to work and now seems to be badly broken. We shouldn't need a work-around for drawing lines.

I poked around a bit more and found that beginShape(POINTS); or beginShape(LINES); seems to help aesthetically, but it's still not actually drawing the correct thing. Also combining beginShape(LINES); with strokeCap(SQUARE); produces similarly broken results.

If you watch closely while it draws, it seems like whatever code is responsible for rotating the end of the stroke cap to the perpendicular of the line's path is acting inconsistently. These errors accumulate into the jagged stroke outline in the screenshot above.

kitschpat..

Re: Drawing Glitches following 2012 Java Mac OS X Lion Updates

1 year ago

I've created some test cases that seem to further suggest that the issue is with how the angle of a line's end cap is calculated.

Again here's an overview of how the same code (from the first post in this thread) looks under Java 1.5 vs. Java 1.6:

The bottom example is another batch of test code designed to show exactly how the line segments are drawing. If you look carefully you can see that the segment caps are getting drawn at slightly variable angles in Java 1.6, while Java 1.5 draws them consistently and correctly. The red lines show the correct angles from the circle formula. Here's a closer look:

And the test code:

float angle;
void setup() {
size (400, 400, JAVA2D);
noFill();
smooth();
}
void draw() {
background (0);
// draw segment angles
stroke(255, 0, 0, 100);
strokeCap(ROUND);
strokeWeight(1);
for (float theta = 0; theta < angle % 360; theta += 5) {
float x = 500 * cos(radians(theta));
float y = 500 * sin(radians(theta));
line(0, 0, x, y);
}
// draw line segments
stroke(255, 100);
strokeCap(SQUARE);
strokeWeight(400);
beginShape(LINES);
for (float theta = 0; theta < angle % 360; theta += 5) {
float x = 200 * cos(radians(theta));
float y = 200 * sin(radians(theta));
vertex(x, y);
}
endShape();
angle++;
}

Next I'll try to see if I can reproduce this using pure Java instead of the Processing API... but from poking around the source for Processing's JAVA2D renderer it doesn't look Processing is doing anything particularly strange... so I'm assuming this is a Java bug.

Looks like this is a problem with Java 1.6 on Windows as well.

kitschpat..

Re: Drawing Glitches following 2012 Java Mac OS X Lion Updates

1 year ago

Ok, apologies for the play-by-play, but I think I found a fix:

Graphics2D g2 = ((PGraphicsJava2D)g).g2;
g2.setRenderingHint(RenderingHints.KEY_STROKE_CONTROL, RenderingHints.VALUE_STROKE_PURE);

Output on Java 1.6.0_31:

Full test code with fix:

import java.awt.Graphics2D;
import java.awt.RenderingHints;
float angle;
void setup() {
size (600, 600, JAVA2D);
Graphics2D g2 = ((PGraphicsJava2D)g).g2;
g2.setRenderingHint(RenderingHints.KEY_STROKE_CONTROL, RenderingHints.VALUE_STROKE_PURE);
strokeWeight(10);
noFill();
stroke(255);
}
void draw() {
background (0);
beginShape();
for (float theta = 0; theta < angle % 360; theta += 0.1) {
float x = 200 * cos(radians(theta)) + 300;
float y = 200 * sin(radians(theta)) + 300;
vertex(x, y);
}
endShape();
angle++;
}

Maybe this should trickle up to core if there aren't any nasty side effects?

More info on the hint:

http://docs.oracle.com/javase/6/docs/api/java/awt/RenderingHints.html#KEY_STROKE_CONTROL

kitschpat..

Re: Drawing Glitches following 2012 Java Mac OS X Lion Updates

1 year ago

Opened an issue here: http://code.google.com/p/processing/issues/detail?id=1068

Sorry this probably should have been on the dev site all along.

Top Reply