Does Picking library support 2d line picking?

unparadise

Does Picking library support 2d line picking?

in Contributed Library Questions • 3 years ago

I an really new to processing. Try to create a program that highlights a line when the mouse is moved over it. I downloaded the picking library from here: http://code.google.com/p/processing-picking-library/

I looked at the demos which show how it works in 3D and I modified the code to 2d circle and it works too. When I changed the circle to a line it doesn't work any more. Any help is appreciated.

Below is the code I modified based on the demo.

------------------------------------

import picking.*;

Picker picker;

void setup() {

size(200, 200);

smooth();

picker = new Picker(this);

stroke(255);

}

void draw() {

background(50);

picker.start(0);

line(0, 0, width, height);

picker.stop();

int id = picker.get(mouseX, mouseY);

switch (id) {

case -1:

stroke(255);

break;

case 0:

stroke(255, 150, 150);

break;

default:

stroke(120);

break;

}

Replies(3)

cedrickie..

Re: Does Picking library support 2d line picking?

3 years ago

you can use caseys, circle line intersection example.
the benefit by using it, you can also determine how close you have to get to touch the line by changing the radius.

float circleX ;
float circleY;
float circleRadius = 10;

float lineX1 = 350;
float lineY1 = 350;
float   lineX2 = 50;
float   lineY2 = 50;

void setup() {
size(400, 400);
ellipseMode(RADIUS);
smooth();
}

void draw() {
background(204);

circleX = mouseX;
circleY = mouseY;
if (circleLineIntersect(lineX1, lineY1, lineX2, lineY2, circleX, circleY, circleRadius) == true) {
    stroke(0);
}
else {
    stroke(255);
}

line(lineX1, lineY1, lineX2, lineY2);
noStroke();
fill(0);
ellipse(circleX, circleY,2,2);
noFill();
stroke(0,40);
ellipse(circleX, circleY, circleRadius, circleRadius);
}

// Code adapted from Paul Bourke:
// http://local.wasp.uwa.edu.au/~pbourke/geometry/sphereline/raysphere.c
boolean circleLineIntersect(float x1, float y1, float x2, float y2, float cx, float cy, float cr ) {
float dx = x2 - x1;
float dy = y2 - y1;
float a = dx * dx + dy * dy;
float b = 2 * (dx * (x1 - cx) + dy * (y1 - cy));
float c = cx * cx + cy * cy;
c += x1 * x1 + y1 * y1;
c -= 2 * (cx * x1 + cy * y1);
c -= cr * cr;
float bb4ac = b * b - 4 * a * c;

//println(bb4ac);

if (bb4ac < 0) { // Not intersecting
    return false;
}
else {

    float mu = (-b + sqrt( b*b - 4*a*c )) / (2*a);
    float ix1 = x1 + mu*(dx);
    float iy1 = y1 + mu*(dy);
    mu = (-b - sqrt(b*b - 4*a*c )) / (2*a);
    float ix2 = x1 + mu*(dx);
    float iy2 = y1 + mu*(dy);

    // The intersection points
    //ellipse(ix1, iy1, 10, 10);
    //ellipse(ix2, iy2, 10, 10);

    float testX;
    float testY;
    // Figure out which point is closer to the circle
    if (dist(x1, y1, cx, cy) < dist(x2, y2, cx, cy)) {
      testX = x2;
      testY = y2;
    }
    else {
      testX = x1;
      testY = y1;
    }

    if (dist(testX, testY, ix1, iy1) < dist(x1, y1, x2, y2) || dist(testX, testY, ix2, iy2) < dist(x1, y1, x2, y2)) {
      return true;
    }
    else {
      return false;
    }
}
}

unparadise

Re: Does Picking library support 2d line picking?

3 years ago

Thank you very much fir sharing the code, cedrickiefer. it works.

chicoatomo

Re: Does Picking library support 2d line picking?

1 year ago

Hello

Other choice for picking lines with the "picking library" (author: Nicolas Clavaud) is to change a little bit the code of the library.

If you open the src file of the library you will discover two java files

\Processing\libraries\Picking\src\picking

1. Buffer.java

2. Picker.java

You only have to add 2 lines in the Buffer.java file and compile the new library jar ( with NetBeans or Eclipse )

/*
Provides an easy way to pick an object in a 3D scene.
(c) copyright
This library is free software; you can redistribute it and/or
modify it under the terms of the GNU Lesser General Public
License as published by the Free Software Foundation; either
version 2.1 of the License, or (at your option) any later version.
This library is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
Lesser General Public License for more details.
You should have received a copy of the GNU Lesser General
Public License along with this library; if not, write to the
Free Software Foundation, Inc., 59 Temple Place, Suite 330,
Boston, MA 02111-1307 USA
*/
package picking;
import processing.core.*;
/**
* All pickable objects are drawn in a Buffer instance.
*
* @author Nicolas Clavaud <antiplastik@gmail.com>
*
*/
public class Buffer extends PGraphics3D {
protected int current_color = 0;
public Buffer() {}
public boolean displayable() { return true; }
public void callCheckSettings() { super.checkSettings(); }
public void background(int arg) { super.background(0); }
public void background(float arg) { super.background(0); }
public void background(float arg, float arg_1) { super.background(0); }
public void background(int arg, float arg_1) { super.background(0); }
public void background(float arg, float arg_1, float arg_2) { super.background(0); }
public void background(float arg, float arg_1, float arg_2, float arg_3) { super.background(0); }
public void background(PImage arg) { super.background(0); }
public void lights() {}
public void smooth() {}
public void fill(int arg) {}
public void fill(float arg) {}
public void fill(float arg, float arg_1) {}
public void fill(int arg, float arg_1) {}
public void fill(float arg, float arg_1, float arg_2) {}
public void fill(float arg, float arg_1, float arg_2, float arg_3) {}
public void stroke(int arg) {}
public void stroke(float arg) {}
public void stroke(float arg, float arg_1) {}
public void stroke(int arg, float arg_1) {}
public void stroke(float arg, float arg_1, float arg_2) {}
public void stroke(float arg, float arg_1, float arg_2, float arg_3) {}
public void textureMode(int arg) {}
public void texture(PImage arg) {}
public void vertex(float x, float y, float z, float u, float v) { super.vertex(x, y, z); }
public void image(PImage arg, float arg_1, float arg_2) {}
public void image(PImage arg, float arg_1, float arg_2, float arg_3, float arg_4) {}
public void image(PImage arg, float arg_1, float arg_2, float arg_3, float arg_4, int arg_5, int arg_6, int arg_7, int arg_8) {}
protected void imageImpl(PImage image,
float x1, float y1, float x2, float y2,
int u1, int v1, int u2, int v2) {}
public void setCurrentId(int i) {
// ID 0 to 16777214 => COLOR -16777215 to -1 (white)
// -16777216 is black
current_color = i - 16777215;
super.fill(current_color);
super.stroke(current_color);
super.strokeWeight(10);
}
public int getId(int x, int y) {
super.loadPixels();
// COLOR -16777216 (black) to -1 => ID -1 (no object) to 16777214
int id = pixels[y*width+x] + 16777215;
return id;
}
}

With the new *.jar you can select lines

Here is the link for download the new : picking.jar

https://docs.google.com/file/d/0B_sGNIYuV8raYVV6cS16OVpzeXc/edit

You must overwrite the file located in:

MyDocuments\Processing\libraries\Picking\library

Note: I have put a strokeWeight = 10, but you can change this value depending on the precision you need.

Example:

import picking.*;
Picker picker;
void setup()
{
size(500,500,P3D);
picker = new Picker(this);
}
void draw()
{
background(255);
camera(20,20,50,0,0,0,0,1,0);
picker.start(1);
stroke(255,0,0);strokeWeight(2);
line(0,0,10,5);
picker.start(2);
stroke(0,255,0);strokeWeight(2);
line(10,5,20,20);
picker.start(3);
stroke(0,0,255);strokeWeight(2);
line(20,20,0,0);
}
void mouseClicked()
{
int id = picker.get(mouseX, mouseY);
println(id);
}

Top Reply