You can adapt the getValues() function in the example below so it uses your incoming values. You can also change the amplitude to achieve the waveform's height you want.

Code Example

1. int numValues = 200;
2. float[] yvalues = new float[numValues];
3. int amplitude = 30;
4.  
5. void setup() {
6.   size(800, 800);
7.   smooth();
8. }
9.  
10. void draw() {
11.   background(0);
12.   getValues();
13.   drawWaveForm();
14. }
15.  
16. void getValues() {
17.   for (int x=0; x<yvalues.length; x++) {
18.     float yourValue = sin(frameCount * 0.02 + (TWO_PI / 75)* x);
19.     yvalues[x] = yourValue * amplitude;
20.   }
21. }
22.  
23. void drawWaveForm() {
24.   float angle = -atan2(mouseX-width/2, mouseY-height/2)+HALF_PI;
25.   translate(width/2, height/2);
26.   rotate(angle);
27.   float spacing = dist(mouseX, mouseY, width/2, height/2) / numValues;
28.   noFill();
29.   stroke(255);
30.   beginShape();
31.   for (int x=0; x<yvalues.length; x++) {
32.     vertex(x * spacing, yvalues[x]);
33.   }
34.   endShape();
35. }

Thank you amnon.owed :) I have compiled your code and i like it.. but i need adapt getvalues, really i dont use mouseX and mouseY im using reactivision then... i have to use (width/2, height/2, tobj.getScreenX(width), tobj.getScreenY(height))

amnon.owed its working fine :) 

some idea? :/

I think I know what you mean. You want both the beginning and the end of the line to connect exactly to the center of the screen and the user (mouse/tuio) respectively. This concerns the amplitude of the line. At the extreme ends of the line you want the amplitude to be zero. Now for this to look visually smooth, you will want to gradually lessen the amplitude as you move towards the extreme ends. There are at least two ways to do this. Either you have individual amplitudes (instead of a global one) that are smaller towards the extreme ends. Or you dampen the outer values, after they have been set. Here is a code example of the second method.

The value that you enter in the dampen value is the range (out of the numvalues) from both sides over which the dampening is gradually done. So a small smaller number (like 10) dampens it very quickly, while a large number (like 100) dampens it very smoothly (but also makes the graph deviate from your original values obviously). So you want the middle ground, a number that makes the dampening look smooth, but doesn't affect the amplitude of the whole graph too much (like 50). Of course a 'solution' to the dampened amplitude of the graph is to increase the global amplitude again, which I've also done a little in the example below.

Code Example

1. int numValues = 200;
2. float[] yvalues = new float[numValues];
3. int amplitude = 50; // increase amplitude a little if you want to compensate for dampening
   
4.  
5. void setup() {
6.   size(800, 800);
7.   smooth();
8. }
9.  
10. void draw() {
11.   background(0);
12.   noStroke();
13.   fill(255);
14.   ellipse(width/2, height/2, 10, 10);
15.   ellipse(mouseX, mouseY, 10, 10);
16.   getValues();
17.   dampen(50); // set dampen smoothness here
    
18.   drawWaveForm();
19. }
20.  
21. void getValues() {
22.   for (int x=0; x<yvalues.length; x++) {
23.     float yourValue = sin(frameCount * 0.2 + (TWO_PI / 75)* x); // I also increased the speed
    
24.     yvalues[x] = yourValue * amplitude;
25.   }
26. }
27.  
28. void dampen(int range) {
29.   for (int x=0; x<range; x++) {
30.     yvalues[x] *= (float) x/range;
31.     yvalues[yvalues.length-1-x] *= (float) x/range;
32.   }
33. }
34.  
35. void drawWaveForm() {
36.   float angle = -atan2(mouseX-width/2, mouseY-height/2)+HALF_PI;
37.   translate(width/2, height/2);
38.   rotate(angle);
39.   float spacing = dist(mouseX, mouseY, width/2, height/2) / numValues;
40.   noFill();
41.   stroke(255);
42.   beginShape();
43.   for (int x=0; x<yvalues.length; x++) {
44.     vertex(x * spacing, yvalues[x]);
45.   }
46.   endShape();
47. }

Your code is not runnable, apart from the fact almost no one will have your setup (aka tuio). In general, if you want help, create a code example that people are able to run. For example in this case your question is not related to the tuio per se.

Now with regard to your question. You should start with shortening your code and then move to optimizing it. Currently you are rewriting almost similar code over and over. I have the feeling that it can be shortened a lot (and then perhaps optimized also). What you write now 20 times, you should be able to write maybe only once. This will not only make your code more readable, require less typing and leave less opportunity for errors, but it will also allow you to see where you can optimize more clearly. The number one function you should look into is the for loop.

Shorten your code first. Then try to optimize it.