distribution of points

General Discussion Other

pacoruizg..

in General Discussion • Other • 1 year ago

Hi,

I want to fill a surface with aleatory points, but if I do it with random I dont like the way it ends because there are some areas with many points and others empty. If I use noise, it doesnt fill the borders of the area.

I want something as particles of a fluid, or as trees in a forest. With an impression of dissorder, but without concentration or empty spaces.

I can do it with random and after separating points creating a force, but it has to be a more eficient way.

Replies(7)

amnon.owed

Re: distribution of points

1 year ago

Another technique would be to randomly 'grow points' from existing points. Something like this...

Code Example

ArrayList <PVector> points = new ArrayList <PVector> ();
float range = 10; // minimum distance between points
int maxPoints = 400; // maximum number of points
void setup() {
size(500, 500);
}
void draw() {
background(255);
if (points.size() < maxPoints) {
// range = random(10, 60); // uncomment to change range continuously
float dR = range*2;
for (int i=points.size()-1; i>=0; i--) {
// for (int i=points.size()-1; i>=max(0,points.size()-30); i--) { // or something like this...
PVector p = points.get(i);
PVector n = PVector.add(p, new PVector(random(-dR, dR), random(-dR, dR)));
if (!withinRange(points, n, range) && onScreen(n)) { points.add(n); }
}
}
for (PVector p : points) {
fill(p.x, p.y, 255-p.x);
rect(p.x, p.y, 4, 4);
}
}
void mousePressed() {
points.clear();
points.add(new PVector(mouseX, mouseY));
}
boolean withinRange(ArrayList <PVector> points, PVector n, float range) {
for (PVector p : points) {
if (n.dist(p) < range) {
return true;
}
}
return false;
}
boolean onScreen(PVector n) {
return n.x >= 0 && n.x <= width && n.y >= 0 && n.y <= height;
}

cedrickie..

Re: distribution of points

1 year ago

i would actually say noise is the way to go. and i cant think of a reason why the borders are not filled. Probably depends on how you use noise to fill the area.

pacoruizg..

Re: distribution of points

1 year ago

amnon idea is interesting, but I agree with cedrick that I fell noise should work and I dont know why not. This is an example of sing noise. I´ve tried to fill a line, and you see the borders are not filled even using a whole lot of points.

for (int i=0; i<3000;i++){
set (50, int(noise(i)*height), color(0));
}

cedrickie..

Re: distribution of points

1 year ago

ok i see... yeah thats because you dont get the really low and really high values.

Something that is perfectly shown by a video by amnon http://amnonp5.wordpress.com/2010/05/05/comparing-number-distributions/

but if you want to fill a 2d surface with points you can use noise in different ways i guess.

Just took the noise example from the processing website and just placed a point when noise it above a random value.

hold down a key to move through noise in 3d space.

float increment = 0.02;
void setup() {
size(200, 200);
noLoop();
}
void draw() {
background(0);
noiseDetail(1, 0.65f);
randomSeed(0);
loadPixels();
float xoff = 0.0; // Start xoff at 0
for (int x = 0; x < width; x++) {
xoff += increment; // Increment xoff
float yoff = 0.0; // For every xoff, start yoff at 0
for (int y = 0; y < height; y++) {
yoff += increment; // Increment yoff
float bright = noise(xoff, yoff, frameCount/15.0);
if (random(1)<bright) pixels[x+y*width] = color(255);
}
}
updatePixels();
}
void keyPressed() {
redraw();
}

amnon.owed

Re: distribution of points

1 year ago

On a sidenote. As discussed in this thread, Processing's noise function appears to be something other than Perlin noise. Only the german demo group farbrausch knows exactly what it is as the code apparantly originates from a 64k they made in 2001 called Art. One for the Processing trivia book.

Anyway, as cedric suggested, there may be indirect ways to use noise for generating point distributions. With the default settings, noise will rarely-to-never generate some outer values. If you really, really want to use noise directly and have a whatever works attitude, you can use 1 octave and double the outcome.

noiseDetail(1,0);
for (int i=0; i<3000;i++){
set(50, int(2*noise(i)*height), color(0));
}

pacoruizg..

Re: Re: distribution of points

1 year ago

I made a try with amnon idea (second post), and I filled all the area, but the impression is not what I was looking for. The first amnon idea produced the impression I wanted, but if I fill all the area, it needs too much time. Maybe the best idea is to generate points with random and after separate them. The purpose of generating the points is to simulate a flow in a pipe. This is my actual version. I simply wanted to simplificate with a better way of generating the points. In my code what I do is separate the balls that were generated with random

class ball{
PVector pos;
PVector v;
PVector force;
color c;
int r=3;
float f = 0.1;
float g = 0.1;
float vaverage = 2;
ball(int x0, int y0){
    pos=new PVector(x0,y0);
    v=new PVector(0,4);
    force = new PVector (0,0);
}
void update(){
    v.y = vaverage * (1 - sq(pos.x - middle)/sq(pipediam/2));
    v.add (force);
    //add some chaos
    v.x = v.x + random(-0.3,0.3);
    count++;
    //v.y = v.y + g ;
    pos.add(v);
    v.x = v.x*0.5;
    force.x = 0;
    force.y = 0;
}
void render(){
    //if (abs(x.x-middle)<0.4 * pipediam){
      fill(20,20,2000);
      ellipse(int(pos.x),int(pos.y),2.5,2.5);
      if ((pos.y > respoint - reslenght/2)&& (pos.y > respoint + reslenght/2)){


      }
    //}
}
}
float count;
int width=800;
int height=600;
float g=2;
ArrayList balls= new ArrayList();
float k=1;//factor to increment distance between balls
float c= 4;//maximun penetrance in walls
float vlim=10;//maximum speed
float population=1000;//population limit
float suck = 10;// distance of influence
float leftborder;
float rightborder;
float visc;
float pipediam = 100;
float middle;
float repulsion = 0.1;
float reslenght = 50;
float respoint;

void setup(){
noStroke();
//frameRate(48);
size(800,600);
leftborder = width/2-pipediam/2;
rightborder = width/2 + pipediam/2;
middle =(leftborder + rightborder)/2;
respoint = height/2;
for (int i = 0; i < population; i++){
balls.add(new ball(int(random(leftborder,rightborder)), int(random(0,height))));
}
}

void draw(){
fill (250,100);
rect(0,0,width, height);
for(int i=0;i<balls.size();i++){
    ball b = (ball) balls.get(i);
    //separate from walls
    if(b.pos.x>rightborder-b.r+c){b.pos.x=rightborder;}
    if(b.pos.x<leftborder + b.r-c){b.pos.x=leftborder;}
    if(b.pos.y>height-b.r+c){b.pos.y-=5;}
    //repulsion between balls
    for(int j=i+1;j<balls.size();j++){
      ball b2 = (ball) balls.get(j);
      PVector dx=PVector.sub(b2.pos,b.pos);
      if (dx.mag() < suck){
        dx.normalize();
        dx.mult(repulsion);
        b2.force.add( dx);
        dx.mult(-1);
        b.force.add( dx);
      }
    }
    //repulsion to walls
    if (b.pos.x < suck + leftborder){
      b.force.x = b.force.x + repulsion;
    }
    if (b.pos.x > rightborder - suck){
      b.force.x = b.force.x - repulsion;
    }
    b.update();
    // corrections
    if (b.v.y < 0){b.v.y = 0;}

    b.render();
    if (b.pos.y > height){
     b.pos.y = 0;
    }
}

}

v.k.

Re: distribution of points

1 year ago

That reminds me of sketch i made for testing the randomness of a implementation of " Fisher-Yattes shuffle" i tried. It seems very random and even and organic to me. Actually there are two methods both uses a pre filled array with numbers in sequence that are shuffled. Then you got a random index to access the array. Also the x position is not random, so is like a line of random points what make it evenly distributed. May have nothing to do with what you need but... may be an idea.

// with code from WikiPedia; Fisher–Yates shuffle
// http://en.wikipedia.org/wiki/Fisher–Yates_shuffle
import java.util.Random;
Random rng = new Random();
int[] numbers = new int[240];
int[] index = new int[7]; // numbers of ponits to draw each line
int[] indexReto = new int[7];// numbers of ponits to draw each line
color c1 = color(69,31,90);
float leng=0;
int xisp=-40;
void setup() {
size(1500,480);
for (int i = 0; i < numbers.length; i++) {
numbers[i]=i+1;
}
for (int i = 0; i < index.length; i++) {
index[i]=i;
indexReto[i]=i;
}
background(c1);
}
void draw() {
stroke(0);
strokeWeight(2);
line(0,height/2,width,height/2);
shuffle(numbers);
shuffle(index);
for (int i = 0; i < index.length; i++) {
fill(115,139,11);
noStroke();
ellipse(xisp+i,height/2-numbers[index[i]],2,2);
stroke(0);
fill(120,142,18);
noStroke();
int ind=int(random(0,60));
ellipse(xisp+i,height-numbers[ind],2,2);
stroke(0);
}
if( xisp<=width){
xisp=(xisp+1);}else{xisp=-40;}
}
void keyReleased() {
}
void shuffle(int[] array) {
// i is the number of items remaining to be shuffled.
for (int i = array.length; i > 1; i--) {
// Pick a random element to swap with the i-th element.
int j = rng.nextInt(i); // 0 <= j <= i-1 (0-based array)
// Swap array elements.
int tmp = array[j];
array[j] = array[i-1];
array[i-1] = tmp;
}
}

Top Reply