Draw only color within blobs

Contributed Library Questions

danieljay

in Contributed Library Questions • 10 months ago

I am trying to set boundaries to draw only within detected blobs.

here is the code I am using thus far:

import blobDetection.*;
BlobDetection theBlobDetection;
PGraphics img;
// ==================================================
// setup()
// ==================================================
void setup()
{
// Works with Processing 1.5
// img = createGraphics(640, 480,P2D);
// Works with Processing 2.0b3
img = createGraphics(640, 480);
img.beginDraw();
img.background(255);
img.noStroke();
img.fill(0);
for (int i=0;i<20;i++) {
float r = random(50);
img.ellipse(random(img.width), random(img.height), r, r);
}
img.endDraw();
theBlobDetection = new BlobDetection(img.width, img.height);
theBlobDetection.setPosDiscrimination(false);
theBlobDetection.setThreshold(0.38f);
theBlobDetection.computeBlobs(img.pixels);
// Size of applet
size(img.width, img.height);
}
// ==================================================
// draw()
// ==================================================
void draw()
{
image(img, 0, 0, width, height);
drawBlobsAndEdges(true, true);
}
// ==================================================
// drawBlobsAndEdges()
// ==================================================
void drawBlobsAndEdges(boolean drawBlobs, boolean drawEdges)
{
noFill();
Blob b;
EdgeVertex eA, eB;
for (int n=0 ; n<theBlobDetection.getBlobNb() ; n++)
{
b=theBlobDetection.getBlob(n);
if (b!=null)
{
// Edges
if (drawEdges)
{
strokeWeight(2);
stroke(0, 255, 0);
for (int m=0;m<b.getEdgeNb();m++)
{
eA = b.getEdgeVertexA(m);
eB = b.getEdgeVertexB(m);
if (eA !=null && eB !=null)
line(
eA.x*width, eA.y*height,
eB.x*width, eB.y*height
);
}
}
// Blobs
if (drawBlobs)
{
strokeWeight(1);
stroke(255, 0, 0);
rect(
b.xMin*width, b.yMin*height,
b.w*width, b.h*height
);
}
}
}
}

Replies(4)

amnon.owed

Re: Draw only color within blobs

10 months ago

You don't need blob detection for that. You can just use mask().

Adapted Code

PGraphics img;
void setup() {
size(640, 480);
img = createGraphics(width, height,P2D);
img.beginDraw();
img.smooth();
img.background(255);
img.noStroke();
img.fill(0);
for (int i=0;i<20;i++) {
float r = random(5,100);
img.ellipse(random(img.width), random(img.height), r, r);
}
img.endDraw();
img.mask(img);
fill(0);
}
void draw() {
background(frameCount % 255,0,255-frameCount % 255);
float w = width/20;
for (int i=0;i<11;i++) {
rect(w*i*2+frameCount%w*2-w, 0, w, height);
}
image(img, 0, 0, width, height);
}

danieljay

Re: Draw only color within blobs

10 months ago

I have looked at your example and Processing reference, but I do not understand how you are using mask in this way.

amnon.owed

Re: Draw only color within blobs

10 months ago

The mask() method can make parts of a regular image transparent. It does this based on the blue color channel of a greyscale mask image. White in the mask image makes the pixel in the regular image fully opaque, black makes it fully transparent and grey everything in between.

In your code the created pgraphics image is black (blobs) and white (background) and I assume this represents the image you get in your real application. So as explained above, a black and white image can be used as a mask. Of course usually the regular image is a normal color image. In my code example however both the "regular image" and the "mask image" are in fact the same image.

By using the black and white image on itself as a mask, you make it transparent in the previously black areas. So you end up with an image that is partially white and partially transparent (where the blobs were). Now you can draw anything you want in the draw() loop and then draw your partially transparent image on top. Of course the white parts will be white, but the transparent (previously black) parts will show what was drawn before. In effect creating the illusion that you are only drawing within the blobs (in reality you draw everywhere, but only seeing what is drawn within the blobs).

danieljay

Re: Re: Draw only color within blobs

10 months ago

Thanks a bunch for that explanation. and a great approach!

Top Reply